设为首页收藏本站CAD论坛CAD教程CAD下载明经币充值
切换到宽版

明经CAD社区

 找回密码
 注册

QQ登录

只需一步，快速开始

搜索
明经CAD社区»社区 › 开发篇 › AutoLISP/Visual LISP 编程技术 › 移动、复制综合集成
返回列表 发新帖
查看: 828|回复: 2

[资源] 移动、复制综合集成

[复制链接]
尘缘一生
发表于 2024-4-10 17:13:45 | 显示全部楼层 |阅读模式
本帖最后由 尘缘一生 于 2024-4-10 22:33 编辑

这部分，任何二开都应该做好集成，不属于专业类，并且，在使用中不断的完善，放一下三领的集成代码，
这部分，可能C开发的速度更快，经过这么久的使用，矩阵也好，函数也好，这部分还不如command ，也许只有期待C了。
这三个函数，不能独立运行，如果你拿来主义，绕道吧，需三领支持测试。

链接：https://pan.baidu.com/s/185B4hyR4cnC65UBfp0CX5Q
提取码：n0vh
  2. ;;实体、选择集9点位移动到 pt定位-----(一级)----
  3. ;;pt 定位点
  4. (defun slmov9 (ss pt / os bb ms1 ms2 loop pt0 p0 e1 ee)
  5.   (defun ssk (ss k)
  6.     (if (= (sslength ss) 1)
  7.       (setq pt0 (e9pt (ssname ss 0) k))
  8.       (setq pt0 (ss9pt ss k))
  9.     )
  10.     pt0
  11.   )
  12.   ;;------------
  13.   (setq ms1
  14.     (strcat
  15.       (slmsg
  16.         "\n->定位 [左下(1)/下中(2)/右下(3)/左中(4)/正中(5)/右中(6)/左上(7)/上中(8)/右上(9)/"
  17.         "\n->﹚ [オ(1)/い(2)/(3)/オい(4)/タい(5)/い(6)/オ(7)/い(8)/(9)/"
  18.         "\n->Positioning [Lower left (1)/Lower middle (2)/Lower right (3)/Middle left (4)/Centering (5)/Middle right (6)/Upper left (7)/Upper middle (8)/Upper right (9)/"
  19.       )
  20.       (slmsg
  21.         "逆转90度(TAB)/取角(A)/LIN.(E)/放大(Q)/缩小(W)/放大一倍(+)/缩小一半(-)](左键、右键、空格>定位)"
  22.         "癴锣90(TAB)/à(A)/LIN.(E)/(Q)/罽(W)/(+)/罽(-)](オ龄龄>﹚)"
  23.         "Rever90(TAB)/Takang(A)/LIN.(E)/Enlarge(Q)/Reduce(W)/Double(+)/Half(-)](Left,Right,Space>Locate)"
  24.       )
  25.     )
  26.   )
  27.   (setq os (getvar "OSMODE"))
  28.   (setvar "OSMODE" 0)
  29.   (setq p0 (ssk ss 5) pt0 (cadr (grread 5)) pt0 (polar pt0 (angle pt0 p0) (distance pt0 p0)))
  30.   (if (= pt nil) (setq pt pt0))
  31.   (setq ms2 (slmsg "-->当前<正中>" "-->讽玡<タい>" "-->Current<Center>"))
  32.   (princ (strcat ms1 ms2))
  33.   (setq loop T)
  34.   (while loop
  35.     (redraw)
  36.     (slslx pt 0)
  37.     (setq bb (grread T 8))
  38.     (cond
  39.       ((or (= (car bb) 3) ;;左键
  40.          (= (car bb) 11)  ;;右键设置为回车时
  41.          (= (car bb) 25)  ;;右键设置为屏幕菜单时
  42.          (equal bb '(2 32))  ;;空格键
  43.        )
  44.         (setq loop nil)
  45.       )
  46.       ((member bb '((2 65) (2 97)))   ;;A 旋转定角
  47.         (setq a (ss9pt ss 5))
  48.         (setq b (polar a 0 500))
  49.         (command ".rotate" ss "" "_non" a "r" "_non" a b pause)
  50.       )
  51.       ((member bb '((2 69) (2 101)))   ;;E e 齐线
  52.         (setq ss (ss-rotang ss 0))
  53.         (setq e1 (car (setq ee (entsel (slmsg "\n -->请选择要对齐的实体" "\n -->叫匡拒璶癸霍龟砰" "\n -->Please select the entity to align")))))
  54.         (setq ang (e-ang e1 (cadr ee)))
  55.         (setq ss (ss-rotang ss ang))
  56.       )
  57.       ((member bb '((2 9)))      ;;table 键
  58.         (command "ROTATE" ss "" pt 90)
  59.       )
  60.       ((member bb '((2 87) (2 119)))     ;;缩小  W w
  61.         (command "scale" ss "" pt "0.9")
  62.       )
  63.       ((member bb '((2 81) (2 113)))     ;;放大  Q q
  64.         (command "scale" ss "" pt "1.1")
  65.       )
  66.       ((equal bb '(2 45))         ;;缩小一半 -
  67.         (command "scale" ss "" pt "0.5")
  68.       )
  69.       ((member bb '((2 43) (2 61)))  ;;放大一倍 +
  70.         (command "scale" ss "" pt "2.0")
  71.       )
  72.       ((equal bb '(2 49))  ;; 1键
  73.         (setq pt0 (ssk ss 1))
  74.         (setq ms2 (slmsg "当前<左下>" "讽玡<オ>" "Current<Bottom Left>"))
  75.         (command "move" ss "" pt0 pt)
  76.         (princ (strcat ms1 ms2))
  77.       )
  78.       ((equal bb '(2 50)) ;; 2键
  79.         (setq pt0 (ssk ss 2))
  80.         (setq ms2 (slmsg "当前<下中>" "讽玡<い>" "Current<Lower Middle>"))
  81.         (command "move" ss "" pt0 pt)
  82.         (princ (strcat ms1 ms2))
  83.       )
  84.       ((equal bb '(2 51)) ;; 3键
  85.         (setq pt0 (ssk ss 3))
  86.         (setq ms2 (slmsg "当前<右下>" "讽玡<>" "Current<Bottom Right>"))
  87.         (command "move" ss "" pt0 pt)
  88.         (princ (strcat ms1 ms2))
  89.       )
  90.       ((equal bb '(2 52))  ;; 4键
  91.         (setq pt0 (ssk ss 4))
  92.         (setq ms2 (slmsg "当前<左中>" "讽玡<オい>" "Current<middle left>"))
  93.         (command "move" ss "" pt0 pt)
  94.         (princ (strcat ms1 ms2))
  95.       )
  96.       ((equal bb '(2 53))  ;; 5键
  97.         (setq pt0 (ssk ss 5))
  98.         (setq ms2 (slmsg "当前<正中>" "讽玡<タい>" "Current<Center>"))
  99.         (command "move" ss "" pt0 pt)
  100.         (princ (strcat ms1 ms2))
  101.       )
  102.       ((equal bb '(2 54)) ;; 6键
  103.         (setq pt0 (ssk ss 6))
  104.         (setq ms2 (slmsg "当前<右中>" "讽玡<い>" "Current<middle right>"))
  105.         (command "move" ss "" pt0 pt)
  106.         (princ (strcat ms1 ms2))
  107.       )
  108.       ((equal bb '(2 55)) ;; 7键
  109.         (setq pt0 (ssk ss 7))
  110.         (setq ms2 (slmsg "当前<左上>" "讽玡<オ>" "Current<Top Left>"))
  111.         (command "move" ss "" pt0 pt)
  112.         (princ (strcat ms1 ms2))
  113.       )
  114.       ((equal bb '(2 56)) ;; 8键
  115.         (setq pt0 (ssk ss 8))
  116.         (setq ms2 (slmsg "当前<上中>" "讽玡<い>" "Current<Top Middle>"))
  117.         (command "move" ss "" pt0 pt)
  118.         (princ (strcat ms1 ms2))
  119.       )
  120.       ((equal bb '(2 57))  ;; 9键
  121.         (setq pt0 (ssk ss 9))
  122.         (setq ms2 (slmsg "当前<右上>" "讽玡<>" "Current<Top Right>"))
  123.         (command "move" ss "" pt0 pt)
  124.         (princ (strcat ms1 ms2))
  125.       )
  126.     )
  127.   )
  128.   (setvar "OSMODE" os)
  129.   (redraw)
  130. )
  131. ;;铺捉、正交移动、复制、旋转、放缩....---(一级)----
  132. ;;ss: 图块 选择集 实体 实体表 || p0:移动起点 or nil
  133. ;;(domov-os (setq ss (ssget)) p0)
  134. ;;图块返回图块 ;其他 处理后选择集
  135. (defun domov-os (ss p0 / e_lst pt pt1 loop ang ang0 dis f3 f8 bb p10 p00 n e ee kk a b nam e1 ee)
  136.   (if (= p0 nil) (setq p0 (ssmpt ss)))
  137.   (if (null c:sl-tkgl)
  138.     (load (strcat sl-path0 "\\Support\" "sl-tkgl.VLX"))
  139.   )
  140.   (setq e_lst (sysvar '("CMDECHO" "NOMUTT" "OSMODE" "ORTHOMODE")) ee (entlast))
  141.   (cond
  142.     ((and (= (type ss) 'ENAME) (/= (dxf1 ss 0) "INSERT")) ;图元
  143.       (setq e (sl-sb (ssadd ss) p0) kk t)
  144.     )
  145.     ((and (= (type ss) 'ENAME) (= (dxf1 ss 0) "INSERT")) ;图块
  146.       (setq e ss kk nil)
  147.     )
  148.     ((= (type ss) 'LIST) ;实体表
  149.       (setq ss (sl:pickset-fromlist ss))
  150.       (setq e (sl-sb ss p0) kk t)
  151.     )
  152.     ((= (type ss) 'PICKSET) ;选择集
  153.       (if (> (sslength ss) 1)
  154.         (setq e (sl-sb ss p0) kk t)
  155.       )
  156.       (if (= (sslength ss) 1)
  157.         (progn
  158.           (setq nam (ssname ss 0))
  159.           (if (= (dxf1 nam 0) "INSERT")
  160.             (setq e nam kk nil)
  161.             (setq e (sl-sb ss p0) kk t)
  162.           )
  163.         )
  164.       )
  165.     )
  166.   )
  167.   (command "_.undo" "be")
  168.   (setvar "CMDECHO" 0)
  169.   (setvar "NOMUTT" 1)
  170.   (princ
  171.     (slmsg
  172.       "\n->[逆转90度(TAB)/取角(A)/LIN.(E)/<-镜向->(D)/↑镜向 ↓(S)/放大(Q)/缩小(W)/大一倍(+)/小一半(-)/基点(X)/正交(F8)/扑捉(F3)](空格..复制)(左键 插入)(右键 退出)"
  173.       "\n->[癴锣90(TAB)/à(A)/LIN.(E)/<-描->(D)/◆描 □(S)/(Q)/罽(W)/(+)/(-)/膀翴(X)/タユ(F8)/汲(F3)](..確)(オ龄 础)(龄 癶)"
  174.       "\n->[Rever90(TAB)/Takang (A)/LIN.(E)/<-mir->(D)/↑mir ↓(S)/Zoom1.1(Q)/Zoom0.9(W)/Zoom2.0(+)/Zoom0.5(-)/Base point(X)/Orth(F8)/Osnap(F3)](Spaced..copy)(Left Insert)(Right Exit)"
  175.     )
  176.   )
  177.   (setq loop t pt1 p0 ang 0 f8 (getvar "ORTHOMODE") f3 (getvar "OSMODE"))
  178.   (while loop
  179.     (setq bb (grread t 15 2) p00 (cadr bb))
  180.     (cond
  181.       ((equal bb '(2 6))    ;F3切换捕捉开关
  182.         (cond
  183.           ((and (< f3 16384) (/= f3 0))
  184.             (setq f3 (+ f3 16384))
  185.             (prompt (slmsg "\n <对象捕捉 关>" "\n <癸禜 闽>" "\n <OSnap Off>"))
  186.           )
  187.           ((or (= f3 0) (>= f3 16384))
  188.             (setq f3 16383)
  189.             (prompt (slmsg "\n <对象捕捉 开>" "\n <癸禜 秨>" "\n <OSnap On>"))
  190.           )
  191.         )
  192.         (setvar "OSMODE" f3) (redraw)
  193.       )   
  194.       ((equal bb '(2 15))    ;F8切换正交开关
  195.         (if (= f8 0)
  196.           (progn (setq f8 1) (prompt (slmsg "\n <正交 开>" "\n <タユ 秨>" "\n <Orth open>")))
  197.           (progn (setq f8 0) (prompt (slmsg "\n <正交 关>" "\n <タユ 闽>" "\n <Orth off>")))
  198.         )
  199.         (setvar "ORTHOMODE" f8) (redraw)
  200.       )
  201.       ((= (car bb) 5)
  202.         (redraw)
  203.         (if (= f8 1)
  204.           (if (< (abs (- (car p00) (car p0))) (abs (- (cadr p00) (cadr p0))))
  205.             (setq pt (list (car p00) (cadr p0)))
  206.             (setq pt (list (car p0)(cadr p00)))
  207.           )
  208.           (setq pt p00)
  209.         )
  210.         (if (> (/ (distance p0 p00) (getvar "VIEWSIZE")) 0.001)
  211.           (if (and (<= f3 16384) (> f3 0))
  212.             (sl_subupd e 10 (setq pt (slosnappt e pt)))
  213.             (sl_subupd e 10 pt)
  214.           )
  215.         )
  216.         (setq p0 pt)
  217.       )
  218.       ((member bb '((2 9)))  ;;table 键
  219.         (setq ang (+ ang pi2))
  220.         (sl_subupd e 50 ang)
  221.         (setq e (blkwzgz e))
  222.       )
  223.       ((member bb '((2 65) (2 97)))   ;;A 旋转定角
  224.         (redraw e 2)
  225.         (sl_subupd e 50 0)
  226.         (setq a (car (ebox4 e)))
  227.         (setq b (polar a 0 500))
  228.         (command ".rotate" e "" "_non" a "r" "_non" a (polar pt (angle pt b) (distance pt b)) pause)
  229.         (setq e (blkwzgz e))
  230.       )
  231.       ((member bb '((2 69) (2 101)))   ;;E e 齐线
  232.         (setq e1 (car (setq ee (entsel (slmsg "\n -->请选择要对齐的实体" "\n -->叫匡拒璶癸霍龟砰" "\n -->Please select the entity to align")))))
  233.         (setq ang (e-ang e1 (cadr ee)))
  234.         (sl_subupd e 50 ang)
  235.         (setq e (blkwzgz e))
  236.       )
  237.       ((member bb '((2 115) (2 83)))  ;;S s 上下翻
  238.         (command "mirror" e "" "_non" pt (mapcar '- pt '(1 0)) "Y")
  239.         (setq e (blkwzgz e))
  240.       )
  241.       ((member bb '((2 100) (2 68))) ;;D d 左右翻
  242.         (command "mirror" e "" "_non" pt (mapcar '- pt '(0 1)) "Y")
  243.         (setq e (blkwzgz e))
  244.       )
  245.       ((or (member bb '((2 13))) (= (car bb) 3));;左键、回车
  246.         (command "copy" e "" "_non" '(0 0) "_non" '(0 0))
  247.         (setq e (entlast) p10 (dxf1 e 10))
  248.         (setq ang0 (angle pt1 p10) dis (distance pt1 p10) pt1 p10)
  249.       )
  250.       ((and ang0 dis (member bb '((2 32)))) ;;空格键
  251.         (sl_subupd e 10 (setq p10 (polar p10 ang0 dis)))
  252.         (setq pt1 p10)
  253.         (command "copy" e "" "_non" '(0 0) "_non" '(0 0))
  254.         (setq e (entlast))
  255.       )
  256.       ((member bb '((2 87) (2 119)))         ;;缩小  W w
  257.         (command "scale" e "" "_non" pt "0.9")
  258.       )
  259.       ((member bb '((2 81) (2 113)))         ;;放大  Q q
  260.         (command "scale" e "" "_non" pt "1.1")
  261.       )
  262.       ((equal bb '(2 45))         ;;缩小一半 -
  263.         (command "scale" e "" "_non" pt "0.5")
  264.       )
  265.       ((member bb '((2 43) (2 61))) ;;放大一倍 +
  266.         (command "scale" e "" "_non" pt "2.0")
  267.       )
  268.       ((member bb '((2 88) (2 120)))  ;;基点 X x
  269.         (setq p0 (getpoint (slmsg "\n 基点" "\n 膀翴" "\n Basic Point")))
  270.         (sl-blockbaseedit e p0)
  271.       )
  272.       ((or t (member (car bb) '(11 25)));;右键 其余键
  273.         (entdel e)
  274.         (setq loop nil)
  275.       )
  276.     )
  277.   )
  278.   (setq s (last_ent ee))
  279.   (if (= kk t) ;非块
  280.     (repeat (setq n (sslength s))
  281.       (vl-catch-all-apply 'exp-blk (list (ssname s (setq n (1- n)))))
  282.     )
  283.   )
  284.   (command "_.undo" "e")
  285.   (mapcar 'eval e_lst)
  286.   ss
  287. )
  288. ;;移动-拷贝-旋转-镜像-递增-放缩------(一级)---------
  289. ;;ss:实体、实体表、选择集 p0 移动起点 nil | k: t(move) nil(copy)
  290. (defun sldomov (ss p0 k / e_lst p1 pt pt1 loop ang dis f3 f8 bb p00 a b e1 ee)
  291.   (setq e_lst (sysvar '("QAFLAGS" "CMDECHO" "NOMUTT" "OSMODE" "ORTHOMODE")))
  292.   (cond
  293.     ((= (type ss) 'ENAME) (setq ss (ssadd ss))) ;图元
  294.     ((= (type ss) 'LIST) (setq ss (sl:pickset-fromlist ss))) ;实体表
  295.   )
  296.   (command "_.undo" "be") ;;舍弃高级代码,加速
  297.   (setvar "CMDECHO" 0) ;;命令显示关闭
  298.   (setvar "NOMUTT" 1)
  299.   (setvar "QAFLAGS" 0)
  300.   (if (= p0 nil)
  301.     (setq p0 (ssmpt ss))
  302.   )
  303.   (princ
  304.     (slmsg
  305.       "\n->[逆转90度(TAB)/取角(A)/LIN.(E)/<-mir->(D)/↑mir ↓(S)/放大(Q)/缩小(W)/递增(Z)/递减(J)/大一倍(+)/小一半(-)/复制当前(C)/基点(X)/正交(F8)/扑捉(F3)](空格..复制)(左键>当前)(右键>退出)"
  306.       "\n->[癴锣90(TAB)/à(A)/LIN.(E)/<-mir->(D)/◆mir □(S)/(Q)/罽(W)/患糤(Z)/患搭(J)/(+)/(-)/確讽玡(C)/膀翴(X)/タユ(F8)/汲(F3)](..確)(オ龄>讽玡)(/龄>癶)"
  307.       "\n->[Rever90(TAB)/Takang(A)/LIN.(E)/<-mir->(D)/↑mir ↓(S)/Zoom1.1(Q)/Zoom0.9(W)/Increase(Z)/Decrease(J)/Zoom2.0(+)/Zoom0.5(-)/Copy current(C)/Base point(X)/Orth(F8)/Osnap(F3)]Spaced..Copy/Right>Exit"
  308.     )
  309.   )
  310.   (setq loop t pt1 p0 f8 (getvar "ORTHOMODE") f3 (getvar "OSMODE"))
  311.   (while loop
  312.     (setq bb (grread t 15 2) p00 (cadr bb))
  313.     (cond
  314.       ((equal bb '(2 6));F3切换捕捉开关
  315.         (cond
  316.           ((and (< f3 16384) (/= f3 0))
  317.             (setq f3 (+ f3 16384))
  318.             (prompt (slmsg "\n <对象捕捉 关>" "\n <癸禜 闽>" "\n <OSnap Off>"))
  319.           )
  320.           ((or (= f3 0) (>= f3 16384))
  321.             (setq f3 16383)
  322.             (prompt (slmsg "\n <对象捕捉 开>" "\n <癸禜 秨>" "\n <OSnap On>"))
  323.           )
  324.         )
  325.         (setvar "OSMODE" f3) (redraw)
  326.       )   
  327.       ((equal bb '(2 15))    ;F8切换正交开关
  328.         (if (= f8 0)
  329.           (progn (setq f8 1) (prompt (slmsg "\n <正交 开>" "\n <タユ 秨>" "\n <Orth open>")))
  330.           (progn (setq f8 0) (prompt (slmsg "\n <正交 关>" "\n <タユ 闽>" "\n <Orth off>")))
  331.         )
  332.         (setvar "ORTHOMODE" f8) (redraw)
  333.       )
  334.       ((= (car bb) 5)
  335.         (redraw)
  336.         (if (= f8 1)
  337.           (if (< (abs (- (car p00) (car p0))) (abs (- (cadr p00) (cadr p0))))
  338.             (setq pt (list (car p00) (cadr p0)))
  339.             (setq pt (list (car p0) (cadr p00)))
  340.           )
  341.           (setq pt p00)
  342.         )
  343.         (if (and (<= f3 16384) (> f3 0) (/= f8 1))
  344.           (setq pt (slosnappt ss pt))
  345.         )
  346.         (if (> (distance p0 pt) 0.001)
  347.           (command "move" ss "" "_non" p0 "_non" pt)
  348.         )
  349.         (setq p0 pt)
  350.       )
  351.       ((member bb '((2 9)))      ;;table 键
  352.         (command "ROTATE" ss "" "_non" pt 90)
  353.         (setq ss (sl-wzgz ss))
  354.       )
  355.       ((member bb '((2 65) (2 97)))   ;;A 旋转定角
  356.         (ss-rotang ss 0) ;选择集先转0度水平
  357.         (setq a (ss9pt ss 1))
  358.         (setq b (polar a 0 500))
  359.         (command ".rotate" ss "" "_non" a "r" "_non" a (polar pt (angle pt b) (distance pt b)) pause)
  360.         (setq ss (sl-wzgz ss))
  361.       )
  362.       ((member bb '((2 115) (2 83)))  ;;S s 上下翻
  363.         (command "mirror" ss "" "_non" pt (mapcar '- pt '(1 0)) "Y")
  364.       )
  365.       ((member bb '((2 100) (2 68))) ;;D d 左右翻
  366.         (command "mirror" ss "" "_non" pt (mapcar '- pt '(0 1)) "Y")
  367.       )
  368.       ((or (member bb '((2 13))) (= (car bb) 3));;左键、回车
  369.         (if (= k t) ;;移动
  370.           (setq loop nil)
  371.           (progn
  372.             (command "copy" ss "" "_non" '(0 0) "_non" '(0 0))
  373.             (setq ang (angle pt1 pt) dis (distance pt1 pt) pt1 pt)
  374.           )
  375.         )
  376.       )
  377.       ((member bb '((2 69) (2 101)))   ;;E e 齐线
  378.         (setq ss (ss-rotang ss 0))
  379.         (setq e1 (car (setq ee (entsel (slmsg "\n -->请选择要对齐的实体" "\n -->叫匡拒璶癸霍龟砰" "\n -->Please select the entity to align")))))
  380.         (setq ang (e-ang e1 (cadr ee)))
  381.         (setq ss (ss-rotang ss ang))
  382.         (setq ss (sl-wzgz ss))
  383.       )
  384.       ((member bb '((2 67) (2 99)))   ;;C c 复制在当前
  385.         (command "copy" ss "" "_non" '(0 0) "_non" '(0 0))
  386.         (setq ang (angle pt1 pt) dis (distance pt1 pt) pt1 pt)
  387.       )
  388.       ((and (member bb '((2 32))) ang dis) ;;空格键
  389.         (command "copy" ss "" "_non" '(0 0) "_non" '(0 0))
  390.         (command "MOVE" ss "" "_non" pt1 "_non" (setq pt1 (polar pt1 ang dis))) ;;移位
  391.       )
  392.       ((member bb '((2 87) (2 119)))         ;;缩小  W w
  393.         (command "scale" ss "" "_non" pt "0.9")
  394.       )
  395.       ((member bb '((2 81) (2 113)))         ;;放大  Q q
  396.         (command "scale" ss "" "_non" pt "1.1")
  397.       )
  398.       ((equal bb '(2 45))         ;;缩小一半 -
  399.         (command "scale" ss "" "_non" pt "0.5")
  400.       )
  401.       ((member bb '((2 43) (2 61))) ;;放大一倍 +
  402.         (command "scale" ss "" "_non" pt "2.0")
  403.       )
  404.       ((member bb '((2 90) (2 122)))  ;;递增 Z z
  405.         (setq ss (ss++ ss 1))
  406.       )
  407.       ((member bb '((2 74) (2 106)))  ;;递减 J j
  408.         (setq ss (ss++ ss -1))
  409.       )
  410.       ((member bb '((2 88) (2 120)))  ;;基点 X x
  411.         (command "MOVE" ss "" "_non" pt "_non" p0)  ;;移回去
  412.         (setq p1 (getpoint (slmsg "\n 基点" "\n 膀翴" "\n Basic Point")))
  413.         (command "MOVE" ss "" "_non" p1 "_non" p0)
  414.       )
  415.       ((or t (member (car bb) '(11 25)));;右键 其余键
  416.         (if (= k t) ;;移动
  417.           (command "MOVE" ss "" "_non" pt "_non" p0)  ;;移回去
  418.           (sl:erase ss)
  419.         )
  420.         (setq loop nil)
  421.       )
  422.     )
  423.   )
  424.   (redraw)
  425.   (command "_.undo" "e")
  426.   (mapcar 'eval e_lst)
  427.   (princ)
  428. )



"觉得好，就打赏"
打赏
还没有人打赏，支持一下
回复

使用道具 举报

尘缘一生
 楼主| 发表于 2024-4-10 20:14:33 | 显示全部楼层
本帖最后由 尘缘一生 于 2024-4-12 07:15 编辑
怕怕吓一跳 发表于 2024-4-10 17:34
老陈准备开源了吗

有些代码，我以后找也好找，放这里，加之，看就可知道啥意思了，我也没空抽调内裤。
主要我得目的是钓鱼，看谁能回复什么的，透露点好的思路，办法，我好改进。
因为，我并不满意，还有改进的地方。
回复 支持 1 反对 0

使用道具 举报

怕怕吓一跳
发表于 2024-4-10 17:34:05 | 显示全部楼层
老陈准备开源了吗
回复 支持 反对

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码，在未取得本站及作者授权的情况下，不得用于商业用途

GMT+8, 2024-11-25 19:48 , Processed in 0.186720 second(s), 26 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表