[分享]将图层信息写到网页上

citykunan · 发表于 2005-1-28 15:33:00

(defun C:DUMPLAYERS
( / acad doc dwg layers name col ltp lwt pst onoff frz dat
path olist outfile output)
(vl-load-com)
(setq acad (vlax-get-acad-object)
doc (vla-get-activedocument acad)
dwg (vla-get-name doc)
path (vla-get-path doc)
layers (vla-get-layers doc)
)
(vlax-for each layers
(setq name (vla-get-name each)
col (itoa (vla-get-color each))
ltp (vla-get-linetype each)
lwt (itoa (vla-get-lineweight each))
pst (vla-get-plotstylename each)
onoff (if (= :vlax-true (vla-get-layeron each))
"ON" "OFF"
)
frz (if (= :vlax-true (vla-get-freeze each))
"FROZEN" "THAWED"
)
dat (list name col ltp lwt pst onoff frz)
olist (cons dat olist)
)
); vlax-for (vlax-release-object layers)
(vlax-release-object doc)
(vlax-release-object acad)
(cond
( olist
(setq outfile (strcat (vl-filename-base dwg) ".htm"))
(setq outfile (strcat path outfile))
(cond
( (setq output (open outfile "w"))
(write-line "<html>" output)
(write-line "<head><title>" output)
(write-line (strcat "Layer Dump: " dwg) output)
(write-line "</title></head><body>" output)
(write-line (strcat "<b>Drawing: " dwg "</b><br>") output)
(write-line "<table border=1>" output)
(foreach layset olist
(write-line "<tr>" output)
(foreach prop layset
(write-line (strcat "<td>" prop "</td>") output)
)
(write-line "</tr>" output)
); foreach layer set
(write-line "</table></body></html>" output)
(close output)
(setq output nil)
(princ "\nReport finished! Opening in browser...")
(vl-cmdf "_.browser" outfile)
)
( T (princ "\nUnable to open output file.") )
)
)
( T (princ "\nUnable to get layer table information.") )
)
)

alin · 发表于 2005-1-28 21:07:00

David Stein 写过一个差不多的程序, 后来AfraLisp引用过.

账号		自动登录	找回密码
密码			注册