LWPOLYLINE/POLYLINE多线段加删点继续画

wzg356

;多线段加删点,LWPOLYLINE/POLYLINE二合一了
;en图元名，index顶点索引，pt点
;当pt为点表,相应点索引位置插入pt
;当pt点为nil,删除索引点(起点索引0)
(defun ContinuePoly (en index pt / obj pts nn)
        (setq obj (vlax-ename->vla-object en))
    (setq pts (vla-get-Coordinates obj))
    (setq pts (vlax-safearray->list (vlax-variant-value pts)))
    (if (= (cdr(assoc 0(entget en))) "LWPOLYLINE")
            (setq nn 2) (setq nn 3)
    )
    (if(= (type pt) 'list)
            (progn
                    (if(= nn 3)(setq pts (nth-list  0.0 (* nn index) pts)))
                        (setq pts (nth-list  (cadr pt) (* nn index) pts))
                    (setq pts (nth-list  (car pt) (* nn index) pts))
            )
            (repeat        nn(setq pts (nth-list nil (* nn index) pts)))
    )
        (vlax-put obj 'coordinates pts);设置坐标        
)
;;表n位插入v或删除n位元素
(defun nth-list (v n lst / i l1 l2)
        (setq l1 lst l2 (reverse lst))
        (if v(setq v (list v)i n)(setq i (1+ n)))
        (repeat i (setq l1(cdr l1)))
        (repeat (- (length lst) n) (setq l2 (cdr l2)))
        (append (reverse l2) (append v l1))
)


功能示例
(setq en (entsel "选择LWPOLYLINE,POLYLINE多线段")  e (car en))
(setq index(fix (vlax-curve-getparamatpoint e
                     (vlax-curve-getclosestpointto e (cadr en)))));所击子段
(setq numpt (if (vlax-curve-isClosed e)(fix (vlax-curve-getendParam e))
                         (1+ (fix (vlax-curve-getendParam e)))));顶点数量
(ContinuePoly e numpt (getpoint "\n请输入添加的点:"));末尾加点
(ContinuePoly e (1-numpt) nil);末尾删点                        
(ContinuePoly e (1+ index) (getpoint "\n请输入添加的点:"));所击子段加点
(ContinuePoly e 1 (getpoint "\n请输入添加的点:"));第1子段加点
(ContinuePoly e 0 nil);删除起点
(ContinuePoly e 0 (getpoint "\n请输入添加的点:"));起点加点

yangchao2005090

楼主，可否分享一下源码程序呀