[求助] 各位高手请帮忙

bh5280 · 发表于 2005-3-30 08:32:00

为什么我这个程序不能满足我的要求 (defun c:zz (/ ss m sa)
(setq ss (ssget))
(setq m (sslength ss))
(while (> m 0)
(setq m (1- m))
(setq sa (entget (ssname ss m)))
(setq sa (subst (cons 62 "7") (assoc 62 sa) sa ))
(entmod sa)
)
) 我是想在不改变实体图层的情况下把实体的颜色改成白色，并且不调用change命令。

alin · 发表于 2005-3-30 09:58:00

(defun c:zz (/ ss m sa)
(setq ss (ssget))
(setq m (sslength ss))
(while (> m 0)
(setq m (1- m))
(setq sa (entget (ssname ss m)))
(if (assoc 62 sa)
(setq sa (subst (cons 62 7) (assoc 62 sa) sa))
(setq sa (append sa (list (cons 62 7))))
)
(entmod sa)
)
(princ)
)

mkhsj928 · 发表于 2005-3-30 10:03:00

如果实体颜色随层的话，(entget)返回表里面没有（62 . ×）这一项

meflying · 发表于 2005-3-30 11:45:00

2楼的程序里已经判断这种情况了

(if (assoc 62 sa)...

bh5280 · 发表于 2005-3-30 14:19:00

好用了，谢谢alin版主！

bh5280 · 发表于 2005-3-30 14:40:00

我还想问一下：当实体是块的时候是要先炸开再运行上面程序还是有其他好办法。

龙龙仔 · 发表于 2005-3-31 08:41:00

;;By LUCAS(龙龙仔)
(defun NENTSGET (/ HOLDPICKADD LIS SSS N NAM)
(setq HOLDPICKADD (getvar "PICKADD"))
(setvar "pickadd" 1)
(prompt "\n请连续个别选取图块内物件...")
(setq LIS (ssnamex (ssget ":N")))
(setq N 0)
(repeat (length LIS)
(if (= (type (setq NAM (cadr (nth N LIS)))) 'ENAME)
(setq SSS (append SSS (list NAM)))
)
(setq N (1+ N))
)
(setvar "pickadd" HOLDPICKADD)
SSS
)(defun C:ZZZ (/ SS SA)
(setq SS (NENTSGET))
(mapcar '(lambda (X)
(setq SA (entget X))
(if (assoc 62 SA)
(setq SA (subst (cons 62 1) (assoc 62 SA) SA))
(setq SA (append SA (list (cons 62 1))))
)
(entmod SA)
)
SS
)
(command "_.regen")
(princ)
)

bh5280 · 发表于 2005-3-31 11:56:00

版主的这句

(setq LIS (ssnamex (ssget ":N")))

是不是要改成这样啊

(setq LIS (ssnamex (ssget :N)))

龙龙仔 · 发表于 2005-3-31 12:13:00

你认为我错了吗?可能是你的autocad版本太低!

账号		自动登录	找回密码
密码			注册