[求助]对象显示置前和置后的问题?

vocabulary

各位前辈:

      我正在用LISP写了一个给直线打断点的程序,在AutoCAD2004里用,断点的宽度和个数由用户决定,断点的宽度有时可能是0,用户有时会给一条直线打一个宽度是0的断点来把这条线一分为二,经过测试,发现还有不少毛病,其中一个问题是:两条长度一样的直线,一条是水平,一条垂直,两条直线在各自的中点处相交,其实就是一个十字架.我在用我写的程序给这两条线一起各打一个宽度为0的断点时,发现程序只能将其中的一条线一分为二,而另一条却打不断.但要是打有宽度的断点就没有问题.我怀疑可能是这个断点刚好在两条线的交点处,于是把这条没打断的线移动一点再试,结果就可以打断了.但只要把这条线移回原来的地方就怎么也打不断,后来我选中这条没有打断的线,然后在AutoCAD菜单:工具\显示顺序\前置.把这条打不断的线"前置".就可以打断了.请问大家,这个"前置"有没有哪个系统变量可以设置的,这个问题怎么解决?要实在没办法只能在打断每条线之前先把它给前置才行了.但我又不知道怎么调整这个"前置",请前辈们给指点指点,先谢谢了!!!

ljpnb

应该说不存在这种可能，这与前置后置应该没有关系，可能是程序上有不完善的地方。

vocabulary

TO:ljpnb大侠,下面是我直线打断点的程序,能不能在百忙之中抽空帮忙看一看是哪个地方有问题?小弟先谢谢您了!!!!

;;根据用户提供的断点宽度和断点数量来给一些用户选定的对象打断点
;;bb.lsp
;;打断点原则:如果断点宽度为0,按断点数将线段平均分成bnumber+1段.如果断点的宽度大于0, 则将线段平均分成bnumber*2段,然后只在奇数断点处打断,偶数断点忽略.
;;********************************************************************************
(defun c:bb()
  ;;存储环境
  (setq osm (getvar "osmode"))
  (setq oce (getvar "cmdecho"))
  (setvar "osmode" 0)
  (setvar "cmdecho" 0)
  (command ".UNDO" "BE") ;;设定UNDO的开始点
 
  (setq bwidth (getreal "\n请输入断点的宽度:"))
  (setq bnumber (getint "\n请输入断点个数:"))
  ;;断点宽度不能小于0
  (if  (< bwidth 0)
    (setq bwidth 0)
  )
  ;;断点数不能小于1
  (if (< bnumber 1)
    (setq bnumber 1)
  )
  ;;选择要打断点的线
  (setq ss1 (ssget))
  (if (null ss1)
    (progn
      (princ "\n没有选中对象!")
      (setq osm (getvar "osmode"))
      (setq oce (getvar "cmdecho"))
      (setvar "osmode" osm)
      (setvar "cmdecho" oce)
      (command ".UNDO" "E") ;;设定UNDO的结束点
      (exit)
    )
  )
  (setq sl1 (sslength ss1))
 
  (setq ids 0)  ;;选集循环种子初始化
  ;;选集循环开始，对用户所选的对象进行逐一处理
  (while (< ids sl1)
    (setq obname (ssname ss1 ids))
    (setq obinfor (entget obname))
    (setq obtype (cdr (assoc 0 obinfor)))
     ;;判断用户选择的对象类型,多条件开始
    (setq idx 1) ;;循环种子初始值,各种实体类型共用
    (cond
      ((= obtype "LINE")        ;;线条
        (progn
          ;;取得线段的始点和终点
          (setq ptst (cdr (assoc 10 obinfor)))     ;;始点
          (setq pted (cdr (assoc 11 obinfor)))     ;;终点
          (setq ang (angle ptst pted))             ;;角度
          (setq dst (distance ptst pted))          ;;线段长度
          ;;根据断点数来求每段平均长度
          (if (= bwidth 0)
            ;;断点宽度为0时
            (progn
       (setq edst (/ dst (1+ bnumber) 1.0))  ;;断点宽度为0时，分段数为:bnumber+1
              ;;开始循环
              (while (< idx (1+ bnumber ))
         (setq ptxa (polar ptst ang (* edst idx)))
         (setq ptxb ptxa)
         (command "_break" ptxa ptxb)
                (setq idx (1+ idx))
              )
       )
     ;;断点宽度大于0时
     (progn
       (setq edst (/ dst bnumber 2.0))       ;;断点宽度大于0时，分段数为:bnumber*2
              ;;开始循环
              (while (< idx (* bnumber 2))
         (setq ptxa (polar ptst ang (- (* edst idx) (/ bwidth 2.0))))
         (setq ptxb (polar ptst ang (+ (* edst idx) (/ bwidth 2.0))))
          (if (/= (rem idx 2) 0)   ;;只对奇数打断点，偶数忽略
           (command "_break" ptxa ptxb)
         )
                (setq idx (1+ idx))
              )
     )
          )
        )
      )  ;;线条件结束
      ((= obtype "CIRCLE"))      ;;圆
      ((= obtype "ARC"))          ;;弧
      ((= obtype "ELLIPSE"))     ;;椭圆
      ((= obtype "LWPLINE"))     ;;多义线
    ) ;;多条件结束
    (setq ids (1+ ids))         ;;选集循环种子递增。
  )  ;;选集循环结束
 
  (command ".UNDO" "E")  ;;设定UNDO的结束点
  ;;恢复环境
  (setvar "osmode" osm)
  (setvar "cmdecho" oce)
  (princ)
)

ljpnb

你的程序我好象没发现什么问题啊

3. ;;根据用户提供的断点宽度和断点数量来给一些用户选定的对象打断点
4. ;;bb.lsp
5. ;;打断点原则:如果断点宽度为0,按断点数将线段平均分成bnumber+1段.如果断点的宽度大于0, 则将线段平均分成bnumber*2段,然后只在奇数断点处打断,偶数断点忽略.
6. ;;********************************************************************************
7. (defun c:bb ()
8.   ;;存储环境
9.   (setq osm (getvar "osmode"))
10.   (setq oce (getvar "cmdecho"))
11.   (setvar "osmode" 0)
12.   (setvar "cmdecho" 0)
13.   (command ".UNDO" "BE")
14.   ;;设定UNDO的开始点
15.   (setq bwidth (getreal "\n请输入断点的宽度:"))
16.   (setq bnumber (getint "\n请输入断点个数:"))
17.   ;;断点宽度不能小于0
18.   (if (or (< bwidth 0)(= bwidth nil))
19.     (setq bwidth 0)
20.   )
21.   ;;断点数不能小于1
22.   (if (or (< bnumber 1)(= bnumber nil))
23.     (setq bnumber 1)
24.   )
25.   ;;选择要打断点的线
26.   (setq ss1 (ssget))
27.   (if (null ss1)
28.     (progn
29.       (princ "\n没有选中对象!")
30.       (setq osm (getvar "osmode"))
31.       (setq oce (getvar "cmdecho"))
32.       (setvar "osmode" osm)
33.       (setvar "cmdecho" oce)
34.       (command ".UNDO" "E")
35.       ;;设定UNDO的结束点
36.       (exit)
37.     )
38.   )
39.   (setq sl1 (sslength ss1))
40.   (setq ids 0)
41.   ;;选集循环种子初始化
42.   ;;选集循环开始，对用户所选的对象进行逐一处理
43.   (while (< ids sl1)
44.     (setq obname (ssname ss1 ids))
45.     (setq obinfor (entget obname))
46.     (setq obtype (cdr (assoc 0 obinfor)))
47.     ;;判断用户选择的对象类型,多条件开始
48.     (setq idx 1)
49.     ;;循环种子初始值,各种实体类型共用
50.     (cond
51.       ((= obtype "LINE")
52.        ;;线条
53.        (progn
54.   ;;取得线段的始点和终点
55.   (setq ptst (cdr (assoc 10 obinfor)))
56.   ;;始点
57.   (setq pted (cdr (assoc 11 obinfor)))
58.   ;;终点
59.   (setq ang (angle ptst pted))
60.   ;;角度
61.   (setq dst (distance ptst pted))
62.   ;;线段长度
63.   ;;根据断点数来求每段平均长度
64.   (if (= bwidth 0)
65.     ;;断点宽度为0时
66.     (progn
67.       (setq edst (/ dst (1+ bnumber) 1.0))
68.       ;;断点宽度为0时，分段数为:bnumber+1
69.       ;;开始循环
70.       (while (< idx (1+ bnumber))
71.         (setq ptxa (polar ptst ang (* edst idx)))
72.         (setq ptxb ptxa)
73.         (command "_break" obname ptxa ptxb)
74.         (setq obname (entlast))
75.         (setq idx (1+ idx))
76.       )
77.     )
78.     ;;断点宽度大于0时
79.     (progn
80.       (setq edst (/ dst bnumber 2.0))
81.       ;;断点宽度大于0时，分段数为:bnumber*2
82.       ;;开始循环
83.       (while (< idx (* bnumber 2))
84.         (setq
85.    ptxa (polar ptst ang (- (* edst idx) (/ bwidth 2.0)))
86.         )
87.         (setq
88.    ptxb (polar ptst ang (+ (* edst idx) (/ bwidth 2.0)))
89.         )
90.         (if (/= (rem idx 2) 0)
91.    ;;只对奇数打断点，偶数忽略
92.    (command "_break" ptxa ptxb)
93.         )
94.         (setq idx (1+ idx))
95.       )
96.     )
97.   )
98.        )
99.       )
100.       ;;线条件结束
101.       ((= obtype "CIRCLE"))
102.       ;;圆
103.       ((= obtype "ARC"))
104.       ;;弧
105.       ((= obtype "ELLIPSE"))
106.       ;;椭圆
107.       ((= obtype "LWPLINE"))
108.       ;;多义线
109.     )
110.     ;;多条件结束
111.     (setq ids (1+ ids))
112.     ;;选集循环种子递增。
113.   )
114.   ;;选集循环结束
115.   (command ".UNDO" "E")
116.   ;;设定UNDO的结束点
117.   ;;恢复环境
118.   (setvar "osmode" osm)
119.   (setvar "cmdecho" oce)
120.   (princ)
121. )

;;根据用户提供的断点宽度和断点数量来给一些用户选定的对象打断点 ;;bb.lsp ;;打断点原则:如果断点宽度为0,按断点数将线段平均分成bnumber+1段.如果断点的宽度大于0, 则将线段平均分成bnumber*2段,然后只在奇数断点处打断,偶数断点忽略. ;;******************************************************************************** (defun c:bb ()   ;;存储环境   (setq osm (getvar "osmode"))   (setq oce (getvar "cmdecho"))   (setvar "osmode" 0)   (setvar "cmdecho" 0)   (command ".UNDO" "BE")   ;;设定UNDO的开始点   (setq bwidth (getreal "\n请输入断点的宽度:"))   (setq bnumber (getint "\n请输入断点个数:"))   ;;断点宽度不能小于0   (if (or (< bwidth 0)(= bwidth nil))     (setq bwidth 0)   )   ;;断点数不能小于1   (if (or (< bnumber 1)(= bnumber nil))     (setq bnumber 1)   )   ;;选择要打断点的线   (setq ss1 (ssget))   (if (null ss1)     (progn       (princ "\n没有选中对象!")       (setq osm (getvar "osmode"))       (setq oce (getvar "cmdecho"))       (setvar "osmode" osm)       (setvar "cmdecho" oce)       (command ".UNDO" "E")       ;;设定UNDO的结束点       (exit)     )   )   (setq sl1 (sslength ss1))   (setq ids 0)   ;;选集循环种子初始化   ;;选集循环开始，对用户所选的对象进行逐一处理   (while (< ids sl1)     (setq obname (ssname ss1 ids))     (setq obinfor (entget obname))     (setq obtype (cdr (assoc 0 obinfor)))     ;;判断用户选择的对象类型,多条件开始     (setq idx 1)     ;;循环种子初始值,各种实体类型共用     (cond       ((= obtype "LINE")        ;;线条        (progn   ;;取得线段的始点和终点   (setq ptst (cdr (assoc 10 obinfor)))   ;;始点   (setq pted (cdr (assoc 11 obinfor)))   ;;终点   (setq ang (angle ptst pted))   ;;角度   (setq dst (distance ptst pted))   ;;线段长度   ;;根据断点数来求每段平均长度   (if (= bwidth 0)     ;;断点宽度为0时     (progn       (setq edst (/ dst (1+ bnumber) 1.0))       ;;断点宽度为0时，分段数为:bnumber+1       ;;开始循环       (while (< idx (1+ bnumber))         (setq ptxa (polar ptst ang (* edst idx)))         (setq ptxb ptxa)         (command "_break" obname ptxa ptxb)         (setq obname (entlast))         (setq idx (1+ idx))       )     )     ;;断点宽度大于0时     (progn       (setq edst (/ dst bnumber 2.0))       ;;断点宽度大于0时，分段数为:bnumber*2       ;;开始循环       (while (< idx (* bnumber 2))         (setq    ptxa (polar ptst ang (- (* edst idx) (/ bwidth 2.0)))         )         (setq    ptxb (polar ptst ang (+ (* edst idx) (/ bwidth 2.0)))         )         (if (/= (rem idx 2) 0)    ;;只对奇数打断点，偶数忽略    (command "_break" ptxa ptxb)         )         (setq idx (1+ idx))       )     )   )        )       )       ;;线条件结束       ((= obtype "CIRCLE"))       ;;圆       ((= obtype "ARC"))       ;;弧       ((= obtype "ELLIPSE"))       ;;椭圆       ((= obtype "LWPLINE"))       ;;多义线     )     ;;多条件结束     (setq ids (1+ ids))     ;;选集循环种子递增。   )   ;;选集循环结束   (command ".UNDO" "E")   ;;设定UNDO的结束点   ;;恢复环境   (setvar "osmode" osm)   (setvar "cmdecho" oce)   (princ) )

Andyhon

这个给您参考

Command: (setq ee (list ee pt))
(<Entity name: 7ef5fee8> (289.215 142.986 0.0))

Command: b
BREAK Select object: !ee
(<Entity name: 7ef5fee8> (289.215 142.986 0.0))

Specify second break point or [First point]: f

Specify first break point: !pt
(289.215 142.986 0.0)

Specify second break point: !pt
(289.215 142.986 0.0)

vocabulary

To:ljpnb大侠，谢谢您的帮忙，我看了您给我修改的程序

 (command "_break" obname ptxa ptxb)    ;;我在这里加上了obname
 (setq obname (entlast))    ;;在下面加了这行语句，直线的问题就解决了。但给圆圈打断点的程序里加上后面这句就出问题了。出现要打三个断点的就只能打一个。我正在研究中。另外我想问一问，怎样才能像您这样把代码插入到那个列表框里，而且还能改字体颜色？

To:Andyhon大侠，谢谢您，我想在程序里解决问题。

ljpnb

如果是给圆打断，需要注意两点：

一，断口宽度为0时，不可以直接(command "_break" obname ptxa ptxa）

二。断口宽度为>0时，第一次break后，没有产生新的实体，也就是说用(setq obname (entlast)) 这句是错误的。第二次break后，才可以用(setq obname (entlast)) 

vocabulary

TO:ljpnb大侠，那么断点宽度为0时，我该怎么处理呢？能不能讲一讲？谢谢您！

ljpnb

参考一下：

3. (defun c:dfy (/ ent old-num num p0 p1 param div-param i point);_等分圆
4.    (setq ent (car (entsel "\n选择需要等分的圆:")))
5.    (if (null old-num)
6.      (setq old-num 2)
7.    )
8.    (if (setq num (getint (strcat "\n输入等分数量<" (rtos old-num) ">:")))
9.      (setq old-num num)
10.      (setq num old-num)
11.    )
12.    (setq obj (vlax-ename->vla-object ent))
13.    (setq p0   (vlax-curve-getStartPoint obj)
14.   param   (vlax-curve-getEndParam obj)
15.   div-param (/ param num)
16.    )
17.    (setq p1 (vlax-curve-getPointAtParam obj -0.1))
18.    (command "break" ent "none" p1 "none" p0)
19.    (setq i 1)
20.    (repeat (1- num)
21.      (setq point (vlax-curve-getPointAtParam obj (* i div-param)))
22.      (command "break" ent "none" point "none" point)
23.      (setq ent (entlast))
24.      (setq obj (vlax-ename->vla-object ent))
25.      (setq i (1+ i))
26.    )
27.    (vla-put-endangle obj 0.0)
28.    (princ)
29. )

(defun c:dfy (/ ent old-num num p0 p1 param div-param i point);_等分圆    (setq ent (car (entsel "\n选择需要等分的圆:")))    (if (null old-num)      (setq old-num 2)    )    (if (setq num (getint (strcat "\n输入等分数量<" (rtos old-num) ">:")))      (setq old-num num)      (setq num old-num)    )    (setq obj (vlax-ename->vla-object ent))    (setq p0   (vlax-curve-getStartPoint obj)   param   (vlax-curve-getEndParam obj)   div-param (/ param num)    )    (setq p1 (vlax-curve-getPointAtParam obj -0.1))    (command "break" ent "none" p1 "none" p0)    (setq i 1)    (repeat (1- num)      (setq point (vlax-curve-getPointAtParam obj (* i div-param)))      (command "break" ent "none" point "none" point)      (setq ent (entlast))      (setq obj (vlax-ename->vla-object ent))      (setq i (1+ i))    )    (vla-put-endangle obj 0.0)    (princ) )

vocabulary

哇,好多新函数呀,好好学习!!!谢谢ljpnb前辈.另外小弟有一事相求,能否加您为我的QQ好友?我的QQ号为:86851026,如果能有您这么一位知识丰富的QQ好友实在是我三生的荣幸呀!!!当然如果不方便也没关系,咱们也可以在论坛里交流.再次感谢您的热心帮助!!!