LISP运行出错，求各大神帮忙解决，谢谢！

paulpipi · 发表于 2019-7-15 23:45

请教各位大神，下面这个LISP为什么在 CAD2008中运行会出错，而低版本就没有问题，望不吝赐教，谢谢！
(defun c:HDZ()  ;本程序绘制导柱孔用(不带油孔)
   (setq r (getreal "\n输入导柱孔直径:"))
   (setq p1 (getpoint "\n选取导柱孔中心生成位置:"))
   (while (/= p1 nil ) ;此语句是定义连续画下一个物体用的
   (setq p1x (car p1))
   (setq p1y (cadr p1))
   (setq pax (+ p1x (/ r 2)))
   (setq pby (- P1y (/ r 2)))
   (setq pcy (+ p1y (/ r 2)))
   (setq pa (list p1x pby))
   (setq Pb (list p1x pcy))
   (setq Pc (list pax pcy))
   (setq pdx (- p1x (/ r 2.82885)))
   (setq pey (+ p1y (/ r 2.82885)))
   (setq pfy (- p1y (/ r 2.82885)))
   (setq p2y (- p1y (/ r 4)))
   (setq p3y (+ p1y (/ r 4)))
   (setq pd (list pdx pey))
   (setq pe (list pdx pfy))
   (setq pf (list p1x p2y))
   (setq pg (list p1x p3y))
(command "zoom" "c" p1 "30")
(command "circle" p1 (/ r 2))
(command "line" "none" pa "none" pb "")
(command "trim" "none" pf "none" pg "" "none" pd "none" pe "")
(command "hatch" "u,n" 45 0.3 "" "w" "none" pa "none" pc "")
(COMMAND "CHPROP" "w" "none" pa "none" pc "" "la" "0" "")
(COMMAND "PEDIT" "w" pa pb "" "J" "W" PA Pc "" "")
(command "erase" "l" "")
(command "circle" p1 (/ r 2))
(command "zoom" "p")
   (princ)
   (setq p1 (getpoint "\n选取导柱孔中心生成位置:"))
   ))

paulpipi · 发表于 2019-7-16 07:24

急等高人解决，谢谢！

fangmin723 · 发表于 2019-7-16 07:34

本帖最后由 fangmin723 于 2019-7-16 07:39 编辑

paulpipi 发表于 2019-7-16 07:24
急等高人解决，谢谢！

最好注释一下，上传图片加以说明！

paulpipi · 发表于 2019-7-16 07:49

D:\123

paulpipi · 发表于 2019-7-16 07:50

执行到一半就不行了，看图片

bssurvey · 发表于 2019-7-16 08:31

應該是 (command "trim" "none" pf "none" pg "" "none" pd "none" pe "")
多了 pe ，因為在PD時已完成裁剪，再做pe會選不到物件。

yshf · 发表于 2019-7-16 09:35

本帖最后由 yshf 于 2019-7-16 09:36 编辑

;试用如下程序
(defun c:HDZ1()  ;本程序绘制导柱孔用(不带油孔)
(setq cmd (getvar "cmdecho"))
(setq osm (getvar "osmode"))
(setvar "cmdecho" 0)
(setvar "osmode" 0)
(setq D (getreal "\n输入导柱孔直径:"))
(setq r (* 0.5 D)) ;孔半径
(while (setq p1 (getpoint "\n选取导柱孔中心生成位置<回车结束>:"))
      (setq pa (mapcar '- p1 (list 0 r 0))) ;孔最低点
      (setq pb (mapcar '+ p1 (list 0 r 0))) ;孔最高点
      (setq pc (mapcar '+ p1 (list r 0 0))) ;孔最右侧点
      (command "_circle" p1 r) ;画孔
      (command "_pline" pa pb "a" "s" pc pa "cl") ;画填充边界线
      (setq ent (entlast)) ;填充边界线
      (command "_hatch" "u,n" 45 0.3 "" ent "") ;填充
      (entdel ent) ;删除填充边界线
)
(setvar "osmode" osm)
(setvar "cmdecho" cmd)
(princ)
)

烟盒迷唇 · 发表于 2019-7-16 20:00

最笨的办法，单独拿出每个COMMAND函数在2008里检查看哪里出错了

1291500406 · 发表于 2019-7-17 10:54

本帖最后由 1291500406 于 2019-7-17 11:36 编辑

(defun c:HDZ()
(setq r (getreal "\n输入导柱孔直径:"))
(setq p1 (getpoint "\n选取导柱孔中心生成位置:"))
(while (/= p1 nil )
(setq p1x (car p1))
(setq p1y (cadr p1))
(setq pax (+ p1x (/ r 2)))
(setq pby (- P1y (/ r 2)))
(setq pcy (+ p1y (/ r 2)))
(setq pa (list p1x pby))
(setq Pb (list p1x pcy))
(setq Pc (list pax pcy))
(setq pdx (- p1x (/ r 2.82885)))
(setq pey (+ p1y (/ r 2.82885)))
(setq pfy (- p1y (/ r 2.82885)))
(setq p2y (- p1y (/ r 4)))
(setq p3y (+ p1y (/ r 4)))
(setq pd (list pdx pey))
(setq pe (list pdx pfy))
(setq pf (list p1x p2y))
(setq pg (list p1x p3y))
(command "zoom" "c" p1 "30")
(command "circle" p1 (/ r 2.0))(setq bb (entlast))
(command "line" "none" pa "none" pb "")
(command "_trim" "l"  ""  bb "" )
(command "hatch" "u,n" 45 0.3 "" "w" "none" pa "none" pc "")
(COMMAND "CHPROP" "w" "none"  pa  "none" pc "" "la" "0" "")
(COMMAND "PEDIT" "w" pa pb "" "J" "W" PA Pc "" "")
(command "erase" "l" "")
(command "circle" p1 (/ r 2.0))
(command "zoom" "p")
(setq p1 (getpoint "\n选取导柱孔中心生成位置:")))(princ))

账号		自动登录	找回密码
密码			注册

[提问] LISP运行出错，求各大神帮忙解决，谢谢！

本帖子中包含更多资源

点评

点评