求助,如何用lisp读取外部TXT文件,写入CAD自带的表格内.

丶吟游诗人灬

如题,需要将外部txt格式的文件,读取后写入CAD自带的表格中,表格行数根据所读取的txt文件行数一致,列数为5列,插入表格时可以以窗口的形式插入(即表格对角两点可以拖拽选择表格范围,行宽,列宽以拖拽的表格范围确定,表格文字大小根据表格整体范围相应的缩小或者放大)

kozmosovia

把txt用Excel打开分好咧，复制黏贴至CAD中即可

革天明

直接从剪贴板中读取数据，不局限于Excel还是txt，免费使用

丶吟游诗人灬

kozmosovia 发表于 2023-6-3 18:29
把txt用Excel打开分好咧，复制黏贴至CAD中即可

这样太麻烦了  我是需要在lisp里操作生成.

渠辉

(lst2excel (txt2list (fn)))

渠辉

2. ;;表快速输出 XLS
   
3. (defun ls2xls (lst / _List:getRC  XD::Excel:i2ColNo  excel bks acBook sht rc  cells range)
   
4. (defun XD::Excel:i2ColNo (a / l _i2ColNo)
   
5.   (defun _i2ColNo (num / lst)
   
6.     (cond
   
7.       ((<= 1 num 26) (setq lst (cons num lst)))
   
8.       ((> num 26) (setq lst (append (_i2ColNo (/ num 26)) (list (rem num 26)))))
   
9.       (t lst)
   
10.     ) lst
    
11.   )
    
12.   (if (and (>= (setq a (fix (abs a))) 1)
    
13.            (setq l (_i2ColNo a))
    
14.       )
    
15.     (apply 'strcat (mapcar '(lambda (x) (chr (+ 64 x))) l))
    
16.   )
    
17. )
    
18. (setq excel (vlax-get-or-create-object "Excel.Application"))
    
19. (vla-put-visible excel :vlax-true)
    
20. (setq bks (vlax-get excel 'workbooks)
    
21.      acBook (vlax-invoke bks 'Add)
    
22.      sht  (vlax-get excel 'ActiveSheet)
    
23.      rc   (strcat "A1:"
    
24.                (xd::excel:i2ColNo (apply 'max (mapcar 'length lst)))
    
25.                (itoa (length lst))
    
26.            )
    
27.      cells (vlax-get sht 'cells)
    
28.      range (vlax-get-property cells 'Range rc)
    
29. )
    
30. (vlax-put-property range  'value2
    
31.     (vlax-safearray-fill
    
32.         (vlax-make-safearray
    
33.             vlax-vbstring
    
34.             (cons 1 (length lst))
    
35.             (cons 1 (length (car lst)))
    
36.         )
    
37.         lst
    
38.     )
    
39. )
    
40. ;(vlax-put-property (vlax-get-property sht "Range" "A:A") "ColumnWidth" 20);列宽20
    
41. ;(vlax-put-property (vlax-get-property sht "Range" "1:1") "RowHeight" 30);行高30
    
42. )

;;表快速输出 XLS<br /> (defun ls2xls (lst / _List:getRC  XD::Excel:i2ColNo  excel bks acBook sht rc  cells range)<br /> (defun XD::Excel:i2ColNo (a / l _i2ColNo)<br />   (defun _i2ColNo (num / lst)<br />     (cond<br />       ((<= 1 num 26) (setq lst (cons num lst)))<br />       ((> num 26) (setq lst (append (_i2ColNo (/ num 26)) (list (rem num 26)))))<br />       (t lst)<br />     ) lst<br />   )<br />   (if (and (>= (setq a (fix (abs a))) 1)<br />            (setq l (_i2ColNo a))<br />       )<br />     (apply 'strcat (mapcar '(lambda (x) (chr (+ 64 x))) l))<br />   )<br /> )<br /> (setq excel (vlax-get-or-create-object "Excel.Application"))<br /> (vla-put-visible excel :vlax-true)<br /> (setq bks (vlax-get excel 'workbooks)<br />      acBook (vlax-invoke bks 'Add)<br />      sht  (vlax-get excel 'ActiveSheet)<br />      rc   (strcat "A1:"<br />                (xd::excel:i2ColNo (apply 'max (mapcar 'length lst)))<br />                (itoa (length lst))<br />            )<br />      cells (vlax-get sht 'cells)<br />      range (vlax-get-property cells 'Range rc)<br /> )<br /> (vlax-put-property range  'value2<br />     (vlax-safearray-fill<br />         (vlax-make-safearray<br />             vlax-vbstring<br />             (cons 1 (length lst))<br />             (cons 1 (length (car lst)))<br />         )<br />         lst<br />     )<br /> )<br /> ;(vlax-put-property (vlax-get-property sht "Range" "A:A") "ColumnWidth" 20);列宽20<br /> ;(vlax-put-property (vlax-get-property sht "Range" "1:1") "RowHeight" 30);行高30<br /> )

渠辉

2. (defun table:List (lst pt rowheight colwidth / tb i maxcol)
   
3.   (setq tb (vla-addtable (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))
   
4.              (vlax-3d-point pt)
   
5.              (1+ (length lst))
   
6.              (apply 'max (mapcar 'length lst))
   
7.              rowheight
   
8.              colwidth
   
9.            )
   
10.   )
    
11.   (setq i 0)
    
12.   (vla-setalignment tb acdatarow acmiddlecenter)
    
13.   (mapcar '(lambda (x / j)
    
14.              (setq i (1+ i)  j -1)
    
15.              (mapcar '(lambda (a) (vla-settext tb i (setq j (1+ j)) a)) x)
    
16.            )
    
17.           lst
    
18.   )
    
19. )
    
20. 
    

(defun table:List (lst pt rowheight colwidth / tb i maxcol)<br />   (setq tb (vla-addtable (vla-get-modelspace (vla-get-activedocument (vlax-get-acad-object)))<br />              (vlax-3d-point pt)<br />              (1+ (length lst))<br />              (apply 'max (mapcar 'length lst))<br />              rowheight<br />              colwidth<br />            )<br />   )<br />   (setq i 0)<br />   (vla-setalignment tb acdatarow acmiddlecenter)<br />   (mapcar '(lambda (x / j)<br />              (setq i (1+ i)  j -1)<br />              (mapcar '(lambda (a) (vla-settext tb i (setq j (1+ j)) a)) x)<br />            )<br />           lst<br />   )<br /> )<br /> <br />

LPACMQ

给你参考下

;;---------------------=={ Add Table }==----------------------;;
;;                                                            ;;
;;  Creates a VLA Table Object at the specified point,        ;;
;;  populated with title and data                             ;;
;;------------------------------------------------------------;;
;;  Author: Lee Mac, Copyright ?2011 - www.lee-mac.com        ;;
;;------------------------------------------------------------;;
;;  Arguments:                                                ;;
;;  space - VLA Block Object                                  ;;
;;  pt    - Insertion Point for Table                         ;;
;;  title - Table title                                       ;;
;;  data  - List of data to populate the table                ;;
;;------------------------------------------------------------;;
;;  Returns:  VLA Table Object                                ;;
;;------------------------------------------------------------;;

;;;;函数：LM:AddTable
;;;;功能：Add Table -by lee mac
;;;;示例：
;;(setq acdoc (vla-get-activedocument (vlax-get-acad-object))
;;        acspc (vlax-get-property acdoc (if (= 1 (getvar 'CVPORT)) 'Paperspace 'Modelspace))
;;  )
;;
;;(LM:AddTable acspc (trans (getpoint) 1 0) "圆坐标统计" (cons '("标记" "直径" "X" "Y") data))

(defun LM:AddTable ( space pt title data / _isAnnotative textheight style )

  (defun _isAnnotative ( style / object annotx )
    (and
      (setq object (tblobjname "STYLE" style))
      (setq annotx (cadr (assoc -3 (entget object '("AcadAnnotative")))))
      (= 1 (cdr (assoc 1070 (reverse annotx))))
    )
  )

  (
    (lambda ( table ) (vla-put-StyleName table (getvar 'CTABLESTYLE)) (vla-SetText table 0 0 title)
      (
        (lambda ( row )
          (mapcar
            (function
              (lambda ( rowitem ) (setq row (1+ row))
                (
                  (lambda ( column )
                    (mapcar
                      (function
                        (lambda ( item )
                          (vla-SetText table row (setq column (1+ column)) item)
                        )
                      )
                      rowitem
                    )
                  )
                  -1
                )
              )
            )
            data
          )
        )
        0
      )
      table
    )
    (
      (lambda ( textheight )
        (vla-AddTable space (vlax-3D-point pt) (1+ (length data)) (length (car data)) textheight
          (* 0.8 textheight ;;文本高度
            (apply 'max
              (cons (/ (strlen title) (length (car data)))
                (mapcar 'strlen (apply 'append data))
              )
            )
          )
        )
      )
      (* 1.2  ;;表格宽度
        (/
          (setq textheight
            (vla-gettextheight
              (setq style
                (vla-item
                  (vla-item
                    (vla-get-dictionaries (vla-get-document space)) "ACAD_TABLESTYLE"
                  )
                  (getvar 'CTABLESTYLE)
                )
              )
              acdatarow
            )
          )
          (if (_isAnnotative (vla-gettextstyle style acdatarow))
            (cond ( (getvar 'CANNOSCALEVALUE) ) ( 1.0 ))
            1.0
          )
        )
      )
    )
  )
)

;;------------------------------------------------------------;;
;;                         End of File                        ;;
;;------------------------------------------------------------;;

丶吟游诗人灬

LPACMQ 发表于 2023-6-15 23:09
给你参考下

;;---------------------=={ Add Table }==----------------------;;

谢谢  已经解决了