(求助)请教各位大神，是否有插件可以实现矩形变单线

999999 · 发表于 2021-12-24 21:56:07

求助各位大神，是否可以帮忙实现矩形变中心单线的插件，

,,以矩形的最长的两边生成中心线

夏生生 · 发表于 2021-12-24 21:56:08

本帖最后由夏生生于 2021-12-26 16:28 编辑

999999 发表于 2021-12-25 23:21
感谢大神的杰作，效果杠杆的，谢谢大神，请问大神可以增加个批量框选生成的吗

试试看，以您的能力加个批量应该不是问题的

(defun c:tt (/ xty-tr-ss2lst getmid lst en dis pt obj1 obj2)
(defun xty-tr-ss2lst (ss form / n en lst)
(repeat (setq n (sslength ss))
(setq en (ssname ss (setq n (1- n))))
(setq lst (cons en lst))
)
(setq lst (reverse lst))
(if form
lst
(mapcar (function vlax-ename->vla-object) lst)
)
)
(defun getmid (en)
(vlax-curve-getpointatparam
en
(* 0.5
(+ (vlax-curve-getstartparam en)
(vlax-curve-getendparam en)
)
)
)
)
(setq ss (ssget '((0 . "lwpolyline") (90 . 4)))
lst (xty-tr-ss2lst ss nil)
)
(foreach en lst
(setq en (vl-catch-all-apply
(function vlax-safearray->list)
(list (vlax-variant-value (vla-explode en)))
)
en (mapcar
'(lambda (x)
(list
(vlax-curve-getdistatparam x (vlax-curve-getendparam x))
(getmid x)
x
)
)
en
)
en (vl-sort en '(lambda (a b) (< (car a) (car b))))
dis (* 0.5 (caar en))
pt (mapcar '(lambda (x y) (* 0.5 (+ x y)))
(cadr (caddr en))
(cadr (last en))
)
obj1 (car (vl-catch-all-apply
(function vlax-safearray->list)
(list (vlax-variant-value
(vla-offset (last (last en)) dis)
)
)
)
)
obj2 (car (vl-catch-all-apply
(function vlax-safearray->list)
(list (vlax-variant-value
(vla-offset (last (last en)) (- dis))
)
)
)
)
)
(if (equal pt (getmid obj1) 1e-4)
(progn (vla-delete obj2)
(vla-put-layer obj1 (getvar "clayer"))
)
(progn (vla-delete obj1)
(vla-put-layer obj2 (getvar "clayer"))
)
)
(foreach n en (vla-delete (last n)))
)
)

(defun c:tt (/ xty-tr-ss2lst getmid lst en dis pt obj1 obj2) 
  (defun xty-tr-ss2lst (ss form / n en lst) 
    (repeat (setq n (sslength ss)) 
      (setq en (ssname ss (setq n (1- n)))) 
      (setq lst (cons en lst)) 
    ) 
    (setq lst (reverse lst)) 
    (if        form 
      lst 
      (mapcar (function vlax-ename->vla-object) lst) 
    ) 
  ) 
  (defun getmid        (en) 
    (vlax-curve-getpointatparam 
      en 
      (* 0.5 
         (+ (vlax-curve-getstartparam en) 
            (vlax-curve-getendparam en) 
         ) 
      ) 
    ) 
  ) 
  (setq        ss  (ssget '((0 . "lwpolyline") (90 . 4))) 
        lst (xty-tr-ss2lst ss nil) 
  ) 
  (foreach en lst 
    (setq en   (vl-catch-all-apply 
                 (function vlax-safearray->list) 
                 (list (vlax-variant-value (vla-explode en))) 
               ) 
          en   (mapcar 
                 '(lambda (x) 
                    (list 
                      (vlax-curve-getdistatparam x (vlax-curve-getendparam x)) 
                      (getmid x) 
                      x 
                    ) 
                  ) 
                 en 
               ) 
          en   (vl-sort en '(lambda (a b) (< (car a) (car b)))) 
          dis  (* 0.5 (caar en)) 
          pt   (mapcar '(lambda (x y) (* 0.5 (+ x y))) 
                       (cadr (caddr en)) 
                       (cadr (last en)) 
               ) 
          obj1 (car (vl-catch-all-apply 
                      (function vlax-safearray->list) 
                      (list (vlax-variant-value 
                              (vla-offset (last (last en)) dis) 
                            ) 
                      ) 
                    ) 
               ) 
          obj2 (car (vl-catch-all-apply 
                      (function vlax-safearray->list) 
                      (list (vlax-variant-value 
                              (vla-offset (last (last en)) (- dis)) 
                            ) 
                      ) 
                    ) 
               ) 
    ) 
    (if        (equal pt (getmid obj1) 1e-4) 
      (progn (vla-delete obj2) 
             (vla-put-layer obj1 (getvar "clayer")) 
      ) 
      (progn (vla-delete obj1) 
             (vla-put-layer obj2 (getvar "clayer")) 
      ) 
    ) 
    (foreach n en (vla-delete (last n))) 
  ) 
)

guosheyang · 发表于 2021-12-25 12:05:26

这个除了圆弧要用到凸度意外另两个都是比较简单

guosheyang · 发表于 2021-12-25 12:06:56

提供一个李迈克的代码
;;;;已知弧线起点、终点及凸度，求圆心坐标
;; Bulge Centre  -  Lee Mac
;; p1 - start vertex  p2 - end vertex b  - bulge
;; Returns the centre of the arc described by the given bulge and vertices
;(LM:bulgecentre (setq p1(getpoint))(setq p2(getpoint)) b)
(defun LM:bulgecentre (p1 p2 b)
  (polar p1
      (+ (angle p1 p2) (- (/ pi 2) (* 2 (atan b))))
      (/ (* (distance p1 p2) (1+ (* b b))) 4 b)
  )
)

夏生生 · 发表于 2021-12-25 17:30:45

本帖最后由夏生生于 2021-12-25 17:35 编辑

仅适用于本例

(defun c:tt (/ getmid en dis pt obj1 obj2)
(defun getmid (en)
(vlax-curve-getpointatparam
en
(* 0.5
(+ (vlax-curve-getstartparam en)
(vlax-curve-getendparam en)
)
)
)
)
(setq en (vl-catch-all-apply
(function vlax-safearray->list)
(list (vlax-variant-value
(vla-explode
(vlax-ename->vla-object (car (entsel "\n选取:")))
)
)
)
)
en (mapcar
'(lambda (x)
(list
(vlax-curve-getdistatparam x (vlax-curve-getendparam x))
(getmid x)
x
)
)
en
)
)
(if (= 4 (length en))
(progn
(setq en (vl-sort en '(lambda (a b) (< (car a) (car b))))
dis (* 0.5 (caar en))
pt (mapcar '(lambda (x y) (* 0.5 (+ x y)))
(cadr (caddr en))
(cadr (last en))
)
)
(setq obj1 (car (vl-catch-all-apply
(function vlax-safearray->list)
(list (vlax-variant-value
(vla-offset (last (last en)) dis)
)
)
)
)
obj2 (car (vl-catch-all-apply
(function vlax-safearray->list)
(list (vlax-variant-value
(vla-offset (last (last en)) (- dis))
)
)
)
)
)
(if (equal pt (getmid obj1) 1e-4)
(progn(vla-delete obj2)(vla-put-layer obj1(getvar"clayer")))
(progn(vla-delete obj1)(vla-put-layer obj2(getvar"clayer")))
)
(foreach n en (vla-delete (last n)))
)
(progn(foreach n en (vla-delete (last n)))(alert"非四边"))
)
)

(defun c:tt (/ getmid en dis pt obj1 obj2) 
  (defun getmid    (en) 
    (vlax-curve-getpointatparam 
      en 
      (* 0.5 
     (+ (vlax-curve-getstartparam en) 
        (vlax-curve-getendparam en) 
     ) 
      ) 
    ) 
  ) 
  (setq    en (vl-catch-all-apply 
         (function vlax-safearray->list) 
         (list (vlax-variant-value 
             (vla-explode 
               (vlax-ename->vla-object (car (entsel "\n选取:"))) 
             ) 
           ) 
         ) 
       ) 
    en (mapcar 
         '(lambda (x) 
        (list 
          (vlax-curve-getdistatparam x (vlax-curve-getendparam x)) 
          (getmid x) 
          x 
        ) 
          ) 
         en 
       ) 
  ) 
  (if (= 4 (length en)) 
    (progn 
      (setq en    (vl-sort en '(lambda (a b) (< (car a) (car b)))) 
        dis    (* 0.5 (caar en)) 
        pt    (mapcar    '(lambda (x y) (* 0.5 (+ x y))) 
            (cadr (caddr en)) 
            (cadr (last en)) 
        ) 
      ) 
      (setq obj1 (car (vl-catch-all-apply 
            (function vlax-safearray->list) 
            (list (vlax-variant-value 
                (vla-offset (last (last en)) dis) 
                  ) 
            ) 
              ) 
         ) 
        obj2 (car (vl-catch-all-apply 
            (function vlax-safearray->list) 
            (list (vlax-variant-value 
                (vla-offset (last (last en)) (- dis)) 
                  ) 
            ) 
              ) 
         ) 
      ) 
      (if (equal pt (getmid obj1) 1e-4) 
    (progn(vla-delete obj2)(vla-put-layer obj1(getvar"clayer"))) 
    (progn(vla-delete obj1)(vla-put-layer obj2(getvar"clayer"))) 
      ) 
      (foreach n en (vla-delete (last n))) 
    ) 
    (progn(foreach n en (vla-delete (last n)))(alert"非四边")) 
  ) 
)

999999 · 发表于 2021-12-25 23:18:59

guosheyang 发表于 2021-12-25 12:05
这个除了圆弧要用到凸度意外另两个都是比较简单

您说的简单，我却感觉太难了

999999 · 发表于 2021-12-25 23:20:09

guosheyang 发表于 2021-12-25 12:06
提供一个李迈克的代码
;;;;已知弧线起点、终点及凸度，求圆心坐标
;; Bulge Centre - Lee Mac

世界上最遥远的距离就是，你把代码摆在我的面前，我却不知道怎么样使用

999999 · 发表于 2021-12-25 23:21:10

夏生生发表于 2021-12-25 17:30
仅适用于本例

感谢大神的杰作，效果杠杆的，谢谢大神，请问大神可以增加个批量框选生成的吗

664571221 · 发表于 2021-12-26 11:47:06

夏生生发表于 2021-12-26 10:37
试试看，以您的能力加个批量应该不是问题的

有批量的了吗？？？？

664571221 · 发表于 2021-12-26 11:52:14

夏生生发表于 2021-12-26 10:37
试试看，以您的能力加个批量应该不是问题的

提示错误; 错误: no function definition: nil

账号		自动登录	找回密码
密码			注册

[提问] (求助)请教各位大神，是否有插件可以实现矩形变单线

最佳答案

评分

本帖子中包含更多资源

点评

点评

点评