[求助][0107]如何参照替换表格栏位资料?

vken7az2p · 发表于 2007-1-7 19:28

如何用LISP程序完成下面过程
01.取得文字资料内容,这方法我知道,但下面的02.及03.我就不清楚了.
02.点选表格栏位内要替换的资料位置
03.替换表格资料

烦请各位高手可以解答一下
谢谢

vken7az2p · 发表于 2007-1-8 06:59

在別處問到了答案轉貼回來給各位看看還可以怎樣改進

(defun C:xtb (/ adoc column pt pvec row tbobj txobj txt)

(vl-load-com)
(setq adoc (vla-get-activedocument
       (vlax-get-acad-object)
     )
)
(vla-startundomark adoc)
(setq txobj (vlax-ename->vla-object
(car (entsel "\n選取文字"))
      )
txt   (vlax-get txobj 'TextString)
)
(setq tbobj
(vlax-ename->vla-object
   (car (entsel "\n選取表格"))
)
)
(setq pt   (trans (getpoint "\n點選交換文字表格位置") 1 0)
pvec (getvar "VIEWDIR")
)
(vla-hittest
    tbobj
    (vlax-3d-point pt)
    (vlax-3d-point pvec)
    'row
    'column
)
(vla-settext tbobj row column txt)
(vla-endundomark adoc)
(princ)
)

龙龙仔 · 发表于 2007-1-9 11:52

;;BY LUCAS
;;最好能把選表格省略掉!
;;http://bbs.mjtd.com/forum.php?mod=viewthread&tid=44719&replyID=&skin=1
;;注意:要先把指令做成按鈕,要先選好單一儲存格,再點按鈕執行指令!!
(defun C:XTB_LAI1 (/ ADOC DATA TXOBJ TXT)
(setq ADOC (vla-get-activedocument
(vlax-get-acad-object)
)
)
(vla-startundomark ADOC)
(if (and (setq DATA (SELECT_TABLE))
(setq TXOBJ (car (entsel "\n選取文字: ")))
)
(progn
(setq TXOBJ (vlax-ename->vla-object TXOBJ))
(setq TXT (vlax-get TXOBJ 'TEXTSTRING))
(vla-settext (car DATA) (nth 1 DATA) (nth 3 DATA) TXT)
)
)
(vla-endundomark ADOC)
(vlax-release-object ADOC)
(princ)
)
(defun SELECT_TABLE (/ TABLE ROWMIN ROWMAX COLMIN COLMAX SS N)
(setq N 0)
(if (setq SS (ssget "X" '((0 . "ACAD_TABLE"))))
(repeat (sslength SS)
(if (not (vl-catch-all-apply
'vla-getsubselection
(list (vlax-ename->vla-object
(ssname SS N)
)
'ROWMIN
'ROWMAX
'COLMIN
'COLMAX
)
)
)
(setq TABLE (vlax-ename->vla-object
(ssname SS N)
)
)
)
(setq N (1+ N))
)
)
(if ROWMIN
(list TABLE ROWMIN ROWMAX COLMIN COLMAX)
NIL
)
)
(princ)

;;BY LUCAS
;;最好能把選表格省略掉!
;;http://bbs.mjtd.com/forum.php?mod=viewthread&tid=44719&replyID=&skin=1
;;注意:要先把指令做成按鈕,要先選好單一儲存格,再點按鈕執行指令!!
(defun C:XTB_LAI1 (/ ADOC DATA TXOBJ TXT)
  (setq ADOC (vla-get-activedocument
        (vlax-get-acad-object)
      )
  )
  (vla-startundomark ADOC)
  (if (and (setq DATA (SELECT_TABLE))
    (setq TXOBJ (car (entsel "\n選取文字: ")))
      )
    (progn
      (setq TXOBJ (vlax-ename->vla-object TXOBJ))
      (setq TXT (vlax-get TXOBJ 'TEXTSTRING))
      (vla-settext (car DATA) (nth 1 DATA) (nth 3 DATA) TXT)
    )
  )
  (vla-endundomark ADOC)
  (vlax-release-object ADOC)
  (princ)
)
(defun SELECT_TABLE (/ TABLE ROWMIN ROWMAX COLMIN COLMAX SS N)
  (setq N 0)
  (if (setq SS (ssget "X" '((0 . "ACAD_TABLE"))))
    (repeat (sslength SS)
      (if (not (vl-catch-all-apply
   'vla-getsubselection
   (list (vlax-ename->vla-object
    (ssname SS N)
         )
         'ROWMIN
         'ROWMAX
         'COLMIN
         'COLMAX
   )
        )
   )
 (setq TABLE (vlax-ename->vla-object
        (ssname SS N)
      )
 )
      )
      (setq N (1+ N))
    )
  )
  (if ROWMIN
    (list TABLE ROWMIN ROWMAX COLMIN COLMAX)
    NIL
  )
)
(princ)

vken7az2p · 发表于 2007-1-9 19:59

请问版主您的SELECT_TABLE 这函数主要作用是什么

他返回的值是代表什么呢

希望版主可以解答一下

谢谢

龙龙仔 · 发表于 2007-1-10 12:27

;;注意:要先把指令做成按鈕,要先選好範圍儲存格,再點按鈕執行指令!!
SELECT_TABLE这函数主要作用是返回你可選取儲存格範圍

返回值---寫得很清楚了

(list TABLE ROWMIN ROWMAX COLMIN COLMAX)

mmmmmm · 发表于 2007-1-10 16:45

load "ACDBTABLEPACK.VLX" before calling XTB

(defun C:xtb (/ adoc column pt pvec row tbobj txobj txt abc)
(vl-load-com)
(setq adoc (vla-get-activedocument
        (vlax-get-acad-object)
      )
)
(vla-startundomark adoc)
(if (and (setq txobj (entsel "\n Pick annotation <Exit>:"))
    (setq txobj (vlax-ename->vla-object (car txobj))
   txt   (vlax-get txobj 'TextString)
    )
    (setq abc (getpoint "\n Pick a point in AcDbTable cell <Exit>:"))
    (setq abc (tblpack-pickcell abc nil nil))
    (setq tbobj (car abc)
   row (nth 1 abc)
   column (nth 2 abc)
    )
      )
    (vla-settext tbobj row column txt)
)
(vla-endundomark adoc)
(princ)
)

龙龙仔 · 发表于 2007-1-11 12:41

本帖最后由作者于 2007-1-11 13:23:09 编辑

有空我也仿一個一樣的[tblpack-pickcell]函數

目前我用selectcell函數

load "selectcell.VLX" before calling Xtb_lai

;;BY LUCAS
;;最好能把選表格省略掉!
(defun C:XTB_LAI (/ ADOC DATA PT TXOBJ TXT)
(vl-load-com)
(setq ADOC (vla-get-activedocument
        (vlax-get-acad-object)
      )
)
(vla-startundomark ADOC)
(prompt "\n選取文字")
(if (and (setq TXOBJ (ssget "+.:E:S" '((0 . "*TEXT"))))
    (setq PT (getpoint "\n點選放置文字儲存格: "))
    (setq PT (trans PT 1 0))
    (setq DATA (SELECTCELL PT))
    ;;SELECTCELL函數傳回值list TABLE ROW COL)
      )
    (progn
      (setq TXOBJ (vlax-ename->vla-object (ssname TXOBJ 0)))
      (setq TXT (vlax-get TXOBJ 'TEXTSTRING))
      (vla-settext (car DATA) (cadr DATA) (last DATA) TXT)
    )
)
(vla-endundomark ADOC)
(vlax-release-object ADOC)
(princ)
)

龙龙仔 · 发表于 2007-1-12 08:13

6樓函數有欠函數

指令: xtb

ick annotation <Exit>:
ick a point in AcDbTable cell <Exit>:*取消*
Program ERROR: 0 no function definition: VLOBJ-GET-VLA-OBJECT
Resetting...; 錯誤: *錯誤* 功能內部已發生一個錯誤無函數定義: #ERROR

vken7az2p · 发表于 2007-1-13 23:48

请问版主

看您这样的描述

(setq PT (getpoint "\n点选放置文字储存格: "))

就可以带入表格物件,那是怎样才选到物件呢

可以解答一下吗

谢谢

vken7az2p · 发表于 2007-1-14 12:51

(nentselp PT)是不是要用這命令呢

账号		自动登录	找回密码
密码			注册

[求助][0107]如何参照替换表格栏位资料?

本帖被以下淘专辑推荐:

本帖子中包含更多资源