请问，这个函数如何实现

syf

各位高人，我有一个问题想请教，我想通过程序从一个文本文档读入坐标，然后画出线来
文本文档格式如下：
6 ；坐标个数
2,4 3,5 2,6 5,7 4,9 4,7

还有一个问题
有一条直线和刚才的折线相交，要求程序能用折线将相交的直线裁切。

请帮忙解答，谢谢。（如有代码最好）

秋枫

(defun c:demo ()
  (makelines (GetPtlist (cadr (mc_getfile "c:/test.txt"))))
  (princ)
)

;;; 上式中用到自定义的函数

;;;getptlist作用： "2,4 3,5 2,6 5,7 4,9 4,7"
;;;->((2 4) (3 5) (2 6) (5 7) (4 9) (4 7))
(defun GetPtList (str / formatptlist )
  ;;formatptlst: (2 4 3 5 2 6 5 7 4 9 4 7)
  ;;->((2 4) (3 5) (2 6) (5 7) (4 9) (4 7))
  ;; 为简单起见这个函数用了递归，如果点极多列表很长，你自行改写一下以免溢出
  (defun FormatPtList (lst)
    (if        lst
      (cons (list (car lst) (cadr lst))
            (FormatPtList (cddr lst))
      )
      nil
    )
  )
  (setq str (vl-string-translate "," " " str))
  (setq str (strcat "(" str ")"))
  (formatptlist (read str))
)

(defun makelines (ptlst)
  (command "_.line")
  (mapcar ''((pt) (command "_non" pt)) ptlst)
        ; 此处的non临时屏蔽掉捕捉, 避免系统变量osmode设置
  (command ""); 如果闭合，改为(command "close")
)

;;;此函数载于本站明经道通函数中
;;;=============================================================
;;;mc_getfile
;;;读取文件并按行将文件转换为表
;;;参数
;;;files：文本文件名，如未指定路径则自动在搜索路径中查找文件
;;;返回值
;;;返回一个表，文件中一行被转换为表中的一个项，如果文件不存在，则返回nil
;;;示例
;;;(mc_getfile "tyl.ini")
;;;注意
;;;无
;;;作者
;;;郑立楷
(defun mc_getfile (files / tmplst x fn)
  (setq files (findfile files))
  (if files
    (progn
      (setq fn (open files "r"))
      (while (setq x (read-line fn))
        (setq tmplst (append tmplst (list x)))
      )
      (close fn)
      tmplst
    )
    nil
  )
)

秋枫

syf

非常感谢郑立楷老师的例子。

syf

非常感谢秋枫，不知我提出的第二个问题可有解决的方法，请告知，谢谢。

秋枫

你那个估计用trim命令即可解决。我没空写。提示一下，trim时选物体可以用fence方式。[br]

mccad

004

;;;此函数载于本站明经道通函数中
;;;=============================================================
;;;mc_getfile
;;;读取文件并按行将文件转换为表

这个明经通道函数集在哪,我以前怎么没听说过.哪位解释下,给个链接.

xiabin68

004 发表于 2012-12-18 16:18
;;;此函数载于本站明经道通函数中
;;;=============================================================
...

你找到了，也给我说声，，我还见你第一次说有明经通道的函数集，，

004

xiabin68 发表于 2012-12-18 18:56
你找到了，也给我说声，，我还见你第一次说有明经通道的函数集，，

刚翻到的http://www.mjtd.com/function/