vl-string-position返回值的问题

citykunan · 发表于 2005-12-27 12:18

(vl-string-position (ascii " ") "aa bb") 返回2，而(vl-string-position (ascii " ") "沥沥 bb")返回4。我想只得到字的位数而不是字符的位数，即(vl-string-position (ascii " ") "沥沥 bb")也返回2，(vl-string-position (ascii " ") "沥a沥 bb")返回3，行不行啊？谢谢

龙龙仔 · 发表于 2005-12-27 12:27

本帖最后由作者于 2005-12-27 14:45:10 编辑

当然可以,就等你写出来! 8-)

寻找字串中有指定的"字"元
(vl-str-position <str> <start-pos> <from-end-p>)

引数

str
要搜寻的字串。

start-pos
字串中要开始搜寻的位置 (第一个字元为 0)；NIL则为 0。

from-end-p
如果指定 T 给引数，搜寻开始于字串的尾端，继续反向到 pos。

传回值
从字串的开端<start-pos>在位移找到STR；如果找不到则为 nil。

范例
(setq STR "沥SDDF 沥 bb")
(VL-STR-POSITION STR " " NIL T)
=>7

(setq STR "沥SDDF 沥 bb")
(VL-STR-POSITION STR " " NIL NIL)
=>5

(setq STR "沥SDDF 沥 bb")
(VL-STR-POSITION STR " " 1 T)
=>6

(setq STR "沥SDDF 沥 bb")
(VL-STR-POSITION STR " " 1 NIL)
=>4

(setq STR "沥SDDF 沥 bb")
(VL-STR-POSITION STR "R" 1 NIL)
=>NIL

(setq STR "沥SDDF 沥 bb")
(VL-STR-POSITION STR "R" 1 T)
=>NIL

(setq STR "沥沥 bb")
(VL-STR-POSITION STR " " NIL NIL)
=>2

(setq STR "沥a沥 bb")
(VL-STR-POSITION STR " " NIL NIL)
=>3

citykunan · 发表于 2005-12-27 16:19

原来要自己写，我写了一个望版主指教。：）

;(get_number "a李 fgag")返回3

(defun get_number (str / str_list i)
    (setq str_list (istr str))
    (setq i 1)
    (while (/= (car str_list) " ")
        (setq str_list (cdr str_list))
        (setq i (+ i 1))
    )
   i
)

;*******************************************************************
;此程序来自明经通道
;例: (istr "明经CAD社区")返回("明" "经" "C" "A" "D" "社" "区")

(defun istr (tt / nn k str_k)
(setq nn (strlen tt) k 1)
(while (<= k nn)
         (if (> (ascii (substr tt k 2)) 127)
         (setq str_k (append str_k (list (substr tt k 2))) k (+ k 2))
         (setq str_k (append str_k (list (substr tt k 1))) k (+ k 1))
         )
)
str_k
)
;*******************************************************************

龙龙仔 · 发表于 2005-12-27 17:23

我也不清楚中文是要(> 127) or (> 159)

get_number 应再改得更通用较好

citykunan · 发表于 2005-12-28 08:30

龙版主是用什么方法编的？能不能介绍一下思路啊？

龙龙仔 · 发表于 2005-12-28 11:56

还能如何编!跟你的一样!
(vl-load-com)
(vl-doc-export 'VL-STR-POSITION)
(defun VL-STR-POSITION (STR DELIM POSL POSR / LST)
(setq LST (TEXT_TO_LST STR))
(if POSL
(repeat POSL
(setq LST (cdr LST))
)
)
(if POSR
(progn
(setq LST (reverse LST))
(if (setq TMP (vl-position DELIM LST))
(- (1- (length LST)) TMP)
NIL
)
)
(vl-position DELIM LST)
)
)
;;WKAI
(vl-doc-export 'TEXT_TO_LST)
(defun TEXT_TO_LST (TEXT / N CHAR STRLST)
(setq N 1)
(while (<= N (strlen TEXT))
(setq CHAR (substr TEXT N 1))
(if (> (ascii CHAR) 159)
(and (substr TEXT (1+ N) 1)
(setq STRLST (cons (substr TEXT N 2) STRLST))
(setq N (1+ N))
)
(setq STRLST (cons CHAR STRLST))
)
(setq N (1+ N))
)
(reverse STRLST)
)

账号		自动登录	找回密码
密码			注册

vl-string-position返回值的问题

本帖子中包含更多资源