来看看啊，刚出炉的不能运行的程序！

honboo · 发表于 2004-12-10 13:50:00

大家帮我看看，错在哪里了呀？？ (setvar "osmode" 0)
(defun c:canal () ;;定义主函数名称
(setq base (getpoint "路线起点")) ;;获取起点坐标
(setq center (getpoint base "路线终点")) ;;获取终点坐标
(setq end (list (car center) (cadr base))) ;;固定纵坐标
(command "line" base end "") ;;做直线
(setq lenth (distance base center));;获取路线长度
(setq off (fix (/ (- lenth 50) 50)));;获取要排列的个数
(setq base1 base) ;;保存起点坐标给base1变量
(setq mark (getstring "输入第一个设备的桩号"));;获得第一个设备桩号如 K00+000形式
(setq oo atoi (substr (mark 2 1))) ;;00位转整
(setq ooo atoi (substr (mark 5 2))) ;;000位转整
(repeat off ;;开始循环，重复off次
(setq lenth1 (polar base1 0 50)) ;;极坐标方式寻找圆心，并存入变量lenth1中
(command "circle" lenth1 5 "") ;;画圆
(if (>= ooo 1000) (setq ooo (- ooo 1000))
(setq oo (+ oo 1))
(command "text" (polar lenth1 (/ 2 PI) 10) 3 strcat ("k" oo "+" ooo ))
(setq base1 lenth1) ;;循环因子
(setq ooo (+ ooo 50))
(princ)
)

meflying · 发表于 2004-12-10 14:38:00

(setq oo atoi (substr (mark 2 1))) ;;00位转整
(setq ooo atoi (substr (mark 5 2))) ;;000位转整 (command "text" (polar lenth1 (/ 2 PI) 10) 3 strcat ("k" oo "+" ooo )) 这三句中有些函数未使用括号或括号位置不对，从别的程序转过来，还不太习惯吧！

honboo · 发表于 2004-12-10 14:55:00

谢谢老大，这个程序是我自己写的，我想达到这个目的，在一条直线上间隔50放一个半径为5的圆，然后在每个圆上标注桩号，形式为k00+000每当后面的000超过1000的时候（如1050）则 k00为K01，后三位则为050！好困难啊，我都晕死了！

我碰到的问题：不知道以文本输出时，数字和字符穿能否用strcat连接在一起！

为什么当我用 polar 命令定义角度为（/ 2 pi ），应该是垂直的，怎么运行出来就不是那样的，很晕

meflying · 发表于 2004-12-10 15:07:00

我知道是你自己写的，我是说你原来会C，现在用LISP写程序，有些习惯上还没完全转过来，如LISP这样写(strcat a b)，按C的习惯就会写成strcat (a b)

(/ 2 pi) --->2/pi

你需要的应该是pi/2吧。。。

ZZXXQQ · 发表于 2004-12-10 15:17:00

1、(setq oo atoi (substr (mark 2 1))) ;;00位转整
改成(setq oo (atoi (substr mark 2 1)))
2、(setq ooo atoi (substr (mark 5 2))) ;;000位转整
改成(setq ooo (atoi (substr mark 5 2)))
3、(if (>= ooo 1000) (setq ooo (- ooo 1000))
(setq oo (+ oo 1))
改成(if (>= ooo 1000)
(setq ooo (- ooo 1000))
(setq oo (+ oo 1))
)
4、(command "text" (polar lenth1 (/ 2 PI) 10) 3 strcat ("k" oo "+" ooo ))
改成
(command "text" (polar lenth1 (/ 2 pi) 10) 3 "" (strcat "k" (itoa oo) "+" (itoa ooo)))

honboo · 发表于 2004-12-10 15:17:00

说的是啊，就是那种感觉，职业病啊！帮我再修改一下我的程序吧，我想今天把他做出来！

meflying · 发表于 2004-12-10 15:58:00

看看是否满足你的要求？

(defun calNum(str n / newStr);一个给字符串增加某一值的子函数
(setq newStr (itoa (+ (atoi str) n)))
(repeat (- (strlen str) (strlen newStr))
(setq newStr (strcat "0" newStr))
)
newStr
)
(defun c:canal () ;;定义主函数名称
(setq base (getpoint "\n路线起点:")) ;;获取起点坐标
(setq center (getpoint base "\n路线终点:")) ;;获取终点坐标
(setq mark (getstring "\n输入第一个设备的桩号:")) ;;获得第一个设备桩号如 K00+000形式
(setq end (list (car center) (cadr base))) ;;固定纵坐标
(command "line" base end "") ;;做直线
(setq lenth (distance base center)) ;;获取路线长度
(setq off (fix (/ (- lenth 50) 50))) ;;获取要排列的个数
(setq base1 base) ;;保存起点坐标给base1变量
(setq oo (substr mark 2 2)) ;;00位转整
(setq ooo (substr mark 5 3)) ;;000位转整
(setq os (getvar "osmode"))
(setvar "osmode" 0)
(setvar "cmdecho" 0)
(repeat off ;;开始循环，重复off次
(setq lenth1 (polar base1 0 50)) ;;极坐标方式寻找圆心，并存入变量lenth1中
(command "circle" lenth1 5) ;;画圆
(if (>= (atoi ooo) 1000)
(progn
(setq ooo (calNum ooo -1000))
(setq oo (calNum oo 1))
);这里注意if只能带两个参数，也就是两个表达式，如果你某种条件要操作的表达式多于一个，必须使用progn
)
(command "text" (polar lenth1 (/ PI 2) 10) 3 "" (strcat "k" oo "+" ooo))
(setq base1 lenth1) ;;循环因子
(setq ooo (calNum ooo 50))
)
(setvar "osmode" os);恢复os值
(princ)
)

(defun calNum(str n / newStr);一个给字符串增加某一值的子函数
   (setq newStr (itoa (+ (atoi str) n)))
   (repeat (- (strlen str) (strlen newStr))
       (setq newStr (strcat "0" newStr))
   )
   newStr
)
(defun c:canal ()   ;;定义主函数名称
   (setq base (getpoint "\n路线起点:"))   ;;获取起点坐标
   (setq center (getpoint base "\n路线终点:"))   ;;获取终点坐标
   (setq mark (getstring "\n输入第一个设备的桩号:"))   ;;获得第一个设备桩号如 K00+000形式
   (setq end (list (car center) (cadr base)))   ;;固定纵坐标
   (command "line" base end "")   ;;做直线
   (setq lenth (distance base center))   ;;获取路线长度
   (setq off (fix (/ (- lenth 50) 50)))   ;;获取要排列的个数
   (setq base1 base)   ;;保存起点坐标给base1变量
   (setq oo (substr mark 2 2))   ;;00位转整
   (setq ooo (substr mark 5 3))   ;;000位转整
   (setq os (getvar "osmode"))
   (setvar "osmode" 0)
   (setvar "cmdecho" 0)
   (repeat off       ;;开始循环，重复off次
       (setq lenth1 (polar base1 0 50))       ;;极坐标方式寻找圆心，并存入变量lenth1中
       (command "circle" lenth1 5)       ;;画圆
       (if (>= (atoi ooo) 1000)
           (progn
  (setq ooo (calNum ooo -1000))
  (setq oo (calNum oo 1))
           );这里注意if只能带两个参数，也就是两个表达式，如果你某种条件要操作的表达式多于一个，必须使用progn
       )
       (command "text" (polar lenth1 (/ PI 2) 10) 3 "" (strcat "k" oo "+" ooo))
       (setq base1 lenth1)       ;;循环因子
       (setq ooo (calNum ooo 50))
   )
   (setvar "osmode" os);恢复os值
   (princ)
)

honboo · 发表于 2004-12-10 16:37:00

运行过，不过还是没有达到效果，那我自己来吧，如果再不行，再请教，该不过被斑竹踢出去吧！

账号		自动登录	找回密码
密码			注册