请教如何知道一个实体是否拥有反应器,并得到这个反应器

sieben

请教如何知道一个实体是否拥有反应器,并得到这个反应器

Ea

已删除的Object是不能转换为 Entity 的，我想把防止删除的实体保存到一个表里，如果 Erased 就从保存的表里找出 Entity 来再次 Entdel，不知这样是否可行

龙龙仔

;; code: Luis Esquivel
;; will return T if an object has reactor attached
(defun HAS-REACTOR? (OBJ)
  (vl-some
    (function (lambda (X) (numberp X)))
    (mapcar (function (lambda (R) (vl-position OBJ (vlr-owners R))))
     (cdar (vlr-reactors :vlr-object-reactor))
    )
  )
)

;; this will return a list of reactors attached to the object of the type:
:vlr-object-reactor
(defun WHAT-REACTOR? (OBJ)
  (vl-remove-if-not
    (function (lambda (R)
  (if (vl-position OBJ (vlr-owners R))
    R
  )
       )
    )
    (cdar (vlr-reactors :vlr-object-reactor))
  )
)

;; (attached-to obj)
;; return a list with the list of reactors or nil
(defun ATTACHED-TO (OBJ)
  (vl-remove
    NIL
    (mapcar
      (function
 (lambda (REACTOR-TYPE)
   (vl-remove-if-not
     (function
       (lambda (R)
  (cond
    ((and (equal REACTOR-TYPE :vlr-object-reactor)
   (vl-position OBJ (vlr-owners R))
     )
     R
    )
    ((and
       (not (equal REACTOR-TYPE
     :vlr-object-reactor
     )
       )
       (vl-position OBJ (vlr-data R))
     )
     R
    )
  )
       )
     )
     (cdar (vlr-reactors REACTOR-TYPE))
   )
 )
      )
      (vlr-types)
    )
  )
)

 

龙龙仔

Ea发表于2005-10-14 12:15:00已删除的Object是不能转换为 Entity 的，我想把防止删除的实体保存到一个表里，如果 Erased 就从保存的表里找出 Entity 来再次 Entdel，不知这样是否可行
...

这种操作很累!还要注意:UNDO,OOPS,U,REDO,ERASE.....反正花不来

sieben

代码还没细看,先谢谢龙龙仔!

sieben

之前我也有这样的模糊的想法，我没想到代码能写得这么简洁，佩服！另外我担心反应器多的话速度慢．不过现在我应该可以减少反应器的数量.谢谢！