[求助]VBA中怎样打开CHM帮助文件

zzz8662

VBA中怎样打开CHM帮助文件？点“帮助”按钮，打开文件。

efan2000

可以使用如Shell "hh.exe C:\Program Files\AutoCAD 2002\Help\acad.chm", vbNormalFocus的方式来打开帮助文件。

zzz8662

我想在自己程序的目录下打开啊

lgf727

用API来做,
先申明:
Public Const SW_SHOWNORMAL = 1
Public Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" _
(ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, _
ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
然后调用:
ShellExecute 0, "Open", 所在目录& "\帮助文件.chm", "", "", SW_SHOWNORMAL

莫名

在程序中调用CHM帮助文件的方法。
方法一　使用F1键：
这种方法最简单，只需如下代码即可：
Private Sub Form_Load()
App.HelpFile = app.path & "\help.chm" '调用与主程序同目录下的help.chm帮助文件，按F1键调用
End Sub

方法二 使用SendKeys方法：
Private Sub Form_Load()
App.HelpFile = app.path & "\help.chm"
End Sub
private Sub CmdHelp_Click()
SendKeys "{F1}" '发送击键到活动窗口
End Sub

方法三 使用Shell函数：
private Sub CmdHelp_Click()
Shell "hh.exe help.chm", vbNormalFocus 'help.chm为指定的帮助文件，可包含路径。
End Sub

方法四 使用HtmlHelp函数：
先声明如下API：
Option Explicit
Private Declare Function HtmlHelpA Lib "hhctrl.ocx" (ByVal hwndCaller As Long, ByVal pszFile As String, ByVal uCommand As Long, ByVal dwData As Long) As Long
'hwndCaller指定调用者的窗口，pszFile指定要调用的文件，uCommand是发送给 HtmlHelp的命令，dwData是uCommand的参数。
然后在过程中调用：
private Sub CmdHelp_Click()
dim i as string
i = app.path & "\help.chm" '用变量i记录与主程序同目录下的help.chm帮助文件
HtmlHelpA Form1.hWnd, i, 0, 0
End Sub

方法五 使用ShellExecute函数：
先声明如下API：
Option Explicit
'声明API函数用于异步打开一个文档
Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
Private Const SW_SHOWNORMAL = 1
然后在过程中调用：
private Sub CmdHelp_Click()
dim a as long
Dim b As String
b = App.Path & "\help.chm" '用变量b记录与主程序同目录下的help.chm帮助文件
a = ShellExecute (0, "open", b, "", "", SW_SHOWNORMAL)
End Sub
以上五种方法各有优缺点，从代码的简单上讲，建议使用第二种方法。从功能上讲，建议使用第五种方法，因其不只用于打开CHM帮助文件，还可用同样的格式打开、打印或查找一个文件或文档