关于选择屏幕外的对象（附图）

669423907

请教一个问题：
(defun c:13(/ p1 p2)
(sssetfirst)
(setq p1 (getpoint (strcat "\n请指定框选第一点：")) )
(setq p2 (getcorner p1 (strcat "\n请指定框选第一点：")) )
(sssetfirst nil (XY框选 p1 p2 ()) )
)

;屏幕外框选 wangyonggao8 2018-6-30 file:///C:\Users\ADMINI~1\AppData\Local\Temp\%W@GJ$ACOF(TYDYECOKVDYB.pnghttp://bbs.mjtd.com/forum.php?mod=viewthread&tid=177750&highlight=ssget
;(XY框选 (getpoint) (getpoint) '((0 . "insert")))
(defun XY框选(d1 d2 filter / minX minY maxX maxY)
(setq  minX (min (car d1) (car d2))
    minY (min (cadr d1) (cadr d2))
    maxX (max (car d1) (car d2))
    maxY (max (cadr d1) (cadr d2))
)
(if filter
  (ssget "x"
     (append (list '(-4 . "<and")
           '(-4 . ">=,>=,*")
           (list 10 minX minY 0)
           '(-4 . "<=,<=,*")
           (list 10 maxX maxY 0)
         )
         (append filter '((-4 . "and>")))
     )
  )
  (ssget "x"
     (list '(-4 . "<and")
       '(-4 . ">=,>=,*")
       (list 10 minX minY 0)
       '(-4 . "<=,<=,*")
       (list 10 maxX maxY 0)
       '(-4 . "and>")
     )
  )
)
)

以上程序，可以选到屏幕外的对象，但我发现有一个问题，在什么都没有选中的时候，它却自动选中了一个矩形框（如图）

masterlong

;999返回当前视窗左下角和右上角 坐标
(defun viewbox(/ a b c d x)
  (setq        b (getvar "viewsize")
                        c (car (getvar "screensize"))
                        d (cadr (getvar "screensize"))
                        a (* b (/ c d))
                        x (setq x (getvar "viewctr"))
                        x (trans x 1 2)
                        c (list (- (car x) (/ a 2.0)) (- (cadr x) (/ b 2.0)) 0.0)
                        d (list (+ (car x) (/ a 2.0)) (+ (cadr x) (/ b 2.0)) 0.0)
                        c (trans c 2 1)
                        d (trans d 2 1)
  )
  (list c d)
)

start4444

看看这个函数对你有无帮助
;;当前视图屏幕角点坐标
(defun dt:viewport-getcoords (/ height width size middle)
  (setq height (getvar "viewsize"))
  (setq size (getvar "screensize"))
  (setq middle (getvar "viewctr"))
  (setq width (* (/ height (cadr size)) (car size)))
  (list        (list (- (car middle) (/ width 2.0))
              (- (cadr middle) (/ height 2.0))
        )
        (list (+ (car middle) (/ width 2.0))
              (+ (cadr middle) (/ height 2.0))
        )
  )
)

masterlong

PL线比较特殊
10点对比较多的的原因？
不光是封闭PL线
不封闭的单段PL线
也可能会选中

masterlong

个人建议啊
尽量避免屏幕外选择
虽然看起来屏幕不晃很爽
但是很多时候会误选和漏选
最常见的例子是
块和块心相距十万八千里的情况
实时缩放窗口确保选择无误
其实没啥大不了的

669423907

masterlong 发表于 2020-9-15 23:23
个人建议啊
尽量避免屏幕外选择
虽然看起来屏幕不晃很爽

谢谢你的回复，如果这样是否会好一些：
(defun c:13(/ p1 p2)
(sssetfirst)
(setq p1 (getpoint (strcat "\n请指定框选第一点：")) )
(setq p2 (getcorner p1 (strcat "\n请指定框选第一点：")) )
(if
如果 p1 在屏幕内，则 (sssetfirst nil (ssget "c" p1 p2))
(sssetfirst nil (XY框选 p1 p2 nil))
)
)

请教一下，如何判断 p1 在屏幕内？

669423907

请问大师们，如何判断点p1在屏幕内？

masterlong

上面的函数没有考虑ucs的影响

masterlong

黄明儒收集的函数
原作者是谁不知道

自贡黄明儒

从程序来看，是会选中的呀