怎样判断一个点在一条直线上（vba）

armylee

rt

fanqinwei

垂距为零

mikewolf2k

判断该直线与直线某端点的斜率与直线斜率是否相等。

torcky

 该点到直线两端点的距离和等于直线的长度

matrix

可以用VBA实现:

得到起点:line.startpoint

得到端点:line.endpoint

然后再照三楼的方法，三个点确定两个斜率，相等就在直线上，否则，就返回false值

zxj_76

三楼的方法可以判断点是否在线段或线段的延长线上；

四楼的方法可以判断点是否在线段上。

如果三楼的判断成立而四楼的判断不成立则点在线段的延长线上。

chffsmc

四楼ok

dengqiaqia

计算误差很烦人，老是要判断

jkbanana

设直线的两端点分别A和B, 判断任意点P在直线AB上否?

解:

    以直线的一端点A为起点, 另一端点B 和任意点P为终点的矢量分别设为V₀和V₁. 任意点P
   点和在直线AB上的话,外积(V₀×V₁)的大小为0.

即：

　　||V₀×V₁|| ＝0　---　任意点P 在直线AB上

    ||V₀×V₁|| <>0　---　任意点P不在直线AB上

式中：
   ×为矢量的外积运算符.

************************************************

具体计算如下：

设直线的端点坐标为
   A = (A(0), A(1), A(2) )^T, B = (B(0), B(1), B(2) )^T, 任意点P = (P(0), P(1), P(2) )^T

则, 矢量

     V₀＝B – A, V₀的成分为：V₀(i) = B(i) – A(i ), i=0,2

     V₁＝P – A, V₁的成分为： V₁(i) = P(i) – A(i ), i=0,2

又设矢量的外积V = V₀×V₁, V还是矢量.

     V = V₀×V₁

     V的成分如下,

        V(0)= V₀ (1) V₁ (2) –  V₀ (2) V₁ (1)

        V(1)= V₀ (2) V₁ (0) –  V₀ (0) V₁ (2)

        V(2)= V₀ (0) V₁ (1) –  V₀ (1) V₁ (0)

则, ||V₀×V₁||= sqr(V(0)^2+ V(1)^2+ V(2)^2)

然后用上面的结论即可判断出点P在直线AB上否.

以上计算中只要进行简单的加,减,乘,乘方,开方运算即可.

该方法不论是在2维空间还是3维空间，也不论点在线段AB上,还是在其延长线上,都能使用.

jkbanana

''''''''''''''''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''
'''
'''这是一个判断点在直线上否的简单Sample
'''
'''Coded By ChunYue,Zou   2007.06.17
''''''''''''''''''''''''''''''''''''''''''''''
''''''''''''''''''''''''''''''''''''''''''''''
Option Explicit
Const CONST_AbsZero = 10 ^ (-4)   '大小由计算精度确定
Public Sub Test()
  Dim objline As AcadLine
  Dim returnPnt As Variant
  Dim A(0 To 2) As Double
  Dim B(0 To 2) As Double
  Dim P(0 To 2) As Double
  Dim V(0 To 2) As Double
  Dim V0(0 To 2) As Double
  Dim V1(0 To 2) As Double
  Dim Norm As Double
 
'''
  '1.指定直线AB
  ThisDrawing.Utility.GetEntity objline, returnPnt, "Select a line:"
  returnPnt = objline.StartPoint
  A(0) = returnPnt(0)
  A(1) = returnPnt(1)
  A(2) = returnPnt(2)
  returnPnt = objline.EndPoint
  B(0) = returnPnt(0)
  B(1) = returnPnt(1)
  B(2) = returnPnt(2)
  '指定一任意点P
  returnPnt = ThisDrawing.Utility.GetPoint(, "Enter a point: ")
  P(0) = returnPnt(0)
  P(1) = returnPnt(1)
  P(2) = returnPnt(2)
  '2.计算矢量V0=B-A, V1=P-A
  V0(0) = B(0) - A(0)
  V0(1) = B(1) - A(1)
  V0(2) = B(2) - A(2)
  '
  V1(0) = P(0) - A(0)
  V1(1) = P(1) - A(1)
  V1(2) = P(2) - A(2)
  '3.求外积 V = V0 x V1
  V(0) = V0(1) * V1(2) - V0(2) * V1(1)
  V(1) = V0(2) * V1(0) - V0(0) * V1(2)
  V(2) = V0(0) * V1(1) - V0(1) * V1(0)
  '4.计算V的大小: Norm = ||V|| = ||V0 X V1||
  Norm = Sqr(V(0) ^ 2 + V(1) ^ 2 + V(2) ^ 2)
  '5.判断
  If Norm < CONST_AbsZero Then
    '点P在直线AB上
    MsgBox "点在直线上, Norm=" & Norm
  Else
    '点P不在直线AB上
    MsgBox "点不在直线上, Norm=" & Norm
  End If
End Sub