求一個可以修改塊文字的程序

ljs026

请各位大大帮帮忙求一个可以修改块文字的程序。我知道晓东工具箱里有一个很棒的可以改块文字、属性块文字、一般文字，但这个程序能否调出单行文字的编辑功能表，而不是在命令列修改？

龙龙仔

;;BY LUCAS(龙龙仔)
(defun C:EDIT_TXT (/ ENT TYPE_NAME TMP_TXT SEL)
(vl-load-com)
(defun DO_IT ()
(entmake (list '(0 . "TEXT")
'(100 . "AcDbEntity")
'(100 . "AcDbText")
'(60 . 1)
'(10 0.0 0.0 0.0)
'(40 . 0.000000001)
(cons 1 (cdr (assoc 1 (entget ENT))))
)
)
(setq TMP_TXT (entlast))
(command "_.DDEDIT" TMP_TXT "")
(vla-put-textstring
(vlax-ename->vla-object ENT)
(cdr (assoc 1 (entget TMP_TXT)))
)
(entdel TMP_TXT)
) (if (setq SEL (nentsel "\nSelect Text:"))
(progn
(setq ENT (car SEL))
(setq TYPE_NAME (cdr (assoc 0 (entget ENT))))
(cond
((and (= TYPE_NAME "TEXT") (= (length SEL) 4))
(DO_IT)
(command "_.REGEN")
)
((wcmatch TYPE_NAME "TEXT,MTEXT,ATTDEF")
(command "_.DDEDIT" ENT "")
)
((= TYPE_NAME "ATTRIB") (DO_IT))
)
)
)
(princ)
)

ljs026

龙龙仔大大真是好人，太感谢了！再请教大大为何我试著点击直线标註时会出现<不正确 图元名称: 4007BC60>，而点第二下就可以编辑了？我想说这个功能可以取代AUTOCAD自带的功能说，那我的功能表上就可以再少一个Button了说

龙龙仔

你并没有说要改标註文字???那程序还要改动一下……

;;BY LUCAS(龙龙仔)
(defun C:EDIT_TXT (/ ENT TYPE_NAME TMP_TXT SEL)
(vl-load-com)
(defun DO_IT ()
(entmake (list '(0 . "TEXT")
'(100 . "AcDbEntity")
'(100 . "AcDbText")
'(60 . 1)
'(10 0.0 0.0 0.0)
'(40 . 0.000000001)
(cons 1 (cdr (assoc 1 (entget ENT))))
)
)
(setq TMP_TXT (entlast))
(command "_.DDEDIT" TMP_TXT "")
(vla-put-textstring
(vlax-ename->vla-object ENT)
(cdr (assoc 1 (entget TMP_TXT)))
)
(entdel TMP_TXT)
)
(if (setq SEL (nentsel "\nSelect Text:"))
(progn
(setq ENT (car SEL))
(setq TYPE_NAME (cdr (assoc 0 (entget ENT))))
(cond
((and (= TYPE_NAME "TEXT") (= (length SEL) 4))
(DO_IT)
(command "_.REGEN")
)
((wcmatch TYPE_NAME "TEXT,MTEXT,ATTDEF")
(if (and (equal TYPE_NAME "MTEXT") (= (length SEL) 4))
(setq ENT (car (last SEL)))
)
(command "_.DDEDIT" ENT "")
)
((= TYPE_NAME "ATTRIB") (DO_IT))
)
)
)
(princ)
)

ljs026

大大真是好人耶~~~