求一段文本代码

wgij007

自己搞不好呀

taoyi0727

(defun c:tt (/ gr loop name obj pt size str)
        (if (and
                                (setq pt (cadr (grread t 15 0)))
                                (entmake (list
                                                 '(0 . "MTEXT")
                                                 '(100 . "AcDbEntity")
                                                 '(100 . "AcDbMText")
                                                 '(7 . "宋体")
                                                 (cons 1 "我是中国人")
                                                 (cons 10 (trans pt 1 0))
                                                 (cons 40 3.2)
                                                 (cons 210 (trans '(0.0 0.0 1.0) 1 0))
                                                 (cons 11 (trans '(1.0 0.0 0.0) 1 0))
                                         )
                                )
                                (setq name (entlast))
                        )
                (progn
                        (setq obj (vlax-ename->vla-object name))
                        (setq loop t)
                        (while loop
                                (setq gr (grread t 15 0))
                                (cond
                                        ((= (car gr) 5);移动
                                                (vla-put-InsertionPoint obj (vlax-3D-point (cadr gr)))
                                        )
                                        ((= (car gr) 3);左键
                                                (setq loop nil)
                                        )
                                        ((or
                                                 (= (car gr) 25);右键
                                                 (= (car gr) 2);空格
                                         )
                                                (entdel name)
                                                (setq loop nil)
                                        )
                                )
                        )
                )
        )
)

taoyi0727

(defun c:tt (/ gr loop name obj pt size str)
(if (and
    (setq str (getstring "输入文字内容:"))
    (setq size 100)
    (setq pt (cadr (grread t 15 0)))
    (entmake (list
          (cons 0 "TEXT")
          (cons 10 pt)
          (cons 40 size)
          (cons 1 str)
          (cons 7 "宋体")
          (cons 210 (trans '(0.0 0.0 1.0) 1 0))
         )
    )
    (setq name (entlast))
   )
  (progn
   (setq obj (vlax-ename->vla-object name))
   (setq loop t)
   (while loop
    (setq gr (grread t 15 0))
    (cond
     ((= (car gr) 5);移动
      (vla-put-InsertionPoint obj (vlax-3D-point (cadr gr)))
     )
     ((= (car gr) 3);左键
      (setq loop nil)
     )
     ((or
       (= (car gr) 25);右键
       (= (car gr) 2);空格
      )
      (entdel name)
      (setq loop nil)
     )
    )
   )
  )
)
(princ)
)

wgij007

taoyi0727 发表于 2020-9-26 11:19
(defun c:tt (/ gr loop name obj pt size str)
(if (and
    (setq str (getstring "输入文字内容:"))
...

老大，这个不是我想要的，我要的是把文本内容设好，一点就出来的.还有一个没说的，是多行文字.
谢谢了。

czb203

感谢楼主的分享

wgij007

taoyi0727 发表于 2020-9-26 11:19
(defun c:tt (/ gr loop name obj pt size str)
(if (and
    (setq str (getstring "输入文字内容:"))
...

老大，能帮忙设下这代码吗。
;|以下为自定函数，用于生成制图日期=================================================|;
(DEFUN MY_DATE (/ TMP Y M D H MINUTE SECOND NYR SFM TXT)
  (setq tmp    (rtos (getvar "cdate") 2 8)
y      (rtos (atof (substr tmp 1 4)) 2 0)
m      (rtos (atof (substr tmp 5 2)) 2 3)
d      (rtos (atof (substr tmp 7 2)) 2 0)
h      (rtos (atof (substr tmp 10 2)) 2 0)
minute (rtos (atof (substr tmp 12 2)) 2 0)
second (rtos (atof (substr tmp 14 2)) 2 0)
yr     (strcat y "." m "." d)
sfm    (strcat h ":" minute ":" second)
sf     (strcat h ":" minute)
txt    (strcat "日期：" y "年" m "月" d "日")
  )
  (LIST Y M D H MINUTE SECOND YR SFM TXT sf) ;返回10个值
)     ;EDN DEFUN MY_DATE

现出来是2020.9.9
能设成  2020.09.09
感谢

taoyi0727

(DEFUN MY_DATE (/ TMP Y M D H MINUTE SECOND NYR SFM TXT)
        (setq tmp    (rtos (getvar "cdate") 2 8))
        (setq y      (rtos (atof (substr tmp 1 4)) 2 0))
        (setq m      (rtos (atof (substr tmp 5 2)) 2 3))
        (setq d      (rtos (atof (substr tmp 7 2)) 2 0))
        (if (= (strlen M) 1) (setq M (strcat "0" M)))
        (if (= (strlen D) 1) (setq D (strcat "0" D)))
        (setq h      (rtos (atof (substr tmp 10 2)) 2 0))
        (setq minute (rtos (atof (substr tmp 12 2)) 2 0))
        (setq second (rtos (atof (substr tmp 14 2)) 2 0))
        (setq yr     (strcat y "." m "." d))
        (setq sfm    (strcat h ":" minute ":" second))
        (setq sf     (strcat h ":" minute))
        (setq txt    (strcat "日期：" y "年" m "月" d "日"))
  (LIST Y M D H MINUTE SECOND YR SFM TXT sf) ;返回10个值
)

wgij007

taoyi0727 发表于 2020-9-26 15:14
(DEFUN MY_DATE (/ TMP Y M D H MINUTE SECOND NYR SFM TXT)
        (setq tmp    (rtos (getvar "cdate") 2 8)) ...

非常感谢