[原创]AutoLISP程序的安装制作教程（三）

秋枫

这两天更新了我的安装程序制作向导，添加了对已有安装包的维护功能与卸载时菜单的卸载支持。另对样例的加载LISP程序进行了优化。因此，决定写一篇新的教程。 这里，以周海兵朋友制作的文字修改大师9.0为一个样例，为它在AutoCAD2000以上的版本制作一个安装程序。（他的文字修改大师目前最新的版本已经挺高了，这里不管，以这个旧为例说明问题。） 文字修改大师（For AutoCAD 2000以上的版本）主要文件有：

ctt.vlx - 主程序
ctt.mns - 菜单文件
ctt.dll - 资源文件
license.rtf - 授权协议
readme.txt - 程序简介，信息
文字修改大师.chm - 帮助文件

因为AutoCAD 2002与AutoCAD 2004的菜单文件编译后的MNC文件格式不一样，2004与2006也不同，为了保证它的菜单可以同时在各个版本的AutoCAD中使用，这里把文件ctt.mns与ctt.dll复制了两份，分别起名为ctt2004.mns, ctt2004.dll与ctt2006.mns, ctt2006.dll。 所有文件准备好后，复制到一个文件夹中，例如D:\文字修改大师。如图: 下面开始编写初始化LISP程序。这里，我们创建一个LISP程序，命名为：LoadCtt.lsp，这个程序将负责把菜单、主程序等加载到系统中。 以下是这个LoadCtt.lsp的写法。我尽量在注释中解释：
;; 首先定义初始化函数
(defun InitCttApplication (/
;; 内部函数
GetMyApplicationPath GetCttPath
strParse StrUnParse
Ctt_AddSupportPath Load_CttMenu
ctt_placemenu
;; 局部变量
Ctt_cmdecho_save
) ;;; 取得本程序的路径.
;;; 文件路径从注册表中读取，这些信息由安装程序负责写入注册表
;;; ---------------------------------------------------------------------------------
(defun GetMyApplicationPath (AppID)
(vl-registry-read
(strcat
"HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall\\"
AppID
"_is1"
)
"Inno Setup: App Path"
)
) ;; 这里取得安装后，安装的文件夹的绝对路径
;; 注意：这里的AppID为"文字修改大师", 稍后的安装程序制作向导设置中必须与这里保持一致
(defun GetCttPath ()
(GetMyApplicationPath "文字修改大师")
) ;;; 解析字符串为表（函数来自明经通道转载）
;;; ---------------------------------------------------------------------------------
(defun strParse (Str Delimiter / SearchStr StringLen return n char)
(setq SearchStr Str)
(setq StringLen (strlen SearchStr))
(setq return '())
(while (> StringLen 0)
(setq n 1)
(setq char (substr SearchStr 1 1))
(while (and (/= char Delimiter) (/= char ""))
(setq n (1+ n))
(setq char (substr SearchStr n 1))
) ;_ end of while
(setq return (cons (substr SearchStr 1 (1- n)) return))
(setq SearchStr (substr SearchStr (1+ n) StringLen))
(setq StringLen (strlen SearchStr))
) ;_ end of while
(reverse return)
) ;_ end of defun ;;; 反解析表为字符串（函数来自明经通道转载）
;;; ---------------------------------------------------------------------------------
(defun StrUnParse (Lst Delimiter / return)
(setq return "")
(foreach str Lst
(setq return (strcat return Delimiter str))
) ;_ end of foreach
(substr return 2)
) ;_ end of defun ;;; 添加支持文件搜索路径
;;; ---------------------------------------------------------------------------------
;;; note: 第二个参数如果为真, 插最前，否则插最后
;;;
(defun Ctt_AddSupportPath (PathToAdd isFirst / supportlist)
(if (not
(vl-string-search
(strcase (strcat pathToAdd ";"))
(strcase (strcat (getenv "ACAD") ";"))
)
) ; 保证不重复添加
(progn
(setq supportlist (strparse (getenv "ACAD") ";"))
(setq supportlist
(vl-remove-if-not
'vl-file-directory-p
supportlist
)
) ; 移除不存在的文件夹
(if isFirst
(setq supportlist (cons PathToAdd supportlist))
(setq supportlist (append supportlist (list PathToAdd)))
)
(setenv "ACAD" (strUnParse supportlist ";"))
)
)
) ;; 根据不同的AutoCAD版本加载不同的菜单文件。
(defun Load_CttMenu (/ acadver)
(setq acadver (atof (getvar "acadver")))
(cond
((and (>= acadver 15.0) (< acadver 16.0))
(command "_menuload" "ctt.mns")
)
((and (>= acadver 16.0) (<= acadver 16.1))
(command "_menuload" "ctt2004.mns")
)
((>= acadver 16.2) (command "_menuload" "ctt2006.mns"))
)
) ;; 这个函数用来插入菜单条
;; The following code "placemenu" from LUCAS(龙龙仔)
(defun ctt_placemenu (/ n)
(if (menugroup "CTT")
(progn
(setq n 1)
(while (< n 24)
(if (menucmd (strcat "P" (itoa n) ".1=?"))
(setq n (+ n 1))
(progn
(if (> n 3)
(setq n (- n 2))
(setq n 3)
) ;if
;; 如需插入多条菜单，以反序在这里写：
;; 因只有一条下拉菜单，因此这里4，3，2条注释掉
;; (menucmd (strcat "p" (itoa n) "=+CTT.pop4"))
;; (menucmd (strcat "p" (itoa n) "=+CTT.pop3"))
;; (menucmd (strcat "p" (itoa n) "=+CTT.pop2"))
(menucmd (strcat "p" (itoa n) "=+CTT.pop1"))
(setq n 25)
) ;progn
) ;if
) ;while
) ;progn
) ;if
(princ)
) ;;; -----------------------------------------------------
;;; main：
;;; -----------------------------------------------------
(setq Ctt_cmdecho_save (getvar "cmdecho"))
(setvar "cmdecho" 0) ;; 添加支持路径。这里只添加一条。多条的话自行修改。
(Ctt_AddSupportPath (GetCttPath) nil) ;; 如果菜单组还没有被加载，则加载之
(if (not (menugroup "Ctt"))
(Load_CttMenu)
) ;; 插到合适的位置
(ctt_placemenu)
(setvar "cmdecho" Ctt_cmdecho_save)
(setq Ctt_cmdecho_save nil) (princ)
) ;_end of defun initCttApplication (initCttApplication) ;; 加载主程序
;; 为节省内存，这里也可以以autoload函数形式定义
;; 有几条写几条
(load "ctt.vlx") (princ) 至此，所有的要添加支持路径、添加菜单的工作在LISP中都做好了。下面运行本人制作的安装程序制作向导： 设置一些基本的信息： 设置AppID。注意：这里必须与LoadCtt.lsp中的GetCttPath一致。AppID设置不正确将导致LoadCtt.lsp无法确定本程序的安装的位置。 下面是一些常规设置了。
告诉安装程序，这个程序支持的AutoCAD版本：
AutoCAD 2000/2000i/2002: R15.0~R15.1
AutoCAD 2004: R16.0
AutoCAD 2005: R16.1
AutoCAD 2006: R16.2 指定我们的程序文件。早准好了： 指定启动AutoCAD时的初始化程序： 指定默认的安装文件夹： 指定开始菜单的程序组。与上一版程序不同的是，我作了小小的修改，即允许不创建开始菜单中的程序组。卸载程序时可以到控制面板的添加、删除程序中卸载。


这里告诉安装程序在卸载时是不是要卸载菜单组。这个也是新添加的功能。在AutoCAD 2005及以前的版本中，菜单组如果找不到系统会提示出错信息。这里卸载程序用于从注册表中清除菜单组信息以免用户卸载后AutoCAD提示出错。对于AutoCAD 2006以上的版本，经试验无此必要了。 考虑到这个文字修改大师也支持AutoCAD 2000-2005的版本，因此这里填入卸载时要卸载的MenuGroup名称为ctt. (MenuGroup的名称在mnu或mns文件中定义)。 注意：LoadCtt.lsp同时也向AutoCAD系统中添加了支持搜索路径，卸载程序卸载时会自动把本程序路径以及本程序路径的子路径从AutoCAD系统的搜索路径中去除，无需设置。 完成。
安装包生成完毕： 看看生成的安装程序，试运行之（全程截图）： 如何修改已经做好的安装程序？可以用WinRAR或7z解压之。这次安装向导修订中我我在基本信息页也添加了一个维护的功能按钮，如图所示： 解开setup.exe后，你可以手动编辑其中的setup.ini或DATA文件夹中的其它文件。Setup.ini内容很简单明了，我也不多说了：

[General]
AppID=文字修改大师
AppName=文字修改大师
AppVerName=文字修改大师 V9.0
LISPStartup=loadctt.lsp
DefaultPath=文字修改大师
DefaultGroup=文字修改大师
License=License.rtf
Help=文字修改大师.chm
Info=ReadMe.txt
VersionSupport=R15.0;R15.1;R16.0;R16.1;R16.2
[UI]
WizardImageFile=
WizardSmallImageFile=
[Uninstall]
RemoveMenuGroup=ctt

重建安装包也可以用这个维护功能实现。 相关链接：
● AutoLISP程序的安装制教程（二）
● AutoLISP程序的安装制教程（一）
● AutoCAD二次开发程序的安装制作向导
● Inno Setup
● 7-zip

angel066499

能解决一下现在2010以下版，启动组中没有植入的vlx,是什么原因呢？

wmh-3816

学习，谢谢分享

LIULISHENG

学习了学习了

spring

谢谢秋枫的程序


我们又得更新一次了,呵呵.

BDYCAD

BDYCAD

我在这步指定加载ACAD.LSP, 可是安装后启动CAD没有加载到哦. 原因是安装后没有自动加上支持路径.

spring

我的没有问题


安装只是把文件复制到指定的目录并加载你所指定的LISP，其它添加路径等动作是在你所指定的LISP里面完成的

xj841000

试一试

BDYCAD

明白了. 不好意思啊. 我还没有看前面的LISP程序.

秋枫

1. 以下是引用BDYCAD在2005-5-21 15:42:38的发言：

复制代码

因为在vlisp中控制加载支持路径可以有更多的灵活性。你自己可以根据需要决定是否添加，是添加一条还是多条。一般来说如果是只有一个vlx文件的应用程序就没有必要添加支持路径了。添加了支持路径会增加整个环境变量ACAD的总长度。太长的支持路径会导致有些操作这个变量的应用程序字符串溢出。我有一阵子用理正建筑软件就发现了这个问题，因为我添加了五六条支持路径，超出了256个字符，导致它的ARX在启动时就出错。出错的原因是很久以后才找到的，跟作者联系后才修正了这个错误。这种事情尽管责任不在我方，但能尽量避免还是避免。

秋枫

BDYCAD发表于2005-5-21 17:58:00明白了. 不好意思啊. 我还没有看前面的LISP程序.

这回我的示例LISP代码比上次的示例稍作了改进，防止了一些多余的重复操作，提高了一点效率。供参考。 具体怎么写还是看你了，呵呵。

kevinchan

有个小小的提议,能否增加安装程序名(setup.exe)的自定义图标?