[求助]请教如何编程实现某图层在指定视口中冻结

e2002 · 发表于 2004-7-7 10:54:00

请教如何编程实现某图层在指定视口(Viewport in a Layout)中冻结?

依然小小鸟 · 发表于 2018-12-5 13:00:42

如何解冻跪求大神

citykunan · 发表于 2004-7-7 11:28:00

1.进入layout,layout中有多个viewport

2.进入某个viewport的model状态。

3.用vplayer--freeze可以冻结这个viewport的某个层。

龙龙仔 · 发表于 2004-7-7 13:12:00

;;(TTT "DIM,CENTER")
(defun TTT (LST / ENT)
(command "_PSPACE")
(setq ENT (cdr
(assoc 69 (entget (car (entsel "\nSelect Viewport: "))))
)
)
(command "_.MSPACE")
(setvar "cvport" ENT)
(command "_.vplayer" "f" LST "" "")
(princ)
)

e2002 · 发表于 2004-7-7 18:07:00

我是想有没有不通过调用command的办法?

秋枫 · 发表于 2004-7-7 20:51:00

这些信息是在xdata中的。很麻烦。ActiveX方法也很难，我是没有试出来。

我原来因为遍历Layout时重生成太费时间而想去冻结不用的图层，后来我放弃了。呵呵。

mccad · 发表于 2004-7-7 22:39:00

http://bbs.mjtd.com/forum.php?mod=viewthread&tid=19949

aeo000000 · 发表于 2004-7-8 00:00:00

viewport的所有冻结层:

(defun viewport-frozen-layers(/ cvp)
(if (= 0 (getvar "tilemode"))
(if (/= 1 (setq cvp (getvar "cvport")))
(apply
'append
(mapcar
'(lambda (x)
(if (= 1003 (car x))
(list (cdr x))
)
)
(cdadr
(assoc
-3
(entget
(ssname
(ssget "_X"
(list (cons 69 cvp) (cons 410 (getvar "ctab")))
)
0
)
'("acad")
)
)
))
))))

写出好东西，别忘了分享!!!!!

龙龙仔 · 发表于 2004-7-8 07:56:00

e2002发表于2004-7-7 18:07:00我是想有没有不通过调用command的办法?

我试出来了!只是忘了带,明天补上(就怕又忘了)

alin · 发表于 2004-7-8 21:15:00

本帖最后由作者于 2004-7-9 10:08:34 编辑

龙龙仔 · 发表于 2004-7-12 08:26:00

;;(freeze_lay '("DIM" "HATCH") (car (entsel "\nSelect Viewport: ")))
;;(freeze_lay <layer list> <Viewport ename>)
;;BY 龙龙仔(LUCAS)
(defun FREEZE_LAY (LST_1 ENT / ENT2 LST1 LST3 LST NN NEW TYPES VALUES
DATA PBJECT)
(vl-load-com)
(defun MAKE_VARIANT (X / V)
(cond
((= (type X) 'INT) (vlax-make-variant X 2))
((= (type X) 'REAL) (vlax-make-variant X 5))
((= (type X) 'STR) (vlax-make-variant X 8))
((= (type X) 'VLA-OBJECT) (vlax-make-variant X 9))
((and (= (type X) 'list)
(vl-remove-if-not 'numberp X)
(setq V (vlax-make-safearray
vlax-vbdouble
(cons 0 (1- (length X)))
)
)
(vlax-safearray-fill V X)
)
(vlax-make-variant V 8197)
)
)
) (setq ENT2 (assoc -3 (entget ENT '("ACAD"))))
(setq LST1 (reverse
(cdr (member (cons 1002 "{") (reverse (cdadr ENT2))))
)
)
(setq LST (mapcar (function (lambda (X) (strcase (cdr X))))
(vl-remove-if-not
(function (lambda (X) (= (car X) 1003)))
(cdadr ENT2)
)
)
)
(foreach NN LST_1
(if (and (tblsearch "layer" NN)
(not (member (strcase NN) LST))
)
(setq LST (append LST (list NN)))
)
)
(setq LST3 (mapcar (function (lambda (X)
(cons 1003 X)
)
)
LST
)
)
(setq NEW (append (list (cons 1001 "ACAD"))
LST1
(list (cons 1002 "{"))
LST3
(list (cons 1002 "}"))
(list (cons 1002 "}"))
)
)
(setq N (1- (length NEW)))
(setq TYPES (vlax-make-safearray vlax-vbinteger (cons 0 N)))
(vlax-safearray-fill TYPES (mapcar 'car NEW))
(setq VALUES (vlax-make-safearray vlax-vbvariant (cons 0 N)))
(setq
DATA (mapcar (function (lambda (X) (MAKE_VARIANT (cdr X)))) NEW)
)
(vlax-safearray-fill VALUES DATA)
(setq OBJECT (vlax-ename->vla-object ENT))
(not
(vl-catch-all-error-p
(vl-catch-all-apply
'vla-setxdata
(list OBJECT TYPES VALUES)
)
)
)
(if (= (vla-get-viewporton OBJECT) :vlax-true)
(progn
(vla-put-viewporton OBJECT :vlax-false)
(vla-put-viewporton OBJECT :vlax-true)
)
)
(princ)
)

;;(freeze_lay '("DIM" "HATCH") (car (entsel "\nSelect Viewport: ")))
;;(freeze_lay <layer list> <Viewport ename>)
;;BY 龙龙仔(LUCAS)
(defun FREEZE_LAY (LST_1 ENT / ENT2 LST1 LST3 LST NN NEW TYPES VALUES
         DATA  PBJECT)
   (vl-load-com)
   (defun MAKE_VARIANT (X / V)
       (cond
           ((= (type X) 'INT) (vlax-make-variant X 2))
           ((= (type X) 'REAL) (vlax-make-variant X 5))
           ((= (type X) 'STR) (vlax-make-variant X 8))
           ((= (type X) 'VLA-OBJECT) (vlax-make-variant X 9))
           ((and (= (type X) 'list)
         (vl-remove-if-not 'numberp X)
         (setq V (vlax-make-safearray
               vlax-vbdouble
               (cons 0 (1- (length X)))
           )
         )
         (vlax-safearray-fill V X)
             )
             (vlax-make-variant V 8197)
           )
       )
   )   (setq ENT2 (assoc -3 (entget ENT '("ACAD"))))
   (setq  LST1 (reverse
               (cdr (member (cons 1002 "{") (reverse (cdadr ENT2))))
           )
   )
   (setq  LST (mapcar (function (lambda (X) (strcase (cdr X))))
           (vl-remove-if-not
               (function (lambda (X) (= (car X) 1003)))
               (cdadr ENT2)
           )
         )
   )
   (foreach NN LST_1
       (if  (and (tblsearch "layer" NN)
           (not (member (strcase NN) LST))
  )
           (setq LST (append LST (list NN)))
       )
   )
   (setq  LST3 (mapcar (function (lambda (X)
         (cons 1003 X)
                   )
             )
             LST
           )
   )
   (setq  NEW (append (list (cons 1001 "ACAD"))
           LST1
           (list (cons 1002 "{"))
           LST3
           (list (cons 1002 "}"))
           (list (cons 1002 "}"))
         )
   )
   (setq N (1- (length NEW)))
   (setq TYPES (vlax-make-safearray vlax-vbinteger (cons 0 N)))
   (vlax-safearray-fill TYPES (mapcar 'car NEW))
   (setq VALUES (vlax-make-safearray vlax-vbvariant (cons 0 N)))
   (setq
       DATA (mapcar (function (lambda (X) (MAKE_VARIANT (cdr X)))) NEW)
   )
   (vlax-safearray-fill VALUES DATA)
   (setq OBJECT (vlax-ename->vla-object ENT))
   (not
       (vl-catch-all-error-p
           (vl-catch-all-apply
  'vla-setxdata
  (list OBJECT TYPES VALUES)
           )
       )
   )
   (if (= (vla-get-viewporton OBJECT) :vlax-true)
       (progn
           (vla-put-viewporton OBJECT :vlax-false)
           (vla-put-viewporton OBJECT :vlax-true)
       )
   )
   (princ)
)

账号		自动登录	找回密码
密码			注册

[求助]请教如何编程实现某图层在指定视口中冻结

本帖子中包含更多资源

评分

点评

浏览过的版块