[求助]圆中心线斜45度

bida · 发表于 2005-8-5 19:18:00

哪位高手有自动画圆中心线而且是斜45度的LSIP>

王咣生 · 发表于 2005-8-5 19:56:00

(defun c:test ()
(setq en (car (entsel "\nSelect a circle: ")))
(if en
    (progn
      (setq obj (vlax-ename->vla-object en))
      (if (= (vlax-get-property obj 'ObjectName) "AcDbCircle")
(progn
   (setq rad (vlax-get-property obj 'Radius))
   (setq cen (vlax-safearray->list (vlax-variant-value (vlax-get-property obj 'Center))))
   (setq spt (polar cen (* (/ 225.0 180.0) pi) rad)
  ept (polar cen (* (/ 45.0 180.0) pi) rad)
  )
   (setq line (vla-addline
         (vla-get-modelspace
    (vla-get-activedocument
      (vlax-get-acad-object)
      ))
         (vlax-3d-point spt)
         (vlax-3d-point ept)
         ))
   )
);if
      )
    );if
);

bida · 发表于 2005-8-6 18:59:00

谢谢，怎么只能画出一条线呢>？

能一次性画出交差的两条性吗？

xyp1964 · 发表于 2005-8-6 19:55:00

(load "xyp_lib")
;|加载通用函数(可在签名栏直接下载)
如果已经下载xyp_lib并放到搜索路径下可以不再下载!
利用以下任何一种方式即可加载和运行通用函数内的所有子程序：
1.在acad.lsp中增加(load"xyp_lib")
2.在每个程序内增加(load"xyp_lib")
3.在command下，输入(load"xyp_lib")
4.在菜单.mnl中增加(load"xyp_lib")
5.将xyp_lib.vlx文件直接拽到cad屏幕
[COLOR=red] ★通用函数下载地址：[/COLOR]
[url]http://www.xdcad.net/forum/attachment.php?s=&postid=1606661[/url]
[url]http://bbs.mjtd.com/forum.php?mod=viewthread&tid=37554[/url]|;
(defun c:xx45 ()
(CMDLA0)
(mkla"中心线"1)
(while (setq s1 (car (entsel "\n选择圆 : ")))
(setq mode (dxf 0 (entget s1)))
(if (= mode "CIRCLE")
(progn
(setq pt (dxf 10 (entget s1))
rad (* (dxf 40 (entget s1)) 0.5)
ss1(ssget "x")
)
(XYP_SZX pt rad)
(setq ss2(ssget "x")
ss(SSDIFF ss2 ss1)
)
(command"rotate"ss "" pt 45)
)
)
)
(CMDLA1)
)
(princ"xx45(斜线45)")
(princ)

王咣生 · 发表于 2005-8-6 20:08:00

另一条你自己改吧.

Ea · 发表于 2005-8-7 08:51:00

(defun c:tt (/ ss mkline j e el r sp1 ep1 sp ep)
(defun mkline (p1 p2)
(entmake (list '(0 . "line")
'(100 . "acdbentity")
'(100 . "acdbline")
(cons 10 p1)
(cons 11 p2)
)
)
)
(if (setq j -1
ss (ssget '((0 . "circle")))
)
(repeat (sslength ss)
(setq e (ssname ss (setq j (1+ j)))
el (entget e)
r (cdr (assoc 40 el))
cen (cdr (assoc 10 el))
sp (polar cen (/ pi 4.) r)
ep (polar cen (* -0.75 pi) r)
sp1 (polar cen (* 0.75 pi) r)
ep1 (polar cen (* -0.25 pi) r)
)
(mkline sp ep)
(mkline sp1 ep1)
)
)
(princ)
)

无痕 · 发表于 2005-8-7 12:19:00

(defun c:tt (/ ss odc i e)
(command ".undo" "be")
(if (setq ss (ssget '((0 . "CIRCLE"))))
(progn
(setq odc(getvar "dimcen"))
(command ".ucs" "z" 45)
(setq i -1)
(while (setq e (ssname ss(setq i (1+ i))))
　　　(setvar "dimcen" (cdr(assoc 40 (entget e))))
　　　(command ".dimcenter" (list e (vlax-curve-getstartpoint e)))
)
(command ".ucs" "p")
(setvar "dimcen" odc)
)
)
(command ".undo" "e")
(princ)
)

小妹丁 · 发表于 2005-8-7 15:31:00

先设UCS，如果是我用的话。

Ea · 发表于 2005-8-7 19:08:00

不知楼主是何用途，要是我在这样有规律的情况下会用下面的程序

(defun c:tt (/ addblk eDoc MS cset)
(defun addblk (/ blkdef oldlyr oldcol)
(if (not (tblsearch "block" "$ea_center_mark"))
(progn
(setq oldlyr (getvar "Clayer")
oldcol (getvar "cecolor")
)
(setvar "clayer" "0")
(setvar "cecolor" "bylayer")
(setq blkdef
(vla-add (vla-get-blocks
(vla-get-activedocument (vlax-get-acad-object))
)
(vlax-3d-point '(0. 0. 0.))
"$ea_center_mark"
)
)
(vla-addcircle blkdef (vlax-3d-point '(0. 0. 0.)) 1.)
(vla-addline
blkdef
(vlax-3d-point (polar '(0. 0. 0.) (* 0.25 pi) 1.))
(vlax-3d-point (polar '(0. 0. 0.) (* -0.75 pi) 1.))
)
(vla-addline
blkdef
(vlax-3d-point (polar '(0. 0. 0.) (* 0.75 pi) 1.))
(vlax-3d-point (polar '(0. 0. 0.) (* -0.25 pi) 1.))
)
(setvar "clayer" oldlyr)
(setvar "cecolor" oldcol)
)
)
)
(if (not (vl-catch-all-error-p
(setq cset
(vl-catch-all-apply
'vla-item
(list
(vla-get-selectionsets
(setq
eDoc (vla-get-activedocument (vlax-get-acad-object))
)
)
"CURRENT"
)
)
)
)
)
(vla-delete cset)
)
(if (ssget '((0 . "circle")))
(progn
(addblk)
(vlax-map-collection
(vla-get-activeselectionset eDoc)
'(lambda (x / r blkref)
(setq blkref (vla-insertblock
(if MS
MS
(setq MS (vla-get-modelspace eDoc))
)
(vla-get-center x)
"$ea_center_mark"
(setq r (vla-get-radius x))
r
r
0.
)
)
(vla-put-layer blkref (vla-get-layer x))
(vla-delete x)
)
)
)
)
(princ)
)

(defun c:tt (/ addblk eDoc MS cset)
  (defun addblk    (/ blkdef oldlyr oldcol)
    (if    (not (tblsearch "block" "$ea_center_mark"))
      (progn
    (setq oldlyr (getvar "Clayer")
          oldcol (getvar "cecolor")
    )
    (setvar "clayer" "0")
    (setvar "cecolor" "bylayer")
    (setq blkdef
           (vla-add    (vla-get-blocks
              (vla-get-activedocument (vlax-get-acad-object))
            )
            (vlax-3d-point '(0. 0. 0.))
            "$ea_center_mark"
           )
    )
    (vla-addcircle blkdef (vlax-3d-point '(0. 0. 0.)) 1.)
    (vla-addline
      blkdef
      (vlax-3d-point (polar '(0. 0. 0.) (* 0.25 pi) 1.))
      (vlax-3d-point (polar '(0. 0. 0.) (* -0.75 pi) 1.))
    )
    (vla-addline
      blkdef
      (vlax-3d-point (polar '(0. 0. 0.) (* 0.75 pi) 1.))
      (vlax-3d-point (polar '(0. 0. 0.) (* -0.25 pi) 1.))
    )
    (setvar "clayer" oldlyr)
    (setvar "cecolor" oldcol)
      )
    )
  )
  (if (not (vl-catch-all-error-p
         (setq cset
            (vl-catch-all-apply
              'vla-item
              (list
            (vla-get-selectionsets
              (setq
                eDoc (vla-get-activedocument (vlax-get-acad-object))
              )
            )
            "CURRENT"
              )
            )
         )
       )
      )
    (vla-delete cset)
  )
  (if (ssget '((0 . "circle")))
    (progn
      (addblk)
      (vlax-map-collection
    (vla-get-activeselectionset eDoc)
    '(lambda (x / r blkref)
       (setq blkref    (vla-insertblock
              (if MS
                MS
                (setq MS (vla-get-modelspace eDoc))
              )
              (vla-get-center x)
              "$ea_center_mark"
              (setq r (vla-get-radius x))
              r
              r
              0.
            )
       )
       (vla-put-layer blkref (vla-get-layer x))
       (vla-delete x)
     )
      )
    )
  )
  (princ)
)

账号		自动登录	找回密码
密码			注册

[求助]圆中心线斜45度

本帖子中包含更多资源

reply