请大家帮我挑错

jimmy8135

小弟有一作业,情况是这样的:
在任意直线上得一点,再得不在这一直线上的点作为方向,然后画表面粗糙度.
小弟参考了上次网友 chg 在 "用(ssget )可以做到" 一文中的办法
想半天,做不出,ssget实体选择实在有点过不去
请各位帮忙挑错,感谢感谢...
(defun c:t2(/ p1 p2 p3 p4 p5 p6 p7 p8 ang ang1 k ename ss)
  (setq p1 (getpoint "\n input p1"))
  (setq p5 (getpoint "\n input p2"))
  (setq k (getdist "\n input k"))
  (setq ss (ssget p1))
  (setq ename (ssname ss 0))
  (setq p2 (cdr (assoc 10 (entget ename))))
  (setq p3 (cdr (assoc 11 (entget ename))))
  (setq ang (angle p2 p3))
  (setq ang1 (angle p1 p5))
  (cond
    ((> (- ang1 pi) ang)
     (setq p6 (polar p1 (- ang (/ pi 3)) (* 10 k)))
     (setq p7 (polar p1 (- ang (* (/ pi 3) 2) (* 10 k))))
     (setq p8 (polar p1 (- ang (* (/ pi 3) 2) (* 20 K)))))
    ((and (> ang1 ang) (< ang1 (+ ang pi)))
     (setq p6 (polar p1 (+ ang (* (/ pi 3) 2) (* 10 k))))
     (setq p7 (polar p1 (+ ang (/ pi 3) (* 10 k))))
     (setq p8 (polar p1 (+ ang (/ pi 3) (* 20 K)))))
    ((and (> ang1 0) (< ang1 ang))
     (setq p6 (polar p1 (- ang (/ pi 3)) (* 10 k)))
     (setq p7 (polar p1 (- ang (* (/ pi 3) 2) (* 10 k))))
     (setq p8 (polar p1 (- ang (* (/ pi 3) 2) (* 20 K))))))
  (command "pline" p7 p6 p1 p8 "")
  )
  
注:k是画粗糙度的比例系数

chg

你的思路和方法基本正确，但是括号不匹配。
将正确的程序贴给你。
(defun c:t2 (/ p1 p2 p3 p4 p5 p6 p7 p8 ang ang1 k ename ss)
  (setq p1 (getpoint "\n input p1"))
  (setq p5 (getpoint "\n input p2"))
  (setq k (getdist "\n input k"))
  (setq ss (ssget p1))
  (setq ename (ssname ss 0))
  (setq p2 (cdr (assoc 10 (entget ename))))
  (setq p3 (cdr (assoc 11 (entget ename))))
  (setq ang (rem (angle p2 p3) (* 2 pi)))
  (setq ang1 (angle p1 p5))
  (cond
    ((> (- ang1 pi) ang)
     (setq p6 (polar p1 (- ang (/ pi 3)) (* 10 k)))
     (setq p7 (polar p1 (- ang (* (/ pi 3) 2)) (* 10 k)))
     (setq p8 (polar p1 (- ang (* (/ pi 3) 2)) (* 20 K)))
    )
    ((and (> ang1 ang) (< ang1 (+ ang pi)))
     (setq p6 (polar p1 (+ ang (* (/ pi 3) 2)) (* 10 k)))
     (setq p7 (polar p1 (+ ang (/ pi 3)) (* 10 k)))
     (setq p8 (polar p1 (+ ang (/ pi 3)) (* 20 K)))
    )
    ((and (> ang1 0) (< ang1 ang))
     (setq p6 (polar p1 (- ang (/ pi 3)) (* 10 k)))
     (setq p7 (polar p1 (- ang (* (/ pi 3) 2)) (* 10 k)))
     (setq p8 (polar p1 (- ang (* (/ pi 3) 2)) (* 20 K)))
    )
  )
  (command "pline" p7 p6 p1 p8 "")
)

龙龙仔

jimmy8135

只能画一半呀
我看看...

jimmy8135

还是不行
只能画到一半

龙龙仔

(defun C:T2 (/ HOLDOSMODE P1 P2 P3 P4 P5 P6 P7 P8 ANG ANG1 K ENAME SS)
  (setq HOLDOSMODE (getvar "OSMODE"))
  (setvar "OSMODE" 0)
  (initget 1)
  (setq P1 (getpoint "\n任意直线上得一点: "))
  (initget 1)
  (setq P5 (getpoint "\n方向点: "))
  (setq K (getdist "\n粗糙度的比例系数: "))
  (if (= K NIL)
    (setq K 1)
  )
  (setq P1 (osnap P1 "NEA"))
  (setq SS (ssget P1))
  (setq ENAME (ssname SS 0))
  (setq P2 (cdr (assoc 10 (entget ENAME))))
  (setq P3 (cdr (assoc 11 (entget ENAME))))
  (setq ANG (angle P2 P3))
  (setq ANG1 (angle P1 P5))
  (cond
    ((> (- ANG1 pi) ANG)
     (setq P6 (polar P1 (- ANG (/ pi 3)) (* 10 K)))
     (setq P7 (polar P1 (- ANG (* (/ pi 3) 2)) (* 10 K)))
     (setq P8 (polar P1 (- ANG (* (/ pi 3) 2)) (* 20 K)))
    )
    ((and (> ANG1 ANG) (< ANG1 (+ ANG pi)))
     (setq P6 (polar P1 (+ ANG (* (/ pi 3) 2)) (* 10 K)))
     (setq P7 (polar P1 (+ ANG (/ pi 3)) (* 10 K)))
     (setq P8 (polar P1 (+ ANG (/ pi 3)) (* 20 K)))
    )
    ((and (> ANG1 0) (< ANG1 ANG))
     (setq P6 (polar P1 (- ANG (/ pi 3)) (* 10 K)))
     (setq P7 (polar P1 (- ANG (* (/ pi 3) 2)) (* 10 K)))
     (setq P8 (polar P1 (- ANG (* (/ pi 3) 2)) (* 20 K)))
    )
  )
  (command "pline" P7 P6 P1 P8 "")
  (setvar "osmode" HOLDOSMODE)
  (princ)
)

jimmy8135

感谢!!