设为首页收藏本站CAD论坛CAD教程CAD下载明经币充值
切换到宽版

明经CAD社区

 找回密码
 注册

QQ登录

只需一步，快速开始

搜索
明经CAD社区»社区 › 开发篇 › AutoLISP/Visual LISP 编程技术 › 修改了下grread捕捉子函数应该能用了
1234下一页
返回列表 发新帖
查看: 11896|回复: 37

[函数] 修改了下grread捕捉子函数应该能用了

    [复制链接]
langjs
发表于 2017-12-25 15:13:42 | 显示全部楼层 |阅读模式
;;; grread捕捉子函数
;;; name为移动的图元名，pt为光标点
;;; 返回值：如果有捕捉点则返回捕捉点，无则返回光标点
(defun osnappt (name pt / color d h k lst nearpt nearpt2 osmo pt1 pt2 pt3 pt4 pt5 ptx pty x)
  (if name (entdel name))
  (redraw)
  (if (< (getvar "osmode") 16384)
    (progn
      (setq color (vla-get-autosnapmarkercolor (vla-get-drafting (vla-get-preferences (vlax-get-acad-object))))
            h (/ (getvar "viewsize") (cadr (getvar "screensize"))) d (getvar "pickbox")
            lst (list (* d h) (* (- d 0.5) h) (* (+ d 0.5) h)) k (* 1.5 d h))
      (if (setq nearpt (osnap pt "_END,_CEN,_NOD,_QUA,_INS,_TAN,_EXT"))(setq osmo 1))
      (if (and(setq nearpt2 (osnap pt "_NEA"))(not (equal nearpt nearpt2 k)))
        (setq osmo 2 nearpt nearpt2))
      (if (and(setq nearpt2 (osnap pt "_MID"))(equal nearpt nearpt2 k))
        (setq osmo 3 nearpt nearpt2))
      (if (and(setq nearpt2 (osnap pt "_INT"))(equal nearpt nearpt2 k))
        (setq osmo 4 nearpt nearpt2))))
  (if name(entdel name))
  (if nearpt
    (progn
      (setq ptx (car nearpt)pty (cadr nearpt))
      (foreach x lst
        (setq pt1 (list (- ptx x) (- pty x)) pt2 (list (+ ptx x) (- pty x))
              pt3 (list (+ ptx x) (+ pty x)) pt4 (list (- ptx x) (+ pty x))
              pt5 (list ptx (+ pty x)))
        (cond
          ((= osmo 1)(grvecs (list color pt1 pt2 pt2 pt3 pt3 pt4 pt4 pt1)))
          ((= osmo 2)(grvecs (list color pt1 pt2 pt2 pt4 pt3 pt4 pt3 pt1)))
          ((= osmo 3) (grvecs (list color pt1 pt2 pt2 pt5 pt5 pt1)))
          ((= osmo 4) (grvecs (list color pt1 pt3 color pt2 pt4)))))
      (setq pt nearpt)))
  pt
)
;;; 示例:动态移动文字
(defun c:qq (/ code ent gr loop name pt)
  (if (setq name (car (entsel "\n选择文本:")))
    (progn
      (setq ent (entget name) loop t)
      (princ "\n指定点:")
      (while loop
        (setq gr (grread t 15 0) code (car gr) pt (cadr gr))
        (cond
          ((= code 3)(redraw) (setq loop nil))  ; 鼠标左键
          ((= code 5)                  ; 鼠标移动
            (setq pt (osnappt name pt))
            (entmod (setq ent (subst(cons 10 pt)(assoc 10 ent)ent))))
          ((= code 2)                  ; 键盘输入
            (princ "\n键盘输入=")(princ pt))
          ((member code '(11 25))      ; 鼠标右击
            (redraw)  (setq loop nil))))))
  (princ)
)

点评

myjping
sorry,昨天晚上在2012试了下，能移动能捕捕，但字不动；今天试换电脑试了下，可以了  发表于 2017-12-26 13:08
myjping
好像运行不了  发表于 2017-12-26 13:01

评分

参与人数 1明经币 +1 收起 理由
669423907 + 1 很给力!

查看全部评分

"觉得好，就打赏"
打赏
还没有人打赏，支持一下

本帖被以下淘专辑推荐:

  • · 学习|主题: 95, 订阅: 8
回复

使用道具 举报

gzcsun
发表于 2024-7-24 11:32:36 | 显示全部楼层
本帖最后由 gzcsun 于 2024-8-10 00:08 编辑
228378553 发表于 2024-7-24 11:03
好像还是不能捕捉圆心和几何中心

自己加上。圆心 ,几何中心,图元中心 都可以有。
我是不用几何中心的,图元中心用得多。

cad原捕捉限显示6个；而且面域不能显示几何中心。

所以圆心限显示4个，
图元中心限显示2个，面域，块，多段线的都能显示，其它的要按一下按键才显示。


本帖子中包含更多资源

您需要 登录 才可以下载或查看，没有账号？注册

x

点评

xtjd
图元中心，创意无限  发表于 2024-7-24 14:07
回复 支持 1 反对 0

使用道具 举报

llsheng_73
发表于 2020-8-11 10:33:40 | 显示全部楼层
本帖最后由 llsheng_73 于 2020-8-11 16:00 编辑

建议 (osnap pt "_END,_CEN,_NOD,_QUA,_INS,_TAN,_EXT")根据当前的捕捉设置来
我把G版那个按我的习惯修改了一下，没有对正交等模式进行处理
  1. (defun dectobin(n m / c f);;十进制转二进制
  2.   (setq f(if(< n 0)1 0)n(abs n))
  3.   (while(>(setq c(cons(rem n 2)c)n(/ n 2))0))
  4.   (while(<(length c)(1- m))(setq c(cons 0 c)))
  5.   (cons f c))
  6. (DEFUN DrawVecs(Pt Vecs Size Color / xdir);;;G版函数绘制矢量
  7.   (setq xdir(getvar'ucsxdir)
  8.   Vecs(mapcar'(lambda(x)(mapcar'(lambda(a)(mapcar'+ pt(mapcar'*(setq a(trans a 0 xdir)a(list(caddr a)(car a)))(List size size))))x))Vecs))
  9.   (GRVECS(APPLY 'APPEND(MAPCAR 'CONS(MAPCAR(FUNCTION (LAMBDA (x)Color))Vecs)Vecs))))
  10. (defun myosnap(pt / p mode osmod osmode Draftobj Size);;;修改G版函数带捕捉grread
  11.   (if(setq Draftobj(VLA-GET-DRAFTING(VLA-GET-PREFERENCES(VLAX-GET-ACAD-OBJECT)))
  12.      osmod'("_END," "_MID," "_CEN," "_NOD," "_QUA," "_INT," "_INS," "_PER," "_TAN," "_NEA," "_NON," "_APP," "_EXT," "_PAR")
  13.      osmode(reverse(DECTOBIN (getvar'osmode) 1))
  14.      size(*(/(getvar "viewsize")(cadr(getvar "screensize")))(VLA-GET-AUTOSNAPMARKERSIZE Draftobj))
  15.      p(osnap pt(apply'strcat(mapcar'(lambda(x y)(if(zerop x)""y))osmode osmod)))
  16.      mode(CDR(ASSOC
  17.       (if p(vl-some'(lambda(x)(if(equal p(cdr x)1e-8)(car x)))
  18.              (vl-remove'nil(mapcar'(lambda(x y / p)(if(zerop x)nil(if(setq p(osnap pt y))(cons y p))))osmode osmod)))"_NON,")
  19.       '(("_END,"((-1 1)(-1 -1))((-1 -1)(1 -1))((1 -1) (1 1))((1 1) (-1 1)))
  20.         ("_MID,"((0 1.414) (-1.225 -0.707)) ((-1.225 -0.707)(1.225 -0.707))((1.225 -0.707) (0 1.414)))
  21.         ("_CEN,"((0 1) (-0.707 0.707))((-0.707 0.707)(-1 0))((-1 0) (-0.707 -0.707))((-0.707 -0.707)(0 -1))
  22.          ((0 -1)(0.707 -0.707))((0.707 -0.707)(1 0)) ((1 0) (0.707 0.707))((0.707 0.707) (0 1)))
  23.         ("_NOD,"((0 1) (-0.707 0.707))((-0.707 0.707)(-1 0))((-1 0)(-0.707 -0.707))((-0.707 -0.707)(0 -1))((0 -1)(0.707 -0.707))
  24.          ((0.707 -0.707)(1 0))((1 0)(0.707 0.707))((0.707 0.707)(0 1))((-1 1)(1 -1))((-1 -1)(1 1)))
  25.         ("_QUA,"((0 1.414)(-1.414 0))((-1.414 0)(0 -1.414))((0 -1.414)(1.414 0))((1.414 0)(0 1.414)))
  26.         ("_INT,"((-1 1)(1 -1))((-1 -1)(1 1))((1 0.859)(-0.859 -1))((-1 0.859)(0.859 -1))((0.859 1)(-1 -0.859))((-0.859 1)(1 -0.859)))
  27.         ("_INS,"((-1 1)(-1 -0.1))((-1 -0.1)(0 -0.1))((0 -0.1)(0 -1.0))((0 -1.0)(1 -1))
  28.          ((1 -1)(1 0.1))((1 0.1)(0 0.1))((0 0.1) (0 1.0))((0 1.0)(-1 1)))
  29.         ("_PER,"((-1 1)(-1 -1))((-1 -1)(1 -1))((0 -1)(0 0))((0 0)(-1 0)))
  30.         ("_TAN,"((0 1)(-0.707 0.707))((-0.707 0.707)(-1 0))((-1 0)(-0.707 -0.707))((-0.707 -0.707)(0 -1))
  31.          ((0 -1)(0.707 -0.707))((0.707 -0.707)(1 0))((1 0)(0.707 0.707))((0.707 0.707)(0 1))((1 1)(-1 1)))
  32.         ("_NEA,"((-1 1)(1 -1))((1 -1)(-1 -1))((-1 -1)(1 1))((1 1)(-1 1)))
  33.         ("_NON,")
  34.         ("_APP,"((-1 1)(-1 -1))((-1 -1)(1 -1))((1 -1)(1 1))((1 1)(-1 1))((-1 1)(1 -1))((-1 -1)(1 1)))
  35.         ("_EXT,"((0.1 0)(0.13 0))((0.2 0)(0.23 0))((0.3 0)(0.33 0)))
  36.         ("_PAR"((0 1)(-1 -1))((1 1)(0 -1)))))))
  37.     (DrawVecs(setq p(if p p pt))mode size(VLA-GET-AUTOSNAPMARKERCOLOR Draftobj)))
  38.   (if p p pt))
  39. (defun c:tt(/ e p) ;;选择一个圆进行移动
  40.   (while(setq e(ssget":E:S"'((0 . "circle"))))
  41.     (setq e(entget(ssname e 0)))
  42.     (while(/=(car(setq p(grread t 15 0)))3)(redraw)
  43.       (if(=(car p)5)(entmod(append e(list(cons 10(myosnap(cadr p)))))))
  44.       ))
  45.   )


回复 支持 1 反对 0

使用道具 举报

yoyoho
发表于 2017-12-25 16:42:52 | 显示全部楼层
本帖最后由 yoyoho 于 2017-12-25 16:47 编辑

感谢 langjs 分享程序!!!
但是在立体的物件貌似捕捉显示位置不正确,不知可否改善呢?

本帖子中包含更多资源

您需要 登录 才可以下载或查看，没有账号？注册

x
回复 支持 反对

使用道具 举报

yoyoho
发表于 2017-12-26 16:23:03 | 显示全部楼层
yoyoho 发表于 2017-12-25 16:42
感谢 langjs 分享程序!!!
但是在立体的物件貌似捕捉显示位置不正确,不知可否改善呢?

将2D点改3D点可以改善!
圆是不是捕捉不到啊!
回复 支持 反对

使用道具 举报

clh521
发表于 2017-12-27 08:25:23 | 显示全部楼层
谢谢，在2012和2018试过可以正确运行，收藏。
回复 支持 反对

使用道具 举报

fl202
发表于 2017-12-27 10:51:18 | 显示全部楼层
本帖最后由 fl202 于 2017-12-27 11:24 编辑

文字组码

组码

说明

100

子类标记 (AcDbText)

39

厚度（可选；默认值 = 0）

10

第一对齐点（在 OCS 中）
DXF：X 值；APP：三维点

20, 30

DXF：第一对齐点的 Y 值和 Z 值（在 OCS 中）

40

文字高度

1

默认值（字符串本身）

50

文字旋转角度（可选；默认值 = 0）

41

X 相对缩放比例宽度（可选；默认值 = 1）
使用拟合类型的文字时，该值也将进行调整。

51

倾斜角（可选；默认值 = 0）

7

文字样式名（可选；默认值 = 标准）

71

文字生成标志（可选；默认值 = 0）：
2 = 文字反向（在 X 轴方向镜像）
4 = 文字倒置（在 Y 轴方向镜像)

72

文字水平对正类型（可选；默认值 = 0）整数代码（非按位编码）
0 = 左对正；1 = 居中对正；2 = 右对正
3 = 对齐（如果垂直对齐 = 0）
4 = 中间（如果垂直对齐 = 0）
5 = 拟合（如果垂直对齐 = 0）
详细信息请参见组 72 和 73 整数代码表

11

第二对齐点（在 OCS 中）（可选）
DXF：X 值；APP：三维点
只有当 72 或 73 组的值非零时，该值才有意义（如果对正不是基线对正/左对正）

21, 31

DXF：第二对齐点的 Y 值和 Z 值（在 OCS 中）（可选）

210

拉伸方向（可选；默认值 = 0, 0, 1）
DXF：X 值；APP：三维矢量

220, 230

DXF：拉伸方向的 Y 值和 Z 值（可选）

100

子类标记 (AcDbText)

73

文字垂直对正类型（可选；默认值 = 0）：整数代码（非按位编码）：
0 = 基线对正；1 = 底端对正；2 = 居中对正；3 = 顶端对正
详细信息请参见组 72 和 73 整数代码表


下表详细说明了组码 72（水平对齐）和组码 73（垂直对齐）。
组 72 和 73 整数代码

组 73

组 72
0


1


2


3


4


5

3（顶端对正）

左上

中上

右上




2（居中对正）

左中

正中

右中




1（底端对正）

左下

中下

右下




0（基线对正）

左

中心

右

对齐

中间

拟合


如果组 72 和/或 73 值非零，则第一对齐点值被忽略，并且 AutoCAD 根据第二对齐点和文字字符串本身的长度和高度（在应用文字样式之后）计算新值。如果 72 和 73 值为零或缺失，则第二对齐点将没有意义。

不能捕捉圆心。
如果文字非左对齐时，楼主的测试程序会出错，文字不移动。
所以应该加入判断72/73组码是否非0语句，然后修改10或者11组码。
(if (and (= (cdr (assoc 72 ent)) 0) (= (cdr (assoc 73 ent)) 0) )
            (entmod (setq ent (subst(cons 10 pt)(assoc 10 ent)ent)))
            (entmod (setq ent (subst(cons 11 pt)(assoc 11 ent)ent)))
            )
谢谢楼主！
回复 支持 反对

使用道具 举报

yoyoho
发表于 2017-12-27 14:28:42 | 显示全部楼层
fl202 发表于 2017-12-27 10:51
下表详细说明了组码 72（水平对齐）和组码 73（垂直对齐）。
如果组 72 和/或 73 值非零，则第一对齐点 ...

感谢回覆!!!!
回复 支持 反对

使用道具 举报

尘缘一生
发表于 2018-2-3 17:02:19 | 显示全部楼层
郎大师：能提供个不要扑捉，只要正交功能的grread函数吗？
回复 支持 反对

使用道具 举报

张积乐
发表于 2018-3-30 19:18:28 | 显示全部楼层
正在寻找grread的捕捉，学习了
回复 支持 反对

使用道具 举报

nihaoya
发表于 2018-4-13 20:27:14 | 显示全部楼层
非常好，可以有动态引线吗，移动的橡皮筋效果
回复 支持 反对

使用道具 举报

evayleung
发表于 2018-5-30 21:12:41 | 显示全部楼层
很好很强大的功能，谢谢分享
回复 支持 反对

使用道具 举报

1234下一页
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码，在未取得本站及作者授权的情况下，不得用于商业用途

GMT+8, 2024-11-16 21:39 , Processed in 0.183641 second(s), 31 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表