利用递归求表内元素全排列

陨落

利用递归计算全排列源码
递归真的是有意思的东西，循环实现不了的，它能实现
(defun perm(lst / ret res);;;lst--任意表
  (cond ((null lst)nil)
        ((null(cdr lst))lst)
        (t
(foreach x lst
  (setq ret(mapcar '(lambda(e)
                      (if (listp e)
                      (cons x e)
                        (list x e))
                      )(perm(vl-remove x lst))))
  (if (listp ret)
    (setq res (append res ret))
  (setq res (list ret res))
    )

    )))
  )

kkq0305

(defun        per (lst)
   (if (cdr lst)
     (apply
       'append
       (mapcar
         '(lambda (x)
            (mapcar '(lambda (y) (cons x y)) (per (vl-remove x lst)))
          )
         lst
       )
     )
     (list lst)
   )
)

ssyfeng

就是速度有点慢，超过了7个元素就不行了

陨落

ssyfeng 发表于 2019-4-13 21:13
就是速度有点慢，超过了7个元素就不行了

应该是lisp性能限制了

lanjqka

谢谢分享
改了一点点
(defun perm (L)
  (cond
    ((null L) nil)
    ((null (cdr L)) (list L))
    (t
     (apply
       'append
       (mapcar (function (lambda (x)
                           (mapcar (function (lambda (y) (cons x y)))
                                   (perm (vl-remove x L))
                           )
                         )
               )
               L
       )
     )
    )
  )
)

tigcat

lanjqka 发表于 2021-8-27 14:41
谢谢分享
改了一点点
(defun perm (L)

(perm '(1 1 3 5 2))少了一个元素

tigcat

(perm '(1 1 3 5 2))少了一个元素