求助：图层透明度的算法

wharan · 发表于 2022-3-4 18:55:28

本帖最后由 wharan 于 2022-3-5 20:56 编辑

做一段小程序，需要定义图层透明度。在群内1291500406和guosheyang等大侠的帮助下，总算通过 (-3 ("AcCmTransparency" (1071 . 33554623)))方法实现了透明图层的定义。但接下来又碰到了新的问题，(-3 ("AcCmTransparency" (1071 . 33554623)))中图层透明度25对应的33554623是怎么计算出来的，求大侠告知算法，不胜感激。

群内真是卧虎藏龙啊。在各位朋友的热心帮助下，算法完美解决，在此一并表示感谢。

如果一个层已经存在，怎么强制更新图层透明度呢？颜色、线型等均已解决，透明度解决不了。

edata · 发表于 2022-3-5 15:58:43

本质应该是记录的不透明度值透明25%，那么不透明75%。
记录值采用的是一个字节大小来存储，范围0-255，255*0.75=191.25 取整191
这个透明度是占用4个字节，高位为02，中间两个字节为0000，低位是不透明度值0xBF=191
0x020000BF=33554623

(+ (lsh 2 56) (fix (* 255(- 1 (* 25 0.01) ))))

Bao_lai · 发表于 2022-3-5 18:51:02

edata 发表于 2022-3-5 15:58
本质应该是记录的不透明度值透明25%，那么不透明75%。
记录值采用的是一个字节大小来存储，范围0-255，25 ...

确实，这个Alpha通道记录的是不透明度。

linyangmjtd · 发表于 2022-6-21 13:49:47

;功能：设置图层的透明度
;参数：
; layername ：图层名称
; value ：设置值0~100的值
;函数：无
;示例：(yd-layer-transparency "0" 0)
(defun yd-layer-transparency(layername value /
ent Objlayer transparency data data-3
)
(if (and
(<= 0 value 100)
(tblsearch "layer" layername)
)
(progn
(setq
ent (tblobjname "layer" layername)
Objlayer (vlax-ename->vla-object ent)
transparency (+ (lsh 2 56) (fix (* 255(- 1 (* value 0.01) ))))
data (entget (tblobjname "layer" layername) '("*"))
data-3 (cdr (assoc -3 data))
)
(if (/= (assoc "AcCmTransparency" (cdr (assoc -3 data))) nil)
(progn
(setq
data-3 (if (= value 0) (vl-remove (assoc "AcCmTransparency" data-3) data-3) (subst (list "AcCmTransparency" (cons 1071 transparency)) (assoc "AcCmTransparency" data-3) data-3))
data (subst (cons -3 data-3) (assoc -3 data) data)
)
(entmod data)
)
(progn
(setq
data-3 (if (= value 0) data-3 (cons (list "AcCmTransparency" (cons 1071 transparency)) data-3))
data (subst (cons -3 data-3) (assoc -3 data) data)
)
(entmod data)
)
)
(vla-put-layeron Objlayer (vla-get-layeron Objlayer))
;更新图层(vla-regen (vla-get-activedocument(vlax-get-acad-object)) 1)，不知道vla-regen和redraw方法哪个速度更快
(redraw ent)
)
)
(princ)
)

;功能 ： 设置图层的透明度 
;参数： 
;      layername ： 图层名称 
;      value ： 设置值0~100的值 
;函数：无 
;示例：(yd-layer-transparency "0" 0) 
(defun yd-layer-transparency(layername value / 
                              ent Objlayer transparency data data-3 
                            ) 
  (if (and 
        (<= 0 value 100) 
        (tblsearch "layer" layername) 
      ) 
    (progn 
      (setq 
        ent (tblobjname "layer" layername) 
        Objlayer (vlax-ename->vla-object ent) 
        transparency (+ (lsh 2 56) (fix (* 255(- 1 (* value 0.01) )))) 
        data (entget (tblobjname "layer" layername) '("*")) 
        data-3 (cdr (assoc -3 data)) 
      ) 
      (if (/= (assoc "AcCmTransparency" (cdr (assoc -3 data))) nil) 
        (progn 
          (setq 
            data-3 (if (= value 0) (vl-remove (assoc "AcCmTransparency" data-3) data-3) (subst (list "AcCmTransparency" (cons 1071 transparency)) (assoc "AcCmTransparency" data-3) data-3)) 
            data (subst (cons -3 data-3) (assoc -3 data) data) 
          ) 
          (entmod data) 
        ) 
        (progn 
          (setq 
            data-3 (if (= value 0) data-3 (cons (list "AcCmTransparency" (cons 1071 transparency)) data-3)) 
            data (subst (cons -3 data-3) (assoc -3 data) data) 
          ) 
          (entmod data) 
        ) 
      ) 
       
      (vla-put-layeron Objlayer (vla-get-layeron Objlayer)) 
      ;更新图层(vla-regen (vla-get-activedocument(vlax-get-acad-object)) 1)，不知道vla-regen和redraw方法哪个速度更快 
      (redraw ent) 
    ) 
  ) 
  (princ) 
)

guosheyang · 发表于 2022-3-4 21:03:55

自己遍历一下就有了

wharan · 发表于 2022-3-4 22:26:20

guosheyang 发表于 2022-3-4 21:03
自己遍历一下就有了

没有思绪，不知道从何下手，从没涉及这方面的算法

Bao_lai · 发表于 2022-3-5 08:26:13

本帖最后由 Bao_lai 于 2022-3-5 08:27 编辑

(setq a(lsh 33554623 24))-->-1090519040 (abs(- (lsh (+ a 2147483647)25)(lsh a -24)))-->33554623

按照强哥提供的参考算法提示，穷举算了下发现可以对应0~255一共256个值，发现CAD的透明度可以用Entmake的这个方式实现(33554687~33554432)0~100%，
具体的对应关系见附件。

guosheyang · 发表于 2022-3-5 11:21:17

简化下，事实上只需要这样一个码值表1071的关联码值，依次对应透明度从0 1 2 到99 100共101个值即可
(setq tmdmzb(list 33554687 33554684 33554681 33554679 33554676 33554674 33554671 33554669 33554666 33554664 33554661 33554658 33554656 33554653 33554651 33554648 33554646 33554643 33554641 33554638 33554636 33554633 33554630 33554628 33554625 33554623 33554620 33554618 33554615 33554613 33554610 33554607 33554605 33554602 33554600 33554597 33554595 33554592 33554590 33554587 33554585 33554582 33554579 33554577 33554574 33554572 33554569 33554567 33554564 33554562 33554559 33554556 33554554 33554551 33554549 33554546 33554544 33554541 33554539 33554536 33554534 33554531 33554528 33554526 33554523 33554521 33554518 33554516 33554513 33554511 33554508 33554505 33554503 33554500 33554498 33554495 33554493 33554490 33554488 33554485 33554483 33554480 33554477 33554475 33554472 33554470 33554467 33554465 33554462 33554460 33554457 33554454 33554452 33554449 33554447 33554444 33554442 33554439 33554437 33554434 33554432))

Bao_lai · 发表于 2022-3-5 13:09:46

本帖最后由 Bao_lai 于 2022-3-5 15:12 编辑

换算关系
# 透明度的范围是0-255，
eg：25%不透明度也就是255*25%=63.75，四舍五入64;

;(setq 透明度 25) ;--->1071组码 33554623
;(setq 组码 (fix (+ 0.05 (- 33554687 (* 255 (float 透明度) 0.01)))))

;修正一个问题
(setq 透明度 25) ;--->1071组码 33554623
(setq 组码 (fix (- 33554687 (* 255 透明度 0.01))))

wharan · 发表于 2022-3-5 19:48:12

Bao_lai 发表于 2022-3-5 13:09
换算关系
# 透明度的范围是0-255，
eg：25%不透明度也就是255*25%=63.75，四舍五入64;

感谢你的指点。还有一个问题，如果一个层已经存在，怎么强制更新图层透明度呢？

Bao_lai · 发表于 2022-3-5 21:40:18

wharan 发表于 2022-3-5 19:48
感谢你的指点。还有一个问题，如果一个层已经存在，怎么强制更新图层透明度呢？

(regapp "AcCmTransparency")
(Setq a (entget (tblobjname "layer" "图层名称") '("AcCmTransparency")))
(setq a (subst '(-3 ("AcCmTransparency" (1071 . 33554462))) (assoc -3 a) a))
;;利用ent的subst替换祖码,entmod更新信息。
(entmod a)

账号		自动登录	找回密码
密码			注册

[提问] 求助：图层透明度的算法

评分

本帖子中包含更多资源

评分