求: 标注文字镜像后文字与引线对齐关系相应改变

fengyu6913 · 发表于 2018-11-8 23:03

本帖最后由 fengyu6913 于 2018-11-9 12:08 编辑

如上图（单行文字与引线没有关联），左边文字与引线是右中对齐关系，镜像后变成右边这样，文字与引线是左中对齐关系，

nzl1116 · 发表于 2018-11-8 23:03

(vl-load-com)
(defun c:ttt (/ Pt0 Pt1 Pt2 Pt3 Lst Len Mir Ali)
(princ "\n框选镜像对象")
(and
(setq sss (ssget))
(setq Pt0 (getpoint "\n指定镜像线的第一点"))
(setq Pt1 (getpoint Pt0 "\n指定镜像线的第二点"))
(progn
(setq Lst nil)
(repeat (setq Len (sslength sss))
(setq Lst (cons (ssname sss (setq Len (1- Len))) Lst))
)
(setq sss nil)
(setq Lst (mapcar 'vlax-ename->vla-object Lst))
(setq Pt0 (vlax-3d-point Pt0))
(setq Pt1 (vlax-3d-point Pt1))
(foreach Obj Lst
(setq Mir (vla-Mirror Obj Pt0 Pt1))
(and
(= (vla-get-ObjectName Obj) "AcDbText")
(setq Ali (assoc (vla-get-Alignment Obj) '((0 . 2) (2 . 0) (6 . 8) (8 . 6) (9 . 11) (11 . 9) (12 . 14) (14 . 12))))
(progn
(setq Pt2 (vla-get-InsertionPoint Mir))
(vla-put-Alignment Mir (cdr Ali))
(setq Pt3 (vla-get-InsertionPoint Mir))
(vla-move Mir Pt3 Pt2)
)
)
)
)
)
(princ)
)

(vl-load-com) 
(defun c:ttt (/ Pt0 Pt1 Pt2 Pt3 Lst Len Mir Ali) 
  (princ "\n框选镜像对象") 
  (and 
    (setq sss (ssget)) 
    (setq Pt0 (getpoint "\n指定镜像线的第一点")) 
    (setq Pt1 (getpoint Pt0 "\n指定镜像线的第二点")) 
    (progn 
      (setq Lst nil) 
      (repeat (setq Len (sslength sss)) 
        (setq Lst (cons (ssname sss (setq Len (1- Len))) Lst)) 
      ) 
      (setq sss nil) 
      (setq Lst (mapcar 'vlax-ename->vla-object Lst)) 
      (setq Pt0 (vlax-3d-point Pt0)) 
      (setq Pt1 (vlax-3d-point Pt1)) 
      (foreach Obj Lst 
        (setq Mir (vla-Mirror Obj Pt0 Pt1)) 
        (and 
          (= (vla-get-ObjectName Obj) "AcDbText") 
          (setq Ali (assoc (vla-get-Alignment Obj) '((0 . 2) (2 . 0) (6 . 8) (8 . 6) (9 . 11) (11 . 9) (12 . 14) (14 . 12)))) 
          (progn 
            (setq Pt2 (vla-get-InsertionPoint Mir)) 
            (vla-put-Alignment Mir (cdr Ali)) 
            (setq Pt3 (vla-get-InsertionPoint Mir)) 
            (vla-move Mir Pt3 Pt2) 
          ) 
        ) 
      ) 
    ) 
  ) 
  (princ) 
)

fengyu6913 · 发表于 2018-11-9 10:21

本人不会LISP编程，能开发的可以留下联系方式，可以再商量!

start4444 · 发表于 2018-11-9 11:05

本帖最后由 start4444 于 2018-11-9 11:07 编辑

cad 引线标准镜像之后默认就是这样的，把mirrtext设成0值

fengyu6913 · 发表于 2018-11-9 12:00

start4444 发表于 2018-11-9 11:05
cad 引线标准镜像之后默认就是这样的，把mirrtext设成0值

我用的引线与文字不是关联的，是单行文字，你说的是针对多行文字。我不习惯用多行文字

vectra · 发表于 2018-11-9 13:39

本帖最后由 vectra 于 2018-11-9 20:07 编辑

要有例图看不懂哪里需要编程
在我的cad上镜相之后，默认就是右中变成左中对齐了

tranney · 发表于 2018-11-9 19:32

我的方法是分2步，第一步，镜像，第2步框选文字检查，如果是左对齐的换为右对齐，如果是右对齐的则换为左对齐

fengyu6913 · 发表于 2018-11-10 02:15

nzl1116 发表于 2018-11-8 23:03

经验证，大神的程序达到预期效果，非常感谢！

czb203 · 发表于 2018-11-11 15:56

经验证，大神的程序达到预期效果

fengyu6913 · 发表于 2018-11-13 14:41

nzl1116 发表于 2018-11-8 23:03

大神，能否将程序加一个 “要删除源对象吗？[是(Y)/否(N)] <N>:” 的选项，做成跟原来的“镜像”命令那样。

账号		自动登录	找回密码
密码			注册

[提问] 求: 标注文字镜像后文字与引线对齐关系相应改变

最佳答案