(讨论)关于三维面对齐二维平面XY轴

999999 · 发表于 2020-8-21 11:09:02

本帖最后由 999999 于 2021-5-21 18:01 编辑

求助想法：1.把三维的XYZ生成的面,识别其坐标点，使其三维面的大小展开对齐为二维XY轴平面并且长宽高不变（能够实现框选最好）
2.如果生成二维XY轴面后，Z轴不为0则使其归零
3.生成二维XY轴面且Z轴归零后，则三维线段转为二维线段并合并

夏生生 · 发表于 2020-8-21 11:09:03

本帖最后由夏生生于 2022-10-27 08:12 编辑

老帖子了，正好看到，搞了一下，试试

;;;向量相关函数来自明经网友高飞鸟
(defun c:tt (/ lst pt pt1 pt2 pt3 ss v v1 v2)
(defun xty-tr-ss2lst (ss form / n en lst)
(repeat (setq n (sslength ss))
(setq en (ssname ss (setq n (1- n))))
(setq lst (cons en lst))
)
(setq lst (reverse lst))
(if form
lst
(mapcar (function vlax-ename->vla-object) lst)
)
)
(defun xty-vec-v*v (v1 v2)
(mapcar (function *) v1 v2)
)
(defun xty-vec-vxs (v sc)
(mapcar (function (lambda (n) (* n sc))) v)
)
(defun xty-vec-vxv (u v)
(list
(- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))
(- (* (car v) (caddr u)) (* (car u) (caddr v)))
(- (* (car u) (cadr v)) (* (car v) (cadr u)))
)
)
(defun xty-vec-norm (v)
(sqrt (apply (function +) (xty-vec-v*v v v)))
)
(defun xty-vec-unit (v / norm)
(setq norm (xty-vec-norm v))
(cond ((= 1. norm) v)
((> norm 1e-14) (xty-vec-vxs v (/ 1. norm)))
((equal 0. norm 1e-14) nil)
)
)
(defun xty-vec-DispToMatrix (mat disp)
(append
(mapcar 'append mat (mapcar 'list disp))
'((0. 0. 0. 1.))
)
)
(defun xty-vec-Trans (from to)
(xty-vec-DispToMatrix
(mapcar
(function (lambda (v) (trans v from to t)))
'((1. 0. 0.) (0. 1. 0.) (0. 0. 1.))
)
(trans '(0 0 0) to from)
)
)
(setq ss (ssget '((0 . "*polyline")))
lst (xty-tr-ss2lst ss nil)
pt (getpoint "\n插入点:")
)
(foreach en lst
(setq en (vla-copy en)
pt1 (vlax-curve-getstartpoint en)
pt2 (vlax-curve-getpointatparam en 1)
pt3 (vlax-curve-getpointatparam en 2)
v1 (mapcar '- pt2 pt1)
v2 (mapcar '- pt3 pt1)
v (xty-vec-unit (xty-vec-vxv v1 v2))
)
(vla-TransformBy
en
(vlax-tmatrix (xty-vec-Trans v '(0 0 1)))
)
(vla-getboundingbox en 'pt1 'pt2)
(vla-move en
pt1
(vlax-3d-point pt)
)
(vla-getboundingbox en 'pt1 'pt2)
(setq pt (list (car (vlax-safearray->list pt2))
(cadr (vlax-safearray->list pt1))
(caddr (vlax-safearray->list pt1))
)
)
)
)

;;;向量相关函数来自明经网友高飞鸟 
(defun c:tt (/ lst pt pt1 pt2 pt3 ss v v1 v2) 
  (defun xty-tr-ss2lst (ss form / n en lst) 
    (repeat (setq n (sslength ss)) 
      (setq en (ssname ss (setq n (1- n)))) 
      (setq lst (cons en lst)) 
      ) 
    (setq lst (reverse lst)) 
    (if  form 
      lst 
      (mapcar (function vlax-ename->vla-object) lst) 
      ) 
    ) 
(defun xty-vec-v*v (v1 v2) 
  (mapcar (function *) v1 v2) 
) 
 
  (defun xty-vec-vxs (v sc) 
    (mapcar (function (lambda (n) (* n sc))) v) 
    ) 
  (defun xty-vec-vxv (u v) 
    (list 
      (- (* (cadr u) (caddr v)) (* (cadr v) (caddr u))) 
      (- (* (car v) (caddr u)) (* (car u) (caddr v))) 
      (- (* (car u) (cadr v)) (* (car v) (cadr u))) 
      ) 
    ) 
  (defun xty-vec-norm (v) 
    (sqrt (apply (function +) (xty-vec-v*v v v))) 
    ) 
  (defun xty-vec-unit (v / norm) 
    (setq norm (xty-vec-norm v)) 
    (cond ((= 1. norm) v) 
    ((> norm 1e-14) (xty-vec-vxs v (/ 1. norm))) 
    ((equal 0. norm 1e-14) nil) 
    ) 
    ) 
  (defun xty-vec-DispToMatrix  (mat disp) 
  (append 
    (mapcar 'append mat (mapcar 'list disp)) 
    '((0. 0. 0. 1.)) 
  ) 
) 
  (defun xty-vec-Trans (from to) 
  (xty-vec-DispToMatrix 
    (mapcar 
      (function (lambda (v) (trans v from to t))) 
      '((1. 0. 0.) (0. 1. 0.) (0. 0. 1.)) 
    ) 
    (trans '(0 0 0) to from) 
  ) 
) 
  (setq  ss  (ssget '((0 . "*polyline"))) 
  lst (xty-tr-ss2lst ss nil) 
  pt  (getpoint "\n插入点:") 
  ) 
  (foreach en lst 
    (setq en  (vla-copy en) 
    pt1 (vlax-curve-getstartpoint en) 
    pt2 (vlax-curve-getpointatparam en 1) 
    pt3 (vlax-curve-getpointatparam en 2) 
    v1  (mapcar '- pt2 pt1) 
    v2  (mapcar '- pt3 pt1) 
    v   (xty-vec-unit (xty-vec-vxv v1 v2)) 
    ) 
    (vla-TransformBy 
      en 
      (vlax-tmatrix (xty-vec-Trans v '(0 0 1))) 
      ) 
    (vla-getboundingbox en 'pt1 'pt2) 
    (vla-move en 
        pt1 
        (vlax-3d-point pt) 
        ) 
    (vla-getboundingbox en 'pt1 'pt2) 
    (setq pt (list (car (vlax-safearray->list pt2)) 
       (cadr (vlax-safearray->list pt1)) 
       (caddr (vlax-safearray->list pt1)) 
       ) 
    ) 
    ) 
  )

纵横八方 · 发表于 2020-10-17 08:14:23

我写过哦哦，不过你要考虑正反面的问题哦，比如垂直的面，正面和反面是对称的关系

999999 · 发表于 2020-10-17 20:10:10

纵横八方发表于 2020-10-17 08:14
我写过哦哦，不过你要考虑正反面的问题哦，比如垂直的面，正面和反面是对称的关系

表示没有理解到意思，，是我想的比较简单可能

kwok · 发表于 2020-10-18 14:06:36

自带的命令Align,,三点对齐。可以弄lsp简化操作，如取3d曲面的3个点后，直接在指点一个点上放平.
3d曲面几个顶点不一定在一个平面，所以放平后还要踏平一下.

999999 · 发表于 2020-10-18 17:56:02

kwok 发表于 2020-10-18 14:06
自带的命令Align,,三点对齐。可以弄lsp简化操作，如取3d曲面的3个点后，直接在指点一个点上放平.
3d曲面 ...

对的，，，要是三维的三条边可以用LSP解决生成对齐二维的两个X一个Y轴就好了，

mokson · 发表于 2020-10-18 17:57:51

AL命令可以达到要求。

999999 · 发表于 2020-10-21 11:33:45

mokson 发表于 2020-10-18 17:57
AL命令可以达到要求。

这个我知道呀，就是我想把布棸简单一些

纵横八方 · 发表于 2021-4-26 18:54:51

比如一个直角梯形片体如果垂直立着的，你对齐到平面会有两种结果，一种是左视图看到的一种也可以是右视图看到的

999999 · 发表于 2021-4-27 16:46:29

纵横八方发表于 2021-4-26 18:54
比如一个直角梯形片体如果垂直立着的，你对齐到平面会有两种结果，一种是左视图看到的一种也可以 ...

我右边的视图是三维视图，然后，左边的是二维的，三维的三个点，对齐二维的三个点，变成了二维平面

账号		自动登录	找回密码
密码			注册

[提问] (讨论)关于三维面对齐二维平面XY轴

最佳答案

本帖子中包含更多资源