明经CAD社区

 找回密码
 注册

QQ登录

只需一步,快速开始

搜索
查看: 1466|回复: 9

[提问] 悬赏做个移动的lisp

[复制链接]
发表于 2018-10-15 11:05 | 显示全部楼层 |阅读模式
10明经币
悬赏10个明经币
画三维图时在做正面,侧面图时标注经常会被挡住,有没有人可以做个快捷键,输入快捷键后布局里(因为标注时都是在布局里做的)的标注z方向会自动移动5000
附件: 您需要 登录 才可以下载或查看,没有账号?注册

最佳答案

查看完整内容

;;;方法一 (defun c:test1 (/ ss p1 p2) (if (setq ss (ssget '((0 . "DIMENSION")))) (progn (setq p1 (vlax-3d-point '(0 0 0)) p2 (vlax-3d-point (trans '(0 0 5000) 1 0)) ) (repeat (setq n (sslength ss)) (vla-move (vlax-ename->vla-object (ssname ss (setq n (1- n)))) p1 p2) ) ) ) (princ) ) ;;;方法二 (defun c:test2(/ ss mat) ;;; ...
发表于 2018-10-15 11:05 | 显示全部楼层
本帖最后由 pzweng 于 2018-10-15 12:08 编辑

;;;方法一
(defun c:test1 (/ ss p1 p2)
  (if (setq ss (ssget '((0 . "DIMENSION"))))
    (progn
      (setq p1 (vlax-3d-point '(0 0 0))
            p2 (vlax-3d-point (trans '(0 0 5000) 1 0))
      )
      (repeat (setq n (sslength ss))
        (vla-move (vlax-ename->vla-object (ssname ss (setq n (1- n)))) p1 p2)
      )
    )
  )
  (princ)
)


;;;方法二
(defun c:test2(/ ss mat)
;;;---------------=={ Translate by Matrix }==-----------------;;
;;;                                                           ;;
;;; Translation Matrix                                        ;;
;;;-----------------------------------------------------------;;
;;; Author: highflybird, Copyright ? 2012                     ;;
;;;-----------------------------------------------------------;;
;;; Arguments:                                                ;;
;;; p1, p2 - Points representing vector by which to translate ;;
;;;-----------------------------------------------------------;;
(defun MAT:TranslateBy2P ( p1 p2 )
  (MAT:Translation (mapcar '- p2 p1))
)
;;;---------------=={ Translate by Matrix }==-----------------;;
;;;                                                           ;;
;;; Translation Matrix                                        ;;
;;;-----------------------------------------------------------;;
;;; Author: highflybird, Copyright ? 2012                     ;;
;;;-----------------------------------------------------------;;
;;; Arguments:                                                ;;
;;; v  - Displacement vector by which to translate            ;;
;;;-----------------------------------------------------------;;
(defun mat:translation (v)
  (list
    (list 1. 0. 0. (car v))
    (list 0. 1. 0. (cadr v))
    (list 0. 0. 1. (caddr v))
    (list 0. 0. 0. 1.)
  )
)
  ;;;ss->vla
(defun lm:ss->vla (ss)
  (if ss
    ((lambda (i / e l)
       (while (setq e (ssname ss (setq i (1+ i))))
         (setq l (cons (vlax-ename->vla-object e) l))
       )
       l
     )
      -1
    )
  )
)
  (if (setq ss (ssget '((0 . "DIMENSION"))))
    (progn
      (setq mat (vlax-tmatrix (mat:translateby2p '(0 0 0) (trans '(0 0 5000) 1 0))))
      (mapcar '(lambda (x) (vla-transformby x mat)) (lm:ss->vla ss))
    )
  )
  (princ)
)


回复

使用道具 举报

发表于 2018-10-15 12:13 | 显示全部楼层
版主出手 代码我有
回复

使用道具 举报

 楼主| 发表于 2018-10-15 14:01 | 显示全部楼层
本帖最后由 fgsyql 于 2018-10-15 14:06 编辑
pzweng 发表于 2018-10-15 12:00
;;;方法一
(defun c:test1 (/ ss p1 p2)
  (if (setq ss (ssget '((0 . "DIMENSION"))))

谢谢版主
差不多是这样了
但有一点能不能改进一下
这个是以视图为基础,如果是以坐标为基础就不行了,比如视图是西南等轴测方向,坐标调成xm方向时就不能用
还有能不能命令输入后布局内的标注全问移动,而不用再去选中标注C:\Users\F\Desktop\QQ截图20181015135911.png

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

x
回复

使用道具 举报

发表于 2018-10-16 08:57 | 显示全部楼层
fgsyql 发表于 2018-10-15 14:01
谢谢版主
差不多是这样了
但有一点能不能改进一下

(defun c:test2 (/ ss)
;;;---------------=={ Translate by Matrix }==-----------------;;
;;;                                                           ;;
;;; Translation Matrix                                        ;;
;;;-----------------------------------------------------------;;
;;; Author: highflybird, Copyright ? 2012                     ;;
;;;-----------------------------------------------------------;;
;;; Arguments:                                                ;;
;;; p1, p2 - Points representing vector by which to translate ;;
;;;-----------------------------------------------------------;;
  (defun mat:translateby2p (p1 p2)
    (mat:translation (mapcar '- p2 p1))
  )
;;;---------------=={ Translate by Matrix }==-----------------;;
;;;                                                           ;;
;;; Translation Matrix                                        ;;
;;;-----------------------------------------------------------;;
;;; Author: highflybird, Copyright ? 2012                     ;;
;;;-----------------------------------------------------------;;
;;; Arguments:                                                ;;
;;; v  - Displacement vector by which to translate            ;;
;;;-----------------------------------------------------------;;
  (defun mat:translation (v)
    (list
      (list 1. 0. 0. (car v))
      (list 0. 1. 0. (cadr v))
      (list 0. 0. 1. (caddr v))
      (list 0. 0. 0. 1.)
    )
  )
;;;ss->vla
  (defun lm:ss->vla (ss)
    (if ss
      ((lambda (i / e l)
         (while (setq e (ssname ss (setq i (1+ i))))
           (setq l (cons (vlax-ename->vla-object e) l))
         )
         l
       )
        -1
      )
    )
  )
  (if (setq ss (ssget "x" '((0 . "DIMENSION"))))
    (mapcar '(lambda (x / mat)
               (setq mat (vlax-tmatrix (mat:translateby2p '(0 0 0) (trans '(0 0 5000) (vlax-vla-object->ename x) 0))))
               (vla-transformby x mat)
             )
            (lm:ss->vla ss)
    )
  )
  (princ)
)
回复

使用道具 举报

 楼主| 发表于 2018-10-19 09:52 | 显示全部楼层
本帖最后由 fgsyql 于 2018-10-19 09:56 编辑
fgsyql 发表于 2018-10-15 14:01
谢谢版主
差不多是这样了
但有一点能不能改进一下

布局内移动的可能比较说不清楚,我还是用第一次写的那个需要选中的,但用了几天发觉好像是跟坐标有关,很多时候还是不能用,会跑偏,有时会有时不会还没发现跑偏的规律.
回复

使用道具 举报

发表于 2018-12-6 06:09 | 显示全部楼层
快捷键  za  Z轴归零
(defun c:za()
   (setvar "cmdecho" 0)
   (setvar "blipmode" 0)
   (graphscr)
   (prompt "Z向归零:") (terpri)

   (princ "请选择要归零的实体")
   (setq s (ssget))
   (setq len (sslength s))
   (setq index 0)

   (repeat len
      (setq a (entget (ssname s index)))

      (setq b10 (assoc 10 a))
      (setq b11 (assoc 11 a))

      (setq x10 (cadr b10))
      (setq y10 (caddr b10))

      (setq x11 (cadr b11))
      (setq y11 (caddr b11))

      (setq b101 (cons 10 (list x10 y10 0)))
      (setq b111 (cons 11 (list x11 y11 0)))

      (setq a (subst b101 b10 a))
      (entmod a)
      (setq a (subst b111 b11 a))
      (entmod a)

      (setq index (+ index 1))
   )
   (princ "成功")
   (princ)
)
回复

使用道具 举报

发表于 2018-12-7 14:08 | 显示全部楼层
说好的币要记得给啦!!
回复

使用道具 举报

 楼主| 发表于 2018-12-23 22:18 | 显示全部楼层
KO你 发表于 2018-12-6 06:09
快捷键  za  Z轴归零
(defun c:za()
   (setvar "cmdecho" 0)

尺寸会置在最前面,但尺寸线会变高或变低,这样做完的话还得重新去拉尺寸线

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有账号?注册

x
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码,在未取得本站及作者授权的情况下,不得用于商业用途

GMT+8, 2024-3-29 00:36 , Processed in 0.325258 second(s), 27 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表