怎样用Vlisp判断一个布局名是否存在？

Hart

怎样用Vlisp判断一个布局名是否存在？
tblobjname 好像不能查找布局名?

chg

(setq elist (member '(3 . "ACAD_LAYOUT") (entget (namedobjdict))))
(setq ln (member '(3 . "LAYOUTNAME") elist))
(if ln
  (princ "\"LAYOUTNAME\" is exist.")
  (princ "\"LAYOUTNAME\" is not exist.")
  )

mccad

'判断布局是否存在的函数
(defun HasLayoutName (LayoutName / i layouts layout HasLName)
  (setq i       -1
        layouts (vla-get-layouts
                  (vla-get-activedocument (vlax-get-acad-object))
                )
  )
  (vlax-for layout layouts
    (if (= (vla-get-name layout) LayoutName)
      (setq HasLName T)
    )
  )
  HasLName
)

'示例：
(defun cName ()
  (setq LN (getstring "\n请输入要查找的布局名称："))
  (if (haslayoutname ln)
    (princ "\n找到该名称的布局")
    (princ "\n未找到该名称的布局")
  )
  (princ)
)

该函数已经加入到实用函数中，同时加入的有VBA的方法

龙龙仔

;;判斷"符號表"否存在
;;USAGE: (HAS "LAYOUTS" "123")
;;USAGE: (HAS "LAYERS" "DIM")
(defun HAS (TYPE_1 NAME)
  (if (not
        (vl-catch-all-error-p
          (vl-catch-all-apply
            'vla-item
            (list ((eval (read (strcat "vla-get-" TYPE_1)))
                    (vla-get-activedocument (vlax-get-acad-object))
                  )
                  NAME
            )
          )
        )
      )
    t
  )
)

Hart

millermin

mccad 发表于 2003-2-19 20:21
'判断布局是否存在的函数
(defun HasLayoutName (LayoutName / i layouts layout HasLName)
  (setq i    ...

我参考了您的方法，用在我的dbx程序里，结果每个layout和model都显示出来了。我并不需要model。本来vla-get-loyouts应该是所有layout的集合，不应该包含model，是不是那出错了？我需要仅仅包括layout名的集合。