设为首页收藏本站CAD论坛CAD教程CAD下载明经币充值
切换到宽版

明经CAD社区

 找回密码
 注册

QQ登录

只需一步，快速开始

搜索
明经CAD社区»社区 › 开发篇 › AutoLISP/Visual LISP 编程技术 › [原创]带属性序号球，有动态拖拽效果，欢迎测试使用！
1234下一页
返回列表 发新帖
查看: 11911|回复: 34

[原创]带属性序号球，有动态拖拽效果，欢迎测试使用！

  [复制链接]
Dallas_whu
发表于 2006-11-10 18:30:00 | 显示全部楼层 |阅读模式
上传的附件哪里去了？有没有版主介绍一下发帖规则？


  
  
  
  2. ;;属性序号球  BY HB.LEE 2006-11-10；
  3. (PRINC "\n*** 带属性序号球绘制, 命令: GJ . BY HB.Lee  2006-11-10. ***")
  4. (Defun C:GJ  (/  Actdoc  Addor  Attball Att_Bl Att_Gjh  Att_Pref
  5.           Att_Str Def_Gjh  Firstpt  Gjbl Gj_Id  I  Insertpt  Mspace
  6.           Oldcmd  Oldcurs  Oldlay  Oldos  Pref  Startpt Att_Addor
  7.            )
  8.     (Vl-Load-Com)
  9.     ;;错误处理函数
  10.     (Defun *$Myerror$*    (Msg)
  11.     (Redraw)
  12.     (Setvar "Osmode" Oldos)
  13.     (Setvar "Clayer" Oldlay)
  14.     (Setvar "Cursorsize" Oldcurs)
  15.     ;;确保出错时插入的块能删除
  16.     (If Attball (Vla-Delete Attball))
  17.     (Setvar "Cmdecho" Oldcmd)
  18.     (Setq *Error* &Olderr&)
  19.         (Princ "*取消*")
  20.     (Princ)
  21.     )
  22.     (Setq &Olderr& *Error*)
  23.     (Setq *Error* *$Myerror$*)
  24.     (Setq Actdoc (Vla-Get-Activedocument (Vlax-Get-Acad-Object)))
  25.     (Setq Mspace (Vla-Get-Modelspace Actdoc))
  26.     (Setq Oldlay (Getvar "Clayer"))
  27.     (Setq Oldos (Getvar "Osmode"))
  28.     (Setq Oldcmd (Getvar "Cmdecho"))
  29.     (Setq Oldcurs (Getvar "Cursorsize"))
  30.     (Setvar "Cmdecho" 0)
  31.     (Vla-Startundomark Actdoc)
  32.     (Setq Gj_Id T)
  33.     ;;捕捉方式设定
  34.     (Setvar "Osmode" (+ 1 2 32 128 512))
  35.     (While Gj_Id
  36.     (Initget 128 "P C S B")
  37.     ;;设置初始比例
  38.     (Setq Gjbl (Vlax-Ldata-Get "Attball" "Gjbl"))
  39.     (If (Not Gjbl) (Setq Gjbl (Rtos (Getvar "Dimscale") 2 2)))
  40.     ;;设置编号前缀
  41.     (Setq Pref (Vlax-Ldata-Get "Attball" "Prefix"))
  42.     (If (OR (= "" Pref) (= NIL Pref))
  43.         (Progn (Setq Pref "") (Princ "\n当前编号无前缀!"))
  44.         (Princ (Strcat "\n当前编号前缀:" Pref))
  45.         )
  46.     ;;设置序号递增或递减,默认递增
  47.     (Setq Addor (Vlax-Ldata-Get "Attball" "Addor"))
  48.     (If (AND ADDOR (= Addor "N"))
  49.       (Princ "   序号递减!")
  50.       (PROGN (Princ "   序号递增!") (SETQ Addor "Y"))
  51.     )
  52.         (Setq Att_Addor Addor)
  53.     ;;改变序号
  54.     (Setq Def_Gjh (Vlax-Ldata-Get "Attball" "Gjh_N"))
  55.     (If (Not Def_Gjh) (Setq Def_Gjh "1"))
  57.     ;;设置默认字符串
  58.     (Setq Att_Str (Strcat Pref Def_Gjh))
  59.     (Setq Att_Gjh Def_Gjh)
  60.     (Setq Att_Bl (Atof Gjbl))
  61.     (Setq Att_Pref Pref)
  62.     (Setq Startpt
  63.          (Getpoint
  64.              (Strcat
  65.              "\n输入构件号引出点或[改绘图比例(S)/改编号前缀(P)/递增或递减(C)/改当前序号(B)]<"
  66.              Att_Str
  67.              ">:"
  68.              )
  69.              )
  70.           )
  71.     (Cond
  72.         ;;设置初始比例
  73.         ((Or (= Startpt "S") (= Startpt "s"))
  74.          (Setq Att_Bl (Getreal (Strcat "\n请输入新的绘图比例<" Gjbl ">:")))
  75.          (If (Not Att_Bl) (Setq Att_Bl (Atof Gjbl)))
  76.          (Vlax-Ldata-Put "Attball" "Gjbl" (Rtos Att_Bl 2 2))
  77.          )
  78.         ;;设置编号前缀
  79.         ((Or (= Startpt "P") (= Startpt "p"))
  80.          (IF (= "" PREF)
  81.            (Setq Att_Pref (Getstring (Strcat "\n若需前缀,请输入编号前缀:")))
  82.            (Setq Att_Pref (Getstring (Strcat "\n若需前缀,请输入编号前缀<" Pref ">:")))
  83.          )
  84.          (If (Not Att_Pref) (Setq Att_Pref Nil))
  85.          (Vlax-Ldata-Put "Attball" "Prefix" Att_Pref)
  86.          )
  87.         ;;设置序号递增或递减,默认递增
  88.         ((Or (= Startpt "C") (= Startpt "c"))
  89.          (Setq Att_Addor (Getstring (Strcat "\n序号是否按顺序递增<" Addor ">:")))
  90.          (If (/= (Strcase Att_Addor) "N") (Setq Att_Addor "Y"))
  91.          (Vlax-Ldata-Put "Attball" "Addor" (Strcase Att_Addor))
  92.          )
  94.         ;;改当前序号
  95.         ((Or (= Startpt "B") (= Startpt "b"))
  96.          (Setq Att_Gjh
  97.               (Getint
  98.               (Strcat "\n请输入新的序号[当前默认序号<" Def_Gjh ">]:")
  99.               )
  100.            )
  101.          (Vlax-Ldata-Put "Attball" "Gjh_N" (Itoa Att_Gjh))
  102.          (If (Not Att_Gjh)
  103.          (Setq Att_Str (Strcat Pref Def_Gjh))
  104.          (Setq Att_Str (Strcat Pref (Itoa Att_Gjh)))
  105.          )
  106.          )
  107.         ;;得到坐标，设置插入点
  108.         ((= (Type Startpt) 'List)
  109.          (If (Null (Tblobjname "Block" (Strcat "Lhb_No_" Att_Pref)))
  110.         (Progn
  111.           (Entmake_Att 2.5 Att_Str Att_Pref)
  112.           (Entdel (Entlast))
  113.         )
  114.          )
  115.          (Setq Insertpt (Vlax-3d-Point (Polar Startpt 0 (* Att_Bl 2.5))))
  116.          (Setq Attball (Vla-Insertblock Mspace Insertpt (Strcat "Lhb_No_" Att_Pref)
  117.                  Att_Bl
  118.                  Att_Bl
  119.                  1
  120.                  0
  121.                )
  122.          )
  123.          (Foreach I (Vlax-Safearray->List
  124.               (Vlax-Variant-Value
  125.                 (Vla-Getattributes Attball)
  126.               )
  127.             )
  128.            (Vla-Put-Textstring I Att_Str) ;属性值
  129.            (Vla-Put-Tagstring I Att_Str) ;标签
  130.            (If (> (Strlen Att_Str) 2) (Vla-Put-Scalefactor I 0.5)
  131.            )
  132.          )
  133.          ;;动态预览
  134.          (View_Gj Attball Startpt Att_Bl)
  135.          (Setq Attball Nil)
  136.          ;;序号递增或递减
  137.          (If (/= (Strcase Att_Addor) "N")
  138.          (Progn
  139.              (Setq Def_Gjh (Itoa (1+ (Atoi Def_Gjh))))
  140.              (Vlax-Ldata-Put "Attball" "Gjh_N" Def_Gjh)
  141.              )
  142.          (Progn
  143.              (Setq Def_Gjh (Itoa (1- (Atoi Def_Gjh))))
  144.              (If (< (Atoi Def_Gjh) 0)
  145.              (Progn    (Setq Def_Gjh "0")
  146.                 (Princ "\n***  编号不能为负数!  ***")
  147.                 )
  148.              )
  149.              (Vlax-Ldata-Put "Attball" "Gjh_N" Def_Gjh)
  150.              )
  151.          ); END IF
  152.          )            ; End TYPE
  153.          ;;动态预览
  154.          (View_Gj Attball Startpt Att_Bl)
  155.          (Setq Attball Nil)
  156.          ;;序号递增或递减
  157.          (If (/= (Strcase Att_Addor) "N")
  158.          (Progn
  159.              (Setq Def_Gjh (Itoa (1+ (Atoi Def_Gjh))))
  160.              (Vlax-Ldata-Put "Attball" "Gjh_N" Def_Gjh)
  161.              )
  162.          (Progn
  163.              (Setq Def_Gjh (Itoa (1- (Atoi Def_Gjh))))
  164.              (If (< (Atoi Def_Gjh) 0)
  165.              (Progn    (Setq Def_Gjh "0")
  166.                 (Princ "\n***  编号不能为负数!  ***")
  167.                 )
  168.              )
  169.              (Vlax-Ldata-Put "Attball" "Gjh_N" Def_Gjh)
  170.              )
  171.          )                ;End Type
  172.         (T (Setq Gj_Id Nil) (PRINC "\n无效的选择或者输入!请重新确认."))
  173.         )
  174.     )
  175.     (Setvar "Clayer" Oldlay)
  176.     (Setvar "Cursorsize" Oldcurs)
  177.     (Vla-Endundomark Actdoc)
  178.     (Setvar "Osmode" Oldos)
  179.     (Setvar "Cmdecho" Oldcmd)
  180.     (Setq *Error* &Olderr&)
  181.     (Princ)
  182.     )
  184. ;;;构件编号动态预览
  185. (DEFUN VIEW_GJ    (VOBJ     VBASEPT VBL     /     DIST     FIRSTPT
  186.          LOOP_ID NEWCENPT     PT1     PT10     PT11
  187.          PT12     PT2     PT3     PT4     PT5     PT6
  188.          PT7     PT8     PT9     VANGLE     VPOINT     VPOINTENT
  189.          MOVEPT)
  190.     (SETQ LOOP_ID T)
  191.     (SETQ ALPHA 0)
  192.     (SETVAR "CURSORSIZE" 1)        ;将光标大小设置为1，最小尺寸
  193.     (PRINC "\n请输入构件号标注点:")
  194.     (WHILE LOOP_ID
  195.     (SETQ VPOINTENT (GRREAD T 4 1))
  196.     (IF (= 5 (CAR VPOINTENT))    ;鼠标跟踪
  197.         (PROGN
  198.         (REDRAW)
  199.         (SETQ VPOINT (CADR VPOINTENT))
  200.         (SETQ MOVEPT VPOINT)    ;记录直线第二点
  201.         (SETQ DIST (DISTANCE VBASEPT VPOINT))
  202.         (SETQ VANGLE (ANGLE VBASEPT VPOINT))
  203.         (SETQ NEWCENPT (POLAR VBASEPT VANGLE (+ DIST (* VBL 2.5))))
  204.         (SETQ FIRSTPT (Vlax-3d-Point NEWCENPT))
  205.         (VLA-PUT-INSERTIONPOINT VOBJ FIRSTPT)
  206.         (GRVECS (LIST 2 VBASEPT VPOINT))
  207.         ;;================================================================
  208.         ;;动态旋转“奔驰”标志,此段可去掉，纯属好玩。
  209.         ;;标注点标志
  210.         (SETQ PT1 (POLAR VPOINT (+ ALPHA (* PI 0.5)) (* VBL 1.0))
  211.               PT2 (POLAR VPOINT (+ ALPHA (/ (* PI 7) 6)) (* VBL 1.0))
  212.               PT3 (POLAR VPOINT (+ ALPHA (/ (* PI 11) 6)) (* VBL 1.0))
  213.               PT4 (POLAR VPOINT (+ ALPHA (/ (* PI 5) 6)) (* VBL 0.268))
  214.               PT5 (POLAR VPOINT (+ ALPHA (* PI 1.5)) (* VBL 0.268))
  215.               PT6 (POLAR VPOINT (+ ALPHA (/ PI 6)) (* VBL 0.268))
  216.               )
  217.         (GRVECS    (LIST 1        PT1      VPOINT      1        PT2      VPOINT
  218.                   1        PT3      VPOINT      6        PT4      VPOINT
  219.                   6        PT5      VPOINT      6        PT6      VPOINT
  220.                   6        PT1      PT4    6     PT4   PT2      6
  221.                   PT2   PT5      6    PT5   PT3   6      PT3
  222.                   PT6   6      PT6    PT1)
  223.             )
  224.         ;;引出点标志
  225.         (SETQ PT7  (POLAR VBASEPT (+ ALPHA (* PI 0.5)) (* VBL 1.0))
  226.               PT8  (POLAR VBASEPT (+ ALPHA (/ (* PI 7) 6)) (* VBL 1.0))
  227.               PT9  (POLAR VBASEPT (+ ALPHA (/ (* PI 11) 6)) (* VBL 1.0))
  228.               PT10 (POLAR VBASEPT (+ ALPHA (/ (* PI 5) 6)) (* VBL 0.268))
  229.               PT11 (POLAR VBASEPT (+ ALPHA (* PI 1.5)) (* VBL 0.268))
  230.               PT12 (POLAR VBASEPT (+ ALPHA (/ PI 6)) (* VBL 0.268))
  231.               )
  232.         (GRVECS    (LIST 1         PT7    VBASEPT      1     PT8
  233.                   VBASEPT        1       PT9      VBASEPT
  234.                   5         PT10   VBASEPT      5     PT11
  235.                   VBASEPT        5       PT12      VBASEPT
  236.                   5         PT7    PT10   5      PT10     PT8
  237.                   5         PT8    PT11   5      PT11     PT9
  238.                   5         PT9    PT12   5      PT12     PT7)
  239.             )
  240.             ;;设置三角星旋转速度，若想加快可将0.056适当加大，如0.112.
  241.             (SETQ ALPHA (+ ALPHA (* PI 0.084)))
  242.         ;;================================================================
  243.         )
  244.         )
  245.         ;; 若点击鼠标左、右键或键盘任意按键，则取得当前鼠标位置，并绘制符号
  246.     (IF (OR    (= 3 (CAR VPOINTENT))
  247.         (= 2 (CAR VPOINTENT))
  248.         (= 11 (CAR VPOINTENT))
  249.         )
  250.         (PROGN
  251.         (REDRAW)
  252.         (SETQ LOOP_ID NIL)
  253.                 ;;绘制直线
  254.         (SETVAR "CLAYER" "构件符号")
  255.         (SETQ STARTPT (Vlax-3d-Point VBASEPT))
  256.         (SETQ ENDPT (Vlax-3d-Point MOVEPT))
  257.         (VLA-ADDLINE MSPACE STARTPT ENDPT)
  258.         )
  259.         )
  260.     )                ;END WHILE
  261.     (SETVAR "CURSORSIZE" OLDCURS)
  262.     (PRINC)
  263.     )                    ;DEFUN VIEW_GJ
  265. ;;建立属性编号
  266. (DEFUN ENTMAKE_ATT  (CIRRAD TEXT PREFIX / CHK_LAYER CHK_STYLE BLKNAME BLKN LST0
  267.              LST1)
  268.     ;;建立编号圆圈图层
  269.     (SETQ CHK_LAYER (TBLSEARCH "LAYER" "构件符号"))
  270.     (IF    (= CHK_LAYER NIL)
  271.     (PROGN
  272.         (ENTMAKE (LIST
  273.              '(0 . "LAYER")
  274.              '(100 . "AcDbSymbolTableRecord")
  275.              '(100 . "AcDbLayerTableRecord")
  276.              '(6 . "continuous") ;线型
  277.              '(62 . 2)    ;颜色
  278.              '(70 . 0)    ;图层状态
  279.              (CONS 2 "构件符号") ;图层名
  280.              )
  281.              )
  282.         )
  283.     )
  285.     ;;建立编号文字图层
  286.     (SETQ CHK_LAYER (TBLSEARCH "LAYER" "构件编号"))
  287.     (IF    (= CHK_LAYER NIL)
  288.     (PROGN
  289.         (ENTMAKE (LIST
  290.              '(0 . "LAYER")
  291.              '(100
  292.                .
  293.                "AcDbSymbolTableRecord")
  294.              '(100 . "AcDbLayerTableRecord")
  295.              '(6 . "continuous") ;线型
  296.              '(62 . 6)    ;颜色
  297.              '(70 . 0)    ;图层状态
  298.              '(2 . "构件编号") ;图层名
  299.              )
  300.              )
  301.         )
  302.     )
  304.     ;;建立编号文字字型
  305.     (SETQ CHK_STYLE (TBLSEARCH "STYLE" "NUM_STYLE"))
  306.     (IF    (= CHK_STYLE NIL)
  307.     (ENTMAKE (LIST
  308.              '(0 . "STYLE")    ;对象名称
  309.              '(100 . "AcDbSymbolTableRecord")
  310.              '(100
  311.                .
  312.                "AcDbTextStyleTableRecord") ;子类标记
  313.              '(2 . "NUM_STYLE")    ;字体样式名
  314.              '(70 . 0)        ;标注位码
  315.              '(40 . 0.0)    ;文字高度
  316.              '(41 . 0.7)    ;宽度系数
  317.              '(50 . 0.0)    ;字斜角
  318.              '(71 . 0)        ;文字生成标注位码2＝反向，4＝颠倒
  319.              '(3 . "TSSDENG.shx") ;西文字体名
  320.              '(4 . "HZTXT.shx")    ;中文字体名
  321.              ) ;_ 结束LIST
  322.          ) ;_ 结束ENTMAKE
  323.     ) ;_ 结束IF
  324.    
  325.     ;;设置属性块名
  326.     (SETQ BLKNAME (Strcat "Lhb_No_" PREFIX))
  328.     (ENTMAKE
  329.     (LIST '(0 . "BLOCK")
  330.           (CONS 2 BLKNAME)        ;图块名称
  331.           '(70 . 2)            ;设置属性块是否可以编辑
  332.           '(10 0.0 0.0 0.0))    ;基准点
  333.     )
  334.     (ENTMAKE (LIST '(0 . "CIRCLE")
  335.            '(100 . "AcDbEntity")
  336.            '(67 . 0)
  337.            '(8 . "构件符号")    ;图层名称
  338.            '(100 . "CIRCLE")
  339.            '(10 0.0 0.0 0.0)    ;中心点
  340.            (CONS 40 CIRRAD)    ;半径
  341.            '(210 0.0 0.0 1.0)
  342.            )
  343.          )
  344.     (ENTMAKE (LIST '(0 . "ATTDEF")
  345.            '(100 . "AcDbEntity")
  346.            '(67 . 0)
  347.            '(8 . "构件编号")    ;图层名称
  348.            '(100 . "AcDbText")
  349.            '(10 -1.08 -1.75 0.0) ;文字起点
  350.            (CONS 40 (+ CIRRAD 1.0)) ;文字高度
  351.            '(1 . "A")        ;默认值
  352.            '(50 . 0)        ;文字旋转
  353.            '(41 . 0.7)        ;相对X比例系数
  354.            '(51 . 0.0)        ;倾斜角度
  355.            '(7 . "NUM_STYLE")    ;文字字型
  356.            '(71 . 0)        ;文字产生的标志
  357.            '(72 . 1)        ;水平文字的对齐类型
  358.            '(11 0.0 0.0 0.0)    ;对齐点，只有在72与74非0才有意义
  359.            '(210 0.0 0.0 1.0)    ;挤出方向
  360.            '(100 . "AcDbAttributeDefinition")
  361.            '(3 . "编号属性")    ;提示字符串
  362.            '(2 . "A")        ;卷标字符串
  363.            '(70 . 0)        ;属性标志
  364.            '(73 . 0)        ;字段长度
  365.            '(74 . 2)        ;垂直文字的对齐类型
  366.            )
  367.          )
  368.     (SETQ BLKN (ENTMAKE '((0 . "ENDBLK"))))
  369.     (SETQ LST0 (LIST '(0 . "INSERT") '(100 . "AcDbEntity") '(67 . 0)
  370.              '(8 . "构件符号")    ;图层
  371.              '(100 . "AcDbBlockReference") '(66 . 1) '(10 0.0 0.0 0.0)
  372.                     ;插入点
  373.              '(41 . 1.0)    ;x
  374.              '(42 . 1.0)    ;y
  375.              '(43 . 1.0)    ;z
  376.              '(50 . 0.0)    ;旋转角度
  377.              '(70 . 0)        ;插入行数
  378.              '(71 . 0)        ;插入列数
  379.              '(44 . 0.0)    ;行间距
  380.              '(45 . 0.0)    ;列间距
  381.              '(210 0.0 0.0 1.0))
  382.       )
  383.     (SETQ LST1 (APPEND LST0 (LIST (CONS 2 BLKN))))
  384.     (ENTMAKE LST1)
  385.     (ENTMAKE (LIST '(0 . "ATTRIB")
  386.            '(5 . "26")
  387.            '(100 . "AcDbEntity")
  388.            '(67 . 0)
  389.            '(8 . "构件编号")    ;图层名称
  390.            '(100 . "AcDbText")
  391.            '(10 -1.08 -1.75 0.0) ;文字起点
  392.            (CONS 40 (+ CIRRAD 1.0)) ;文字高度
  393.            (CONS 1 TEXT)    ;默认值
  394.            '(50 . 0)        ;文字旋转
  395.            '(41 . 0.7)        ;相对X比例系数
  396.            '(51 . 0.0)        ;倾斜角度
  397.            '(7 . "NUM_STYLE")    ;文字字型
  398.            '(71 . 0)        ;文字产生的标志
  399.            '(72 . 1)        ;水平文字的对齐类型
  400.            '(11 0.0 0.0 0.0)    ;对齐点，只有在72与74非0才有意义
  401.            '(210 0.0 0.0 1.0)    ;挤出方向
  402.            '(100 . "AcDbAttribute")
  403.            (CONS 2 TEXT)    ;卷标字符串
  404.            '(70 . 0)        ;属性标志
  405.            '(73 . 0)        ;字段长度
  406.            '(74 . 2)        ;垂直文字的对齐类型
  407.            )
  408.          )
  409.     (ENTMAKE '((0 . "SEQEND")))
  410.     (PRINC)
  411.     )

点评

puzb2001
谢谢分享！  发表于 2012-3-14 20:43

评分

参与人数 2明经币 +3 金钱 +20 贡献 +5 激情 +5 收起 理由
断箭 + 1 很给力!
mccad + 2 + 20 + 5 + 5 【精华】好程序

查看全部评分

回复

使用道具 举报

LinBinFen
发表于 2024-4-26 10:55:42 | 显示全部楼层
18年前的程序效果很好，多谢分享!
回复 支持 反对

使用道具 举报

mojianxing
发表于 2024-1-9 14:00:18 | 显示全部楼层
效果很好的程序，多谢分享
回复 支持 反对

使用道具 举报

sunny_8848
发表于 2020-6-14 18:47:36 | 显示全部楼层
效果很好的程序，多谢分享
回复 支持 反对

使用道具 举报

rongyifei
发表于 2006-11-10 22:44:00 | 显示全部楼层
程序文件是不是没有格式化,看起来很乱!
回复 支持 反对

使用道具 举报

Dallas_whu
 楼主| 发表于 2006-11-10 22:47:00 | 显示全部楼层
我不知道怎么帖源码？有没有版主帮帮忙？
回复 支持 反对

使用道具 举报

xshrimp
发表于 2006-11-11 00:38:00 | 显示全部楼层
例如
  3. ;程序主程序
  4. (defun c:xxx()sddd)
代码前加

本帖子中包含更多资源

您需要 登录 才可以下载或查看，没有账号？注册

x
回复 支持 反对

使用道具 举报

Dallas_whu
 楼主| 发表于 2006-11-11 08:43:00 | 显示全部楼层
我加上[code]就变成一片混乱了，不知道是不是行数太多了？另外我传得附件不知到哪里去了？
回复 支持 反对

使用道具 举报

rongyifei
发表于 2006-11-11 20:22:00 | 显示全部楼层
程序很长,看来够学习阵子了,楼主辛苦了!
回复 支持 反对

使用道具 举报

ctclsc
发表于 2006-11-14 12:51:00 | 显示全部楼层
能不能让直线和圆、数字成为一体，并且在拖动直线端点时，使直线始终通过圆心（好像是通过反应器），谢谢。。。
回复 支持 反对

使用道具 举报

Dallas_whu
 楼主| 发表于 2006-11-14 22:04:00 | 显示全部楼层
呵呵，反应器这玩意儿还不会玩！
回复 支持 反对

使用道具 举报

killer9806
发表于 2006-11-16 23:04:00 | 显示全部楼层
感谢楼主提供。
回复 支持 反对

使用道具 举报

jxphklibin
发表于 2010-7-16 04:09:00 | 显示全部楼层
呵呵，旧贴子了
回复 支持 反对

使用道具 举报

1234下一页
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|CAD论坛|CAD教程|CAD下载|联系我们|关于明经|明经通道 ( 粤ICP备05003914号 )  
©2000-2023 明经通道 版权所有 本站代码，在未取得本站及作者授权的情况下，不得用于商业用途

GMT+8, 2024-11-25 19:27 , Processed in 0.230945 second(s), 28 queries , Gzip On.

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表