如何批量修改多个文件中圆的大小

1864953597

有很多的文件 每个文件都有很多圆 所有的圆大小都一致，想把所有圆半径0.1改为0.2 求大佬帮帮忙

夏生生

特慢系列，别怪我没提醒您，单独建立一个文件夹拷贝文件测试

1. (defun c:tt (/ f file tmp)
   
2.   (setq  f (getfiled "选择文件夹并任意选取一个文件，请先剔除无需处理文件"
   
3.         "d:\\"
   
4.         "dwg"
   
5.         0
   
6.         )
   
7.   f (vl-filename-directory f)
   
8.   f (mapcar '(lambda (x) (strcat f "\\" x))
   
9.       (vl-directory-files f "*.dwg" 1)
   
10.       )
    
11.   )
    
12.   (setq tmp (open (setq file (strcat (getenv "TEMP") "\\tmp.scr")) "w"))
    
13.   (foreach n f
    
14.     (write-line (strcat "_.open \"" n "\"") tmp)
    
15.     (write-line
    
16.       "(setq ss (ssget \"x\" '((0 . \"CIRCLE\") (40 . 0.1))))
    
17.        (repeat  (setq n (sslength ss))
    
18.        (setq  en (ssname ss (setq n (1- n)))
    
19.   en (entget en)
    
20.   en (subst (cons 40 0.2) (assoc 40 en) en)
    
21.   )
    
22.        (entmod en)
    
23.   )"
    
24.       tmp
    
25.       )
    
26.     (write-line "_.qsave _.close" tmp)
    
27.     )
    
28.   (close tmp)
    
29.   (command ".script" file)
    
30.   (vl-file-delete file)
    
31.   (princ)
    
32.   )
    

(defun c:tt (/ f file tmp)<br />   (setq  f (getfiled "选择文件夹并任意选取一个文件，请先剔除无需处理文件"<br />         "d:\\"<br />         "dwg"<br />         0<br />         )<br />   f (vl-filename-directory f)<br />   f (mapcar '(lambda (x) (strcat f "\\" x))<br />       (vl-directory-files f "*.dwg" 1)<br />       )<br />   )<br />   (setq tmp (open (setq file (strcat (getenv "TEMP") "\\tmp.scr")) "w"))<br />   (foreach n f<br />     (write-line (strcat "_.open \"" n "\"") tmp)<br />     (write-line<br />       "(setq ss (ssget \"x\" '((0 . \"CIRCLE\") (40 . 0.1))))<br />        (repeat  (setq n (sslength ss))<br />        (setq  en (ssname ss (setq n (1- n)))<br />   en (entget en)<br />   en (subst (cons 40 0.2) (assoc 40 en) en)<br />   )<br />        (entmod en)<br />   )"<br />       tmp<br />       )<br />     (write-line "_.qsave _.close" tmp)<br />     )<br />   (close tmp)<br />   (command ".script" file)<br />   (vl-file-delete file)<br />   (princ)<br />   )<br />

再来个dbx的

1. (defun c:tt1 (/ f dbx)
   
2.   (setq    f   (getfiled "选择文件夹并任意选取一个文件，请先剔除无需处理文件"
   
3.               "d:\\"
   
4.               "dwg"
   
5.               0
   
6.               )
   
7.     f   (vl-filename-directory f)
   
8.     f   (mapcar '(lambda (x) (strcat f "\\" x))
   
9.             (vl-directory-files f "*.dwg" 1)
   
10.             )
    
11.     dbx (vlax-get-or-create-Object
    
12.           (strcat "ObjectDBX.AxDbDocument."
    
13.               (itoa (atoi (getvar "acadver")))
    
14.               )
    
15.           )
    
16.     )
    
17.   (foreach n f
    
18.     (vla-open dbx n)
    
19.     (vlax-for m    (vla-get-modelspace dbx)
    
20.       (if (and (eq "AcDbCircle" (vla-get-objectname m))
    
21.            (= 0.1 (vla-get-Radius m))
    
22.            )
    
23.     (vla-put-Radius m 0.2)
    
24.     )
    
25.       )
    
26.     (vla-saveas dbx n)
    
27.     )
    
28.   (vlax-release-object dbx)
    
29.   (princ)
    
30.   )
    

(defun c:tt1 (/ f dbx)<br />   (setq    f   (getfiled "选择文件夹并任意选取一个文件，请先剔除无需处理文件"<br />               "d:\\"<br />               "dwg"<br />               0<br />               )<br />     f   (vl-filename-directory f)<br />     f   (mapcar '(lambda (x) (strcat f "\\" x))<br />             (vl-directory-files f "*.dwg" 1)<br />             )<br />     dbx (vlax-get-or-create-Object<br />           (strcat "ObjectDBX.AxDbDocument."<br />               (itoa (atoi (getvar "acadver")))<br />               )<br />           )<br />     )<br />   (foreach n f<br />     (vla-open dbx n)<br />     (vlax-for m    (vla-get-modelspace dbx)<br />       (if (and (eq "AcDbCircle" (vla-get-objectname m))<br />            (= 0.1 (vla-get-Radius m))<br />            )<br />     (vla-put-Radius m 0.2)<br />     )<br />       )<br />     (vla-saveas dbx n)<br />     )<br />   (vlax-release-object dbx)<br />   (princ)<br />   )<br />

轮回

我来一个常规的吧，借用论坛程序修改的，就不道谢了哈！
命令: TT1
功能：不开图将一个文件夹下所有图纸内原直径为0.2的圆，将直径修改为0.4。


-------------------------------------------------------------------------------------------------------


;取得目录
(defun qf_getFolder (msg / WinShell shFolder path catchit)
        (vl-load-com)
        (setq winshell (vlax-create-object "Shell.Application"))
        (setq shFolder (vlax-invoke-method WinShell 'BrowseForFolder 0 msg 1))
        (setq
                catchit (vl-catch-all-apply
                                                        '(lambda () (setq shFolder (vlax-get-property shFolder 'self)) (setq path (vlax-get-property shFolder 'path))
                                                         )
                                                )
        )
        (if (vl-catch-all-error-p catchit)
                nil
                path
        )
)


;程序开始
(vl-load-com)
(defun C:TT1(/ banben dbx dwgname files i lx path)
        (setq BANBEN (substr (getvar "acadver" ) 1 2 ))
        (setq DBX (vlax-get-or-create-object (strcat "ObjectDBX.AxDbDocument." BANBEN ) ))
        (setq PATH (strcat (qf_getFolder  "\n 选择图纸所在文件夹：" ) "\\" ))
        (setq FILES (vl-directory-files PATH "*.dwg" 1 ))
        (setq I -1)
        (while (and (setq  DWGNAME (nth (setq  I (1+ I )) FILES ))  )
                (vlax-invoke-method DBX 'open (strcat PATH DWGNAME ) )
                (vlax-for OB (vlax-get DBX 'MODELSPACE )  
                        (setq LX (vla-get-ObjectName OB))
                        (if (= LX "AcDbCircle")
                                (if (= (vla-get-Diameter OB) 0.2);原直径为0.2
                                        (vla-put-Diameter OB 0.4);修改直径为0.4
                                )
                        )
                )
                (vlax-invoke-method DBX 'SAVEAS (strcat PATH DWGNAME ) )
        )
        (vlax-release-object DBX )  
)

xj6019

夏生生 发表于 2022-4-7 16:37
特慢系列，别怪我没提醒您，单独建立一个文件夹拷贝文件测试

再来个dbx的

你好，大佬 ，你那个超慢模式速度能提升不，确实想找个这种模式的代码，就是挨个打开文件，执行一系列操作后，关闭文件   再循环打开下个文件继续执行，只到循环完，求大佬给一段速度还算可以的，这种模式的代码，参考学习一下可以吗，谢谢了！

夏生生

xj6019 发表于 2022-4-10 09:38
你好，大佬 ，你那个超慢模式速度能提升不，确实想找个这种模式的代码，就是挨个打开文件，执行一系列操 ...

采用alisp就用scr的方法，这种方法个人认为不是很适合逐个文件处理的方式，比较慢；
采用vlisp就用dbx的方法，这种方法要全部采用vba的函数，速度比较快；
我在前面的帖子应该就是您需要的示例代码，您根据帖子的思路去改就是了。

xj6019

夏生生 发表于 2022-4-10 11:13
采用alisp就用scr的方法，这种方法个人认为不是很适合逐个文件处理的方式，比较慢；
采用vlisp就用dbx的 ...

多个文件内执行burst    就是炸开属性块  dbx能实现吗   好像没找到 用dbx炸开属性块的方法

夏生生

xj6019 发表于 2022-4-10 16:03
多个文件内执行burst    就是炸开属性块  dbx能实现吗   好像没找到 用dbx炸开属性块的方法

burst是express的命令，不在乎速度可以用scr，(c:burst)解决问题，vla的话就要自己想办法解决vla-explode后attribute转换的问题了，就是有点绕，也不是解决不了

xj6019

夏生生 发表于 2022-4-10 16:15
burst是express的命令，不在乎速度可以用scr，(c:burst)解决问题，vla的话就要自己想办法解决vla-explode ...

嗯   谢谢指导，看来确实没有直接的办法，只能绕几个圈才能用dbx解决，改块内文字 和炸属性块 不是一回事，看来确实是比较费劲，算了 以后再说吧，谢谢！

革天明

最近也搞了个批量修改圆、圆弧半径的，但只支持框选内容。每个人的需求真是千差万别啊

sniper1111

革天明 发表于 2022-4-10 22:51
最近也搞了个批量修改圆、圆弧半径的，但只支持框选内容。每个人的需求真是千差万别啊

你左边工具栏是什么。