近期论坛附件(图片)下载后文件损坏的解决方法

tryhi

mokson发现的问题所在http://bbs.mjtd.com/thread-182456-1-1.html


这些打不开的图片或附件之中，在首行文件头都加入了一个“0D 0A”这两个字节，因此本论坛出现这种情况： jpg,gif,png 等图片不能正确显示，下载的全部压缩附件也打不开，解压提示错误信息。

用十六进制编辑器可以去除前面两个字节来恢复，或者使用下面lsp程序来处理下载后的文件，处理后会在原理目下生成同名+new名称的文件



(vl-Load-COM)
(defun try-file-ReadBinary (FileName / node size str stream xmldom)
        (setq xmldom (vlax-create-object "Microsoft.XMLDOM"))
        (setq node (vlax-invoke-method xmldom 'CreateElement "binary"))
        (vlax-put-Property node 'DataType "bin.hex")
        (setq stream (vlax-create-object "ADODB.Stream"))
        (vlax-put-Property stream 'type 1)
        (Vlax-Invoke stream 'open)
        (vlax-invoke-method
                stream
                'LoadFromFile
                FileName
        )
        (setq size(vlax-get-Property stream 'size))
        (vlax-put-Property node 'NodeTypedValue (Vlax-Invoke-Method stream 'Read size))
        (Vlax-Invoke-Method stream 'close)
        (setq str (vlax-get-Property node 'text))
        (vlax-release-object xmldom)
        str
)
(defun try-file-WriteBinary (file str / node stream xmldom)
        (setq xmldom (vlax-create-object "Microsoft.XMLDOM"))
        (setq node (vlax-invoke-method xmldom 'CreateElement "binary"))
        (vlax-put-Property node 'DataType "bin.hex")
        (vlax-put-Property node 'Text str)
        (setq stream (vlax-create-object "ADODB.Stream"))
        (vlax-put-Property stream 'type 1)
        (Vlax-Invoke stream 'open)
        (vlax-invoke-method stream 'write
                (vlax-get-Property node 'NodeTypedValue)
        )
        (vlax-invoke-method stream 'saveToFile file 2)
        (Vlax-Invoke-Method stream 'close)
        (vlax-release-object xmldom)
        (vlax-release-object stream)
)
(defun c:tt (/ file h16 h16-2 newfile)
        (setq file(getfiled "选择一个文件" "" "*" 0))
        (or file (exit))
        (setq
                h16(try-file-ReadBinary file)
                h16-2(substr h16 5)
        )
        (setq newfile (strcat(vl-filename-directory file)"\\"(vl-filename-base file)"_new"(vl-filename-extension file)))
        (try-file-WriteBinary newfile h16-2)
        (princ(strcat"\n处理完成，生成新文件"newfile))(princ)
)

alexmai

liufii 发表于 2021-8-26 09:33
复制上面的内容后运行提示输入的字符串有缺陷。

那是因为你用win10 记事本，默认编码 要改为 ANSI 的方式

liufii

alexmai 发表于 2021-9-2 14:49
那是因为你用win10 记事本，默认编码 要改为 ANSI 的方式

多谢，确实是这个问题！

sunny_8848

复制上面的内容后运行提示输入的字符串有缺陷。不过提供的方法挺实用，谢谢楼主分享

xiaotao

我以为是我电脑出问题了呢！

664571221

海哥你也太牛逼了吧

hbabc

期待早日恢复正常！！！

菜卷鱼

本应该是管理员给论坛打补丁，
但是海大师厉害，能给文件打补丁

mokson

海哥将 lisp 玩弄于掌心之中，出神入化。膜拜！

yoyoho

谢谢! 海大师  

树櫴希德

mobai膜拜 请问现在论坛附件还是那个问题吗？

czb203

还没解决吗，好像病毒一样