炸开问价 图形随层

孙玉坤

我不懂编程   这个也是在明经下载的   就是炸开文字后  多段线会自动到 当前层长  ，我想把它改成无论当前层是那一个图形 ，炸开文字的多段线 都是（017划线）这个图层名，颜色为白色，求那个大神帮忙给修改一下。万分感谢

Andyhon

先配置好 017划线 图层
(defun c:xpp (/ PtList)
  (setvar "cmdecho" 0)
  (setvar "osmode" 15359)
(setvar "clayer" "017划线")
  ...
)

非常规捷略法

孙玉坤

Andyhon 发表于 2019-5-30 11:12
先配置好 017划线 图层
(defun c:xpp (/ PtList)
  (setvar "cmdecho" 0)

非常感谢老师的帮助 ，我的意思是上面的代码 炸开文字后  ， 无论文字在什么图层上， 或者当前层是什么图层，文字炸开后 自己归到017划线图层，  一个命令两个功能

Andyhon

请上传不能 归到017划线图层 的Dwg样例

wen1235

;;;*****分解文字 程序开始*****
(defun c:xpp (/ PtList)
  (setvar "cmdecho" 0)
  (setvar "osmode" 15359)
  (princ "\n★功能：将文字分解为曲线。\n提示：若出现变变换错误，请先将UCS设置为默认。\n")
  (command "undo" "be")
  (princ "\n请选取要分解为曲线的文字：")
  (setq ss (ssget '((0 . "TEXT,MTEXT"))))
  (if (not ss)
    (progn (princ "\n提示：未选中文字，程序退出！\n") (exit))
  )
  (setvar "mirrtext" 1)
  (setvar "osmode" 0)
  (setq i 0 pent (entlast) newss (ssadd))
  (repeat (setq num (sslength ss))
    (setq entnam (ssname ss i))
    (command "zoom" "o" entnam "")
    (setq PixelSize  (getvar "screensize") ;以像素为单位读取当前视口大小（X 和 Y）
          ViewHeigh  (getvar "viewsize") ;以图形单位测量当前视口中显示的视图的高度
          ViewCenter (getvar "viewctr") ;以UCS坐标表示当前视口中的视图的中心
          PtList     (list (list (- (car ViewCenter) (* 0.5 (* ViewHeigh (/ (car PixelSize) (cadr PixelSize)))))
                                 (- (cadr ViewCenter) (* 0.5 ViewHeigh))
                           ) ;视窗区左下角的坐标点
                           (list (+ (car ViewCenter) (* 0.5 (* ViewHeigh (/ (car PixelSize) (cadr PixelSize)))))
                                 (+ (cadr ViewCenter) (* 0.5 ViewHeigh))
                           ) ;视窗区右上角的坐标点
                     )
          LTPoint    (list (caar PtList) ;视窗区左下角的X坐标
                           (cadadr PtList) ;视窗区右上角的Y坐标
                     )
    )
    (setq TempFil (strcat (getenv "Temp") "\\textb.wmf"))
    (command "mirror" entnam "" ViewCenter "@0,1" "y") ;以Y轴镜像
    (command "wmfout" TempFil entnam "" "erase" entnam "" "wmfin" TempFil LTPoint "2.0" "" "")
    (command "mirror" (entlast) "" ViewCenter "@0,1" "y") ;以Y轴镜像
    (setq entnam2 (vlax-ename->vla-object (entlast)))
    (setq list1        (vlax-safearray->list (vlax-variant-value (vla-explode entnam2)))
          list2        nil
          list3        nil
    )
    (foreach entnam3 list1
      (if (eq (vla-get-ObjectName entnam3) "AcDbLine")
        (progn (setq entnam41 (vlax-curve-getpointatparam entnam3 (/ (vlax-curve-getendparam entnam3) 2.0))
                     entnam42 (strcat (rtos (car entnam41) 2 8) (rtos (cadr entnam41) 2 8))
               )
               (if (setq entnam43 (assoc entnam42 list3))
                 (progn (vla-delete entnam3) (vla-delete (cadr entnam43)))
                 (setq list3 (cons (list entnam42 entnam3) list3))
               )
        )
        (progn (setq list2 (append (vlax-safearray->list (vlax-variant-value (vla-explode entnam3))) list2))
               (vla-delete entnam3)
        )
      )
    )
    (foreach entnam3 list2
      (if (eq (vla-get-length entnam3) 0.0)
        (if (not (vlax-erased-p entnam3))
          (vla-delete entnam3)
        )
        (progn (setq entnam41 (vlax-curve-getstartpoint entnam3)
                     entnam42 (strcat (rtos (car entnam41) 2 8) (rtos (cadr entnam41) 2 8))
                     entnam41 (vlax-curve-getendpoint entnam3)
                     entnam44 (strcat entnam42 (rtos (car entnam41) 2 8) (rtos (cadr entnam41) 2 8))
                     entnam45 (strcat (rtos (car entnam41) 2 8) (rtos (cadr entnam41) 2 8) entnam42)
               )
               (if (or (setq entnam43 (assoc entnam44 list3)) (setq entnam43 (assoc entnam45 list3)))
                 (progn        (if (not (vlax-erased-p entnam3))
                          (vla-delete entnam3)
                        )
                        (if (not (vlax-erased-p (cadr entnam43)))
                          (vla-delete (cadr entnam43))
                        )
                 )
                 (setq list3 (cons (list entnam44 entnam3) list3))
               )
        )
      )
    )
    (vla-delete entnam2)
    (setq i (1+ i))
    (command "zoom" "p")
    (vl-file-delete TempFil)
  )
  (while (setq e (entnext pent)) (setq newss (ssadd e newss) pent e))
  (if (> (sslength newss) 0) (command "_change" newss "" "p" "lay" "017划线" ""))
  (setvar "mirrtext" 0)
  (setvar "osmode" 15359)
  (command "undo" "e")
  (princ (strcat "\n提示：共将" (itoa num) "个文字对象成功分解为曲线。\n"))
  (princ)
)
;;;*****分解文字 程序结束*****

孙玉坤

wen1235 发表于 2019-5-31 16:37
;;;*****分解文字 程序开始*****
(defun c:xpp (/ PtList)
  (setvar "cmdecho" 0)

非常感谢  就是要这样的效果

孙玉坤

wen1235 发表于 2019-5-31 16:37
;;;*****分解文字 程序开始*****
(defun c:xpp (/ PtList)
  (setvar "cmdecho" 0)

就是颜色不是白色   我修改一下就是修改不好

yangchao2005090

          (if (= (tblsearch "Layer" "017划线") nil) ;;新建图层
                (command "-Layer" "new" "017划线" "color" "1" "017划线" "p" "n" "017划线" "")
        )

funny64

狠好！！！！！！！