利用向量求点到直线的垂直距离

dtucad

上次弄了个利用向量计算两条直线的夹角http://bbs.mjtd.com/thread-188543-1-1.html

这次利用上次的函数求点到直线的垂直距离
没啥技术含量，向量入门知识，希望对新手有用。
水平有限，如有错误，请不吝指正。

2. ;利用向量求点到直线的垂直距离
   
3. ;参数1、2：直线起点、终点
   
4. ;参数3：直线外一点
   
5. ;返回值：点到直线的垂直距离
   
6. (defun distance-to-line (p1 p2 cp / ang dis)
   
7.   (setq ang (angle-between-lines p1 p2 p1 cp));以p1为起点的2条直线的夹角
   
8.   (setq dis (distance p1 cp));三角形斜边长度
   
9.   (* dis (sin ang))
   
10. )
    
11. 
    
12. ;利用向量计算两条直线的夹角 上次发过的函数
    
13. ;参数：直线1起点、终点，直线2起点、终点
    
14. ;返回夹角的弧度值
    
15. (defun angle-between-lines (p1 p2 p3 p4 / cosa dp m-v1 m-v2 v1 v2)
    
16.   (setq v1 (mapcar '- p2 p1)); 计算直线1的方向向量
    
17.   (setq v2 (mapcar '- p4 p3)); 计算直线2的方向向量
    
18.   (setq dp (+ (* (car v1) (car v2)) (* (cadr v1) (cadr v2)) (* (caddr v1) (caddr v2)))) ; 计算两个向量的点积
    
19.   (setq m-v1 (sqrt (+ (* (car v1) (car v1)) (* (cadr v1) (cadr v1)) (* (caddr v1) (caddr v1))))) ; 计算向量v1的模长
    
20.   (setq m-v2 (sqrt (+ (* (car v2) (car v2)) (* (cadr v2) (cadr v2)) (* (caddr v2) (caddr v2))))) ; 计算向量v2的模长
    
21.   (setq cosA (/ dp (* m-v1 m-v2))) ; 计算夹角的余弦值
    
22.   (if (zerop cosA) ; 判断是否0值
    
23.     (/ pi 2) ; 0值时为0.5pi
    
24.     (atan (sqrt (- 1.0 (* cosA cosA))) cosA) ; 利用反正切函数求反余弦
    
25.   )
    
26. )
    
27. 
    
28. ;测试用
    
29. (defun c:tt (/ cp dis p1 p2)
    
30.   (if (and
    
31.         (setq p1 (getpoint "\n指定直线起点"))
    
32.         (setq p2 (getpoint p1 "\n指定直线终点"))
    
33.         (setq cp (getpoint "\n指定直线外一点"))
    
34.       )
    
35.     (progn
    
36.       (setq dis (distance-to-line p1 p2 cp))
    
37.       (princ (strcat "\n点到直线的距离为：" (rtos dis 2 4)))
    
38.     )
    
39.   )
    
40.   (princ)
    
41. )
    

;利用向量求点到直线的垂直距离<br /> ;参数1、2：直线起点、终点<br /> ;参数3：直线外一点<br /> ;返回值：点到直线的垂直距离<br /> (defun distance-to-line (p1 p2 cp / ang dis)<br />   (setq ang (angle-between-lines p1 p2 p1 cp));以p1为起点的2条直线的夹角<br />   (setq dis (distance p1 cp));三角形斜边长度<br />   (* dis (sin ang))<br /> )<br /> <br /> ;利用向量计算两条直线的夹角 上次发过的函数<br /> ;参数：直线1起点、终点，直线2起点、终点<br /> ;返回夹角的弧度值<br /> (defun angle-between-lines (p1 p2 p3 p4 / cosa dp m-v1 m-v2 v1 v2)<br />   (setq v1 (mapcar '- p2 p1)); 计算直线1的方向向量<br />   (setq v2 (mapcar '- p4 p3)); 计算直线2的方向向量<br />   (setq dp (+ (* (car v1) (car v2)) (* (cadr v1) (cadr v2)) (* (caddr v1) (caddr v2)))) ; 计算两个向量的点积<br />   (setq m-v1 (sqrt (+ (* (car v1) (car v1)) (* (cadr v1) (cadr v1)) (* (caddr v1) (caddr v1))))) ; 计算向量v1的模长<br />   (setq m-v2 (sqrt (+ (* (car v2) (car v2)) (* (cadr v2) (cadr v2)) (* (caddr v2) (caddr v2))))) ; 计算向量v2的模长<br />   (setq cosA (/ dp (* m-v1 m-v2))) ; 计算夹角的余弦值<br />   (if (zerop cosA) ; 判断是否0值<br />     (/ pi 2) ; 0值时为0.5pi<br />     (atan (sqrt (- 1.0 (* cosA cosA))) cosA) ; 利用反正切函数求反余弦<br />   )<br /> ) <br /> <br /> ;测试用<br /> (defun c:tt (/ cp dis p1 p2)<br />   (if (and <br />         (setq p1 (getpoint "\n指定直线起点"))<br />         (setq p2 (getpoint p1 "\n指定直线终点"))<br />         (setq cp (getpoint "\n指定直线外一点"))<br />       )<br />     (progn<br />       (setq dis (distance-to-line p1 p2 cp))<br />       (princ (strcat "\n点到直线的距离为：" (rtos dis 2 4)))<br />     )<br />   )<br />   (princ)<br /> )<br />

tigcat

点到直线距离应该是一句话函数.高飞版主trans讲课中最后实例有提到.

自贡黄明儒

tigcat 发表于 2023-9-11 23:24
点到直线距离应该是一句话函数.高飞版主trans讲课中最后实例有提到.

这里解释得也很清楚http://bbs.mjtd.com/thread-188468-1-1.html

dtucad

trans背后实质是用的矩阵变换，这只是桌子提供的一个轮子，虽然用起来很方便，但是并不是因为有了这个轮子，我们就不用学习向量、矩阵的知识了。
这只是向量应用的一个例子而已，并不是说它有多高级，有多省代码，主要是帮助学习向量，理解底层原理，理解了底层原理才能造出新的轮子。
假如桌子没有提供distance函数，你能利用向量计算出两点的距离吗？

x_s_s_1

没那么复杂

1. (defun distance-to-line         (p1 p2 cp / vxv)
   
2.     (defun vxv        (u v)
   
3.         (list (- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))
   
4.               (- (* (car v) (caddr u)) (* (car u) (caddr v)))
   
5.               (- (* (car u) (cadr v)) (* (car v) (cadr u)))))
   
6.     (/ (distance '(0 0 0)
   
7.                  (vxv (mapcar '- cp p1) (mapcar '- cp p2)))
   
8.        (distance p1 p2)))

(defun distance-to-line         (p1 p2 cp / vxv)<br />     (defun vxv        (u v)<br />         (list (- (* (cadr u) (caddr v)) (* (cadr v) (caddr u)))<br />               (- (* (car v) (caddr u)) (* (car u) (caddr v)))<br />               (- (* (car u) (cadr v)) (* (car v) (cadr u)))))<br />     (/ (distance '(0 0 0)<br />                  (vxv (mapcar '- cp p1) (mapcar '- cp p2)))<br />        (distance p1 p2)))

vormittag

dtucad 发表于 2023-9-12 09:50
trans背后实质是用的矩阵变换，这只是桌子提供的一个轮子，虽然用起来很方便，但是并不是因为有了这个轮子 ...

1. (sqrt (apply '+ (mapcar '(lambda (x y)  (* (- x y) (- x y)) ) pt1 pt2)))

复制代码

用这一问太简单了。