隧道超欠挖标注

cjf160204

隧道超欠挖标注，效果不好希望大神帮忙优化

技术工作室

修改了make-dimension子函数的参数如下：
;;说明:绘制超欠挖标注参数说明
;;参数:p14:实测开挖线上的实测点
;;参数:p13:设计线上的对应的垂直点
;;参数:p11:标注文字放置的点
;;参数:dimsty:前缀符号超挖为"+<>"；欠挖为"-<>"
;;参数:ys:箭头及线颜色
;;示例make-dimension pt@curve pt p11 "-<>" 1);箭头及线颜色1 红色
(defun make-dimension (p14 p13 p11 dimsty ys)
  (entmake (list '(0 . "DIMENSION")
                 '(100 . "AcDbEntity")
                 '(100 . "AcDbDimension")                 
                  (cons 10 p14)
                  (cons 11 p11)
                 '(70 . 33)
                  (cons 1 dimsty);前缀符号
                  (cons 3 "超欠挖")
                 '(100 . "AcDbAlignedDimension")
                 (cons 13 p13)
                 (cons 14 p14)
                 (cons 62 ys) ;箭头及线颜色
                 )
           );endmake  
  );end defun

技术工作室

试一试看看是不是你要的效果
;文件名：PB.lsp
;;功能说明：标注实际开挖线各点与设计开挖线之间的距离
;;;修改时间：2015-01-07  ss en v-en pc ss1 en1 po-li n p11 pt pt@curve osm

(vl-load-com)
(defun c:PB(/ )  
  (setq osm (getvar "osmode"))  
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)  

  (while
    (progn
      (prompt "\n请选择设计开挖线：")
      (not(setq ss(ssget ":s" '((0 . "CIRCLE,*POLYLINE")))))
        );end progn
    (prompt "\n<<<<未选择到正确的对象，请重新选择!>>>>")
  );end while

  (setq en(ssname ss 0)
        v-en(vlax-ename->vla-object en)
    )  
  (setq pc(find-centerpoint en));找设计开挖线的型心

  (while(progn(prompt "\n请选择实际开挖线：")
                (not(setq ss1(ssget ":s" '((0 . "*POLYLINE")))))
        );end progn
    (prompt "\n<<<<未选择到正确的对象，请重新选择!>>>>")
  );end while

  (setq en1(ssname ss1 0))
  (setq po-li (vl-remove-if 'not (mapcar '(lambda (x) (if (= (car x) 10) (cdr x))) (entget en1))));取多段线顶点表

  (initget 6)
  (setq n (getint "\n 请输入实际开挖线上标注间隔数(默认为0):"))
  (if(null n)(setq n 0))

  (if(/= n 0)(setq po-li(get-new-point-list po-li n)));end if

  (foreach pt po-li   
    (setq pt@curve(vlax-curve-getClosestPointTo v-en pt))

    (if(> (distance pt pc) (distance pt@curve pc));如果超挖
      (progn
      (setq p11 (polar pt@curve (angle pt@curve pt) (* 2 (distance pt pt@curve))))
      ;(make-dimension pt pt@curve p11 "隧道超挖+")
      (make-dimension pt pt@curve p11 "+<>" 3);箭头及线颜色3 绿色
    ;   (command "_.pline" P11 pc "")
      );end progn
      );end if

    (if(< (distance pt pc) (distance pt@curve pc));如果欠挖
      (progn
      (setq p11(polar pt(angle pt pt@curve ) (* 3 (distance pt pt@curve))))
      ;(make-dimension pt@curve pt p11 "隧道欠挖-")
      (make-dimension pt@curve pt p11 "-<>" 1);箭头及线颜色1 红色
     ;  (command "_.pline" Pt p11 "")
      );end progn
      );end if

    );end foreach

  (setvar "osmode" osm)
  (princ)  
  );end defun

;;;sub-routine1
(defun find-centerpoint(en / po-li n y pc)
  (setq entda(entget en)
        ename(cdr(assoc 0 entda)))
  (if(= ename "CIRCLE")
    (setq pc(cdr(assoc 10 entda)))
    (progn
      (setq po-li (vl-remove-if 'not (mapcar '(lambda (x) (if (= (car x) 10) (cdr x))) entda)))
      (setq n(length po-li))  
      (setq y(apply 'mapcar (cons '+ po-li)))
      (setq pc(mapcar '/ y (list n n n)))
      );progn
    );end if
  );end defun

;;;sub-routine2
(defun make-dimension (p14 p13 p11 dimsty ys)
  (entmake (list '(0 . "DIMENSION")
                 '(100 . "AcDbEntity")
                 '(100 . "AcDbDimension")                 
                  (cons 10 p14)
                  (cons 11 p11)
                 '(70 . 33)
                  (cons 1 dimsty);前缀符号
                  (cons 3 "超欠挖")
                 '(100 . "AcDbAlignedDimension")
                 (cons 13 p13)
                 (cons 14 p14)
                 (cons 62 ys) ;箭头及线颜色
                 )
           );endmake  
  );end defun

;;;sub-routine3
;;;间隔N个数取点表
(defun get-new-point-list(li n / s-li i k)
  (setq s-li nil i 0 k (1+ n))

  (while(nth i li)
    (setq s-li(cons (nth i li) s-li))
    (setq i(+ i k))
    );end while

  (reverse s-li)
  );end defun

cjf160204

(vl-load-com)

(defun c:bz (/ osm ss ss1 en v-en pc en1 po-li n pt pt@curve p11 dims)
  (setq osm (getvar "osmode"))
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)

  ;; 选择设计开挖线
  (setq ss (ssget "_:S" '((0 . "CIRCLE,*POLYLINE"))))
  (if (not ss)
    (progn
      (prompt "\n<<<<未选择到正确的对象，请重新选择!>>>>")
      (exit)
    )
  )
  (setq en (ssname ss 0)
        v-en (vlax-ename->vla-object en)
        pc (find-centerpoint en)
  )

  ;; 选择实际开挖线
  (setq ss1 (ssget "_:S" '((0 . "*POLYLINE"))))
  (if (not ss1)
    (progn
      (prompt "\n<<<<未选择到正确的对象，请重新选择!>>>>")
      (exit)
    )
  )
  (setq en1 (ssname ss1 0)
        po-li (vl-remove-if 'not (mapcar '(lambda (x) (if (= (car x) 10) (cdr x))) (entget en1)))
  )

  ;; 获取标注间隔
  (initget 6)
  (setq n (getint "\n请输入实际开挖线上标注间隔数(默认为0):"))
  (if (null n) (setq n 0))
  (if (/= n 0) (setq po-li (get-new-point-list po-li n)))

  ;; 收集标注数据
  (setq dims '())
  (foreach pt po-li
    (setq pt@curve (if (= (cdr (assoc 0 (entget en))) "CIRCLE")
                       (get-closest-point-to-circle pc (cdr (assoc 40 (entget en))) pt)
                       (vlax-curve-getClosestPointTo v-en pt)
                   )
    )
    (if (> (distance pt pc) (distance pt@curve pc))
      (setq dims (cons (list pt pt@curve (polar pt@curve (angle pt@curve pt) (* 2 (distance pt pt@curve))) "+<>" 3) dims))
    )
    (if (< (distance pt pc) (distance pt@curve pc))
      (setq dims (cons (list pt@curve pt (polar pt (angle pt pt@curve) (* 3 (distance pt pt@curve))) "-<>" 1) dims))
    )
  )

  ;; 创建标注
  (foreach dim dims
    (make-dimension (nth 0 dim) (nth 1 dim) (nth 2 dim) (nth 3 dim) (nth 4 dim))
  )

  ;; 恢复设置
  (setvar "osmode" osm)
  (princ)
)

;;; 子程序：计算型心
(defun find-centerpoint (en / pc)
  (setq entda (entget en))
  (setq ename (cdr (assoc 0 entda)))
  (if (= ename "CIRCLE")
    (setq pc (cdr (assoc 10 entda)))
    (progn
      (setq po-li (vl-remove-if 'not (mapcar '(lambda (x) (if (= (car x) 10) (cdr x))) entda)))
      (setq n (length po-li))
      (setq y (apply 'mapcar (cons '+ po-li)))
      (setq pc (mapcar '/ y (list n n n)))
    )
  )
  pc
)

;;; 子程序：获取多段线顶点的间隔点
(defun get-new-point-list (li n / s-li i k)
  (setq s-li '() i 0 k (1+ n))
  (while (< i (length li))
    (setq s-li (cons (nth i li) s-li))
    (setq i (+ i k))
  )
  (reverse s-li)
)

;;; 子程序：创建标注
(defun make-dimension (p1 p2 p3 dimtext color)
  (entmake (list '(0 . "DIMENSION")
                 '(100 . "AcDbEntity")
                 '(100 . "AcDbDimension")
                 (cons 10 p1)
                 (cons 11 p3)
                 '(70 . 33)
                 (cons 1 dimtext)
                 (cons 3 "超欠挖")
                 '(100 . "AcDbAlignedDimension")
                 (cons 13 p2)
                 (cons 14 p1)
                 (cons 62 color)
                 )
           )
)

;;; 子程序：计算点到圆的最近点
(defun get-closest-point-to-circle (circle-pt radius pt)
  (let ((dx (- (car pt) (car circle-pt)))
        (dy (- (cadr pt) (cadr circle-pt))))
    (list (+ (car circle-pt) (* dx (/ radius (sqrt (+ (* dx dx) (* dy dy))))))
          (+ (cadr circle-pt) (* dy (/ radius (sqrt (+ (* dx dx) (* dy dy)))))))
  )
)

(princ "\n超欠挖标注工具已加载。输入命令 'bz' 开始使用。")
(princ)

czb203

优化啥东西，得说清楚用文字或者图的形式

CeGong.Com_____

没图。哎。可惜

cjf160204

这种效果。。。。。。。。。。。。。。。。

cjf160204

想要这种效果，欠挖未负。

cjf160204

;文件名：PB.lsp
;;功能说明：标注实际开挖线各点与设计开挖线之间的距离
;;;修改时间：2015-01-07  ss en v-en pc ss1 en1 po-li n p11 pt pt@curve osm

(vl-load-com)
(defun c:PB(/ )  
  (setq osm (getvar "osmode"))  
  (setvar "cmdecho" 0)
  (setvar "osmode" 0)  

  (while
    (progn
      (prompt "\n请选择设计开挖线：")
      (not(setq ss(ssget ":s" '((0 . "CIRCLE,*POLYLINE")))))
        );end progn
    (prompt "\n<<<<未选择到正确的对象，请重新选择!>>>>")
  );end while

  (setq en(ssname ss 0)
        v-en(vlax-ename->vla-object en)
    )  
  (setq pc(find-centerpoint en));找设计开挖线的型心

  (while(progn(prompt "\n请选择实际开挖线：")
                (not(setq ss1(ssget ":s" '((0 . "*POLYLINE")))))
        );end progn
    (prompt "\n<<<<未选择到正确的对象，请重新选择!>>>>")
  );end while

  (setq en1(ssname ss1 0))
  (setq po-li (vl-remove-if 'not (mapcar '(lambda (x) (if (= (car x) 10) (cdr x))) (entget en1))));取多段线顶点表

  (initget 6)
  (setq n (getint "\n 请输入实际开挖线上标注间隔数(默认为0):"))
  (if(null n)(setq n 0))

  (if(/= n 0)(setq po-li(get-new-point-list po-li n)));end if

  (foreach pt po-li   
    (setq pt@curve(vlax-curve-getClosestPointTo v-en pt))

    (if(> (distance pt pc) (distance pt@curve pc));如果超挖
      (progn
      (setq p11 (polar pt@curve (angle pt@curve pt) (* 2 (distance pt pt@curve))))
      ;(make-dimension pt pt@curve p11 "隧道超挖+")
      (make-dimension pt pt@curve p11)
    ;   (command "_.pline" P11 pc "")
      );end progn
      );end if

    (if(< (distance pt pc) (distance pt@curve pc));如果欠挖
      (progn
      (setq p11(polar pt(angle pt pt@curve ) (* 3 (distance pt pt@curve))))
;(make-dimension pt@curve pt p11 "隧道欠挖-")
(make-dimension pt@curve pt p11)
     ;  (command "_.pline" Pt p11 "")
      );end progn
      );end if

    );end foreach

  (setvar "osmode" osm)
  (princ)  
  );end defun

;;;sub-routine1
(defun find-centerpoint(en / po-li n y pc)
  (setq entda(entget en)
        ename(cdr(assoc 0 entda)))
  (if(= ename "CIRCLE")
    (setq pc(cdr(assoc 10 entda)))
    (progn
      (setq po-li (vl-remove-if 'not (mapcar '(lambda (x) (if (= (car x) 10) (cdr x))) entda)))
      (setq n(length po-li))  
      (setq y(apply 'mapcar (cons '+ po-li)))
      (setq pc(mapcar '/ y (list n n n)))
      );progn
    );end if
  );end defun

;;;sub-routine2
(defun make-dimension (p13 p14 p11 dimsty)
  (entmake (list '(0 . "DIMENSION")
                 '(100 . "AcDbEntity")
                 '(100 . "AcDbDimension")                 
                  (cons 10 p14)
                  (cons 11 p11)
                 '(70 . 33)
                 '(1 . "")
                  (cons 3 dimsty)
                 '(100 . "AcDbAlignedDimension")
                 (cons 13 p13)
                 (cons 14 p14)
                 )
           );endmake  
  );end defun

;;;sub-routine3
;;;间隔N个数取点表
(defun get-new-point-list(li n / s-li i k)
  (setq s-li nil i 0 k (1+ n))

  (while(nth i li)
    (setq s-li(cons (nth i li) s-li))
    (setq i(+ i k))
    );end while

  (reverse s-li)
  );end defun

cjf160204

这是网上找的不知道哪里有问题

cjf160204

错误应该是在make-dimension这个子程序中（或者说子函数），说有四个参数，主程序中只给了三个参量

技术工作室

修改后的效果如下