点转成阵列点表

aws

假设我有一个基点，我想阵列一些点表，如何写呢？

变量的话，可以给行个数，列个数，行距，列距，这四个变量。

nzl1116

;;;_$ (ttt '(0 0) 10 10 1 1)
;;; ((0 0) (1 0) (2 0) (3 0) (4 0) (5 0) (6 0) (7 0) (8 0) (9 0)
;;;  (0 1) (1 1) (2 1) (3 1) (4 1) (5 1) (6 1) (7 1) (8 1) (9 1)
;;;  (0 2) (1 2) (2 2) (3 2) (4 2) (5 2) (6 2) (7 2) (8 2) (9 2)
;;;  (0 3) (1 3) (2 3) (3 3) (4 3) (5 3) (6 3) (7 3) (8 3) (9 3)
;;;  (0 4) (1 4) (2 4) (3 4) (4 4) (5 4) (6 4) (7 4) (8 4) (9 4)
;;;  (0 5) (1 5) (2 5) (3 5) (4 5) (5 5) (6 5) (7 5) (8 5) (9 5)
;;;  (0 6) (1 6) (2 6) (3 6) (4 6) (5 6) (6 6) (7 6) (8 6) (9 6)
;;;  (0 7) (1 7) (2 7) (3 7) (4 7) (5 7) (6 7) (7 7) (8 7) (9 7)
;;;  (0 8) (1 8) (2 8) (3 8) (4 8) (5 8) (6 8) (7 8) (8 8) (9 8)
;;;  (0 9) (1 9) (2 9) (3 9) (4 9) (5 9) (6 9) (7 9) (8 9) (9 9))
(defun ttt (Insert x y dx dy / ret Vx Vy m n)
  (setq ret nil)
  (setq m 0)
  (setq Vy (cadr Insert))
  (while (< m y)
    (setq n 0)
    (setq Vx (car Insert))
    (while (< n x)
      (setq ret (cons (list Vx Vy) ret))
      (setq n (1+ n))
      (setq Vx (+ Vx dx))
    )
    (setq m (1+ m))
    (setq Vy (+ Vy dy))
  )
  (reverse ret)
)

xyp1964

1. (defun abc (pt nx ny dx dy / ptn tmp p0)
   
2.   "点阵列"
   
3.   ;; (abc '(0 0) 10 10 1 1)
   
4.   (setq p0 pt)
   
5.   (repeat ny
   
6.     (setq ptn '())
   
7.     (repeat nx
   
8.       (setq ptn (cons pt ptn)
   
9.             pt (polar pt 0 dx)
   
10.       )
    
11.     )
    
12.     (setq tmp (cons (reverse ptn) tmp)
    
13.           p0  (polar p0 (* pi 0.5) dy)
    
14.           pt  p0
    
15.     )
    
16.   )
    
17.   (reverse tmp)
    
18. )

(defun abc (pt nx ny dx dy / ptn tmp p0)<br />   "点阵列"<br />   ;; (abc '(0 0) 10 10 1 1)<br />   (setq p0 pt)<br />   (repeat ny<br />     (setq ptn '())<br />     (repeat nx<br />       (setq ptn (cons pt ptn)<br />             pt (polar pt 0 dx)<br />       )<br />     )<br />     (setq tmp (cons (reverse ptn) tmp)<br />           p0  (polar p0 (* pi 0.5) dy)<br />           pt  p0<br />     )<br />   )<br />   (reverse tmp)<br /> )

start4444

(defun ptlst (p0 xn yn xd yd / i ii plst px)       
(setq plst '())
(setq i -1)       
(repeat xn (setq plst (cons (setq px (polar p0 (* 0 pi) (* (setq i (1+ i)) xd))) plst))        
(setq ii 0)                
(if (/= yn 1)
(repeat (1- yn) (setq plst (cons (polar px (* 0.5 pi) (* (setq ii (1+ ii)) yd)) plst))));re2         
        );re1
plst               
)

飞雪神光

两层while循环 polar算点 copy复制 (或vla-Copy复制后 vla-Move移动)

aws

飞雪神光 发表于 2024-5-15 17:25
两层while循环 polar算点 copy复制 (或vla-Copy复制后 vla-Move移动)

我意思是通过表操作来转换。

start4444

polar计算点坐标加入表保存，关键要确定基础点的位置，左上？右下？中间？之后点表的排列顺序？

aws

start4444 发表于 2024-5-15 17:57
polar计算点坐标加入表保存，关键要确定基础点的位置，左上？右下？中间？之后点表的排列顺序？

都无所谓，默认左下吧

guosheyang

vlisp好像有阵列函数啊

guosheyang

vla-ArrayRectangular     vla-ArrayPolar  

guosheyang

如果没有实体点   就 ploar   或者向量计算