[讨论]一段可绘出弹簧的代码，中间有几个不明白的地方

超然A

2. ;========================================================================
3. (defun C:3DSPIRAL (/ olderr ocmd oblp nt bp hg vg sr lp)
4.   (setq olderr  *error*
5.         *error* myerror)
6.   (setq ocmd (getvar "cmdecho"))
7.   (setq oblp (getvar "blipmode"))
8.   (setvar "cmdecho" 0)
9.   (initget 1)                         ; bp must not be null
10.   (setq bp (getpoint "\nCenter point: "));起始圈圆心
11.   (initget 7)                         ; nt must not be zero, neg, or null
12.   (setq nt (getint "\nNumber of rotations: "));弹簧圈数
13.   (initget 7)                         ; sr must not be zero, neg, or null
14.   (setq sr (getdist bp "\nStarting radius: "));起始圈半径
15.   (initget 1)                         ; cf must not be zero, or null
16.   (setq hg (getdist "\nHorizontal growth per rotation: "));每圈的水平增量，为0时绘出的弹簧粗细均匀
17.   (initget 3)                         ; cf must not be zero, or null
18.   (setq vg (getdist "\nVertical growth per rotation: "));每圈的垂直增量，也就是相邻两个圈的距离
19.   (initget 6)                         ; lp must not be zero or neg
20.   (setq lp (getint "\nPoints per rotation <30>: "));每圈上设置多少个点，点越多越接近圆。默认值30
21.   (cond ((null lp) (setq lp 30)))
22.   (cspiral nt bp hg lp sr vg)
23.   (setvar "cmdecho" ocmd)
24.   (setvar "blipmode" oblp)
25.   (setq *error* olderr)               ; Restore old *error* handler
26.   (princ)
27. )
28. ;==========================================================================
29. (defun myerror (s)                    ; If an error (such as CTRL-C) occurs
30.                                       ; while this command is active...
31.   (if (/= s "Function cancelled")
32.     (princ (strcat "\nError: " s))
33.   )
34.   (setvar "cmdecho" ocmd)             ; Restore saved modes
35.   (setvar "blipmode" oblp)
36.   (setq *error* olderr)               ; Restore old *error* handler
37.   (princ)
38. )
39. ;======================================================================
40. (defun cspiral (ntimes bpoint hfac lppass strad vfac
41.                 / ang dist tp ainc dhinc dvinc circle dv)
42.   (setvar "blipmode" 0)               ; turn blipmode off
43.   (setvar "cmdecho" 0)                ; turn cmdecho off
44.   (setq circle (* 3.1415926535 2))
45.   (setq ainc (/ circle lppass))
46.   (setq dhinc (/ hfac lppass))
47.   (if vfac (setq dvinc (/ vfac lppass)))
48.   (setq ang 0.0)
49.   (if vfac
50.     (setq dist strad dv 0.0)
51.     (setq dist 0.0)
52.   )
53.   (if vfac
54.     (command "_3dpoly")               ; start spiral ...
55.     (command "_pline" bpoint)         ; start spiral from base point and...
56.   )
57.   (repeat ntimes
58.     (repeat lppass
59.       (setq tp (polar bpoint (setq ang (+ ang ainc))
60.                       (setq dist (+ dist dhinc))
61.                )
62.       )
63.       (if vfac
64.           (setq tp (list (car tp) (cadr tp) (+ dv (caddr tp)))
65.                 dv (+ dv dvinc)
66.           )
67.       )
68.       (command tp)                    ; continue to the next point...
69.     )
70.   )
71.   (command "")                        ; until done.
72.   (princ)
73. )

;======================================================================== (defun C:3DSPIRAL (/ olderr ocmd oblp nt bp hg vg sr lp)   (setq olderr  *error*         *error* myerror)   (setq ocmd (getvar "cmdecho"))   (setq oblp (getvar "blipmode"))   (setvar "cmdecho" 0)   (initget 1)                         ; bp must not be null   (setq bp (getpoint "\nCenter point: "));起始圈圆心   (initget 7)                         ; nt must not be zero, neg, or null   (setq nt (getint "\nNumber of rotations: "));弹簧圈数   (initget 7)                         ; sr must not be zero, neg, or null   (setq sr (getdist bp "\nStarting radius: "));起始圈半径   (initget 1)                         ; cf must not be zero, or null   (setq hg (getdist "\nHorizontal growth per rotation: "));每圈的水平增量，为0时绘出的弹簧粗细均匀   (initget 3)                         ; cf must not be zero, or null   (setq vg (getdist "\nVertical growth per rotation: "));每圈的垂直增量，也就是相邻两个圈的距离   (initget 6)                         ; lp must not be zero or neg   (setq lp (getint "\nPoints per rotation <30>: "));每圈上设置多少个点，点越多越接近圆。默认值30   (cond ((null lp) (setq lp 30)))   (cspiral nt bp hg lp sr vg)   (setvar "cmdecho" ocmd)   (setvar "blipmode" oblp)   (setq *error* olderr)               ; Restore old *error* handler   (princ) ) ;========================================================================== (defun myerror (s)                    ; If an error (such as CTRL-C) occurs                                       ; while this command is active...   (if (/= s "Function cancelled")     (princ (strcat "\nError: " s))   )   (setvar "cmdecho" ocmd)             ; Restore saved modes   (setvar "blipmode" oblp)   (setq *error* olderr)               ; Restore old *error* handler   (princ) ) ;====================================================================== (defun cspiral (ntimes bpoint hfac lppass strad vfac                 / ang dist tp ainc dhinc dvinc circle dv)   (setvar "blipmode" 0)               ; turn blipmode off   (setvar "cmdecho" 0)                ; turn cmdecho off   (setq circle (* 3.1415926535 2))   (setq ainc (/ circle lppass))   (setq dhinc (/ hfac lppass))   (if vfac (setq dvinc (/ vfac lppass)))   (setq ang 0.0)   (if vfac     (setq dist strad dv 0.0)     (setq dist 0.0)   )   (if vfac     (command "_3dpoly")               ; start spiral ...     (command "_pline" bpoint)         ; start spiral from base point and...   )   (repeat ntimes     (repeat lppass       (setq tp (polar bpoint (setq ang (+ ang ainc))                       (setq dist (+ dist dhinc))                )       )       (if vfac           (setq tp (list (car tp) (cadr tp) (+ dv (caddr tp)))                 dv (+ dv dvinc)           )       )       (command tp)                    ; continue to the next point...     )   )   (command "")                        ; until done.   (princ) )

请问这里面的：
  (initget 1)        
  (initget 7)         
  (initget 7)                 
  (initget 1)            
  (initget 3)                       
  (initget 6)   
有什么作用？

ljpnb

1(位0)	阻止用户仅经过按下  Enter  键来回应要求
2(位1)	阻止用户仅经过键入 0 值来回应要求
4(位2)	阻止用户仅通过键入负值来回应要求

超然A

明白了  谢谢老顽童    （我是杨过哦，哈哈  以后是）