请问龙大侠，怎么修改才能将这个循环选择程序返回的点表每个子表内的坐标值改成

hlzhong

请问龙大侠，怎么修改才能将这个循环选择程序返回的点表每个子表内的坐标值全部改成小数点后只含3位有效数字的小数呢？如某一坐标值为20。0 该为20。000  如为-2.13163e-014，则能将它近似为0。000   如果是整型的，也一并改成**.***的形式。

(defun C:TT (/ SS SS1 N N1 NN ENT CHECK TMP PT_LIST)
  (defun DO_IT (TMP)
    (if
      (and
(not (equal (car TMP) (cadr TMP)))
(= (vl-position TMP PT_LIST) NIL)
(= (vl-position (list (cadr TMP) (car TMP)) PT_LIST) NIL)
      )
       (setq PT_LIST (append PT_LIST (list TMP)))
    )
  )

  (defun DO_IT1 (ENT / TMP)
    (setq TMP (list (cdr (assoc 10 ENT))
    (cdr (assoc 11 ENT))
      )
    )
    (DO_IT TMP)
  )

  (setq SS (ssget '((0 . "polyline,line,lwpolyline,3dface,region"))))
  (setq PT_LIST '())
  (setq N 0)
  (repeat (sslength SS)
    (setq ENT (ssname SS N))
    (setq CHECK (cdr (assoc 100 (reverse (entget ENT)))))
    (cond
      ((or (= CHECK "AcDbPolygonMesh") (= CHECK "AcDbFace"))
       (if (= CHECK "AcDbPolygonMesh")
(progn
   (command "_.COPY" ENT "" "0,0" "@")
   (command "_.EXPLODE" (entlast))
   (setq SS1 (ssget ""))
)
(progn (setq SS1 (ssadd)) (ssadd ENT SS1))
       )
       (setq N1 0)
       (repeat (sslength SS1)
(setq ENT (entget (ssname SS1 N1)))
(setq NN 0)
(setq LINE0 (list (cdr (assoc 10 ENT))
   (cdr (assoc 11 ENT))
     )
       LINE1 (list (cdr (assoc 11 ENT))
   (cdr (assoc 12 ENT))
     )
       LINE2 (list (cdr (assoc 12 ENT))
   (cdr (assoc 13 ENT))
     )
       LINE3 (list (cdr (assoc 13 ENT))
   (cdr (assoc 10 ENT))
     )
)
(repeat 4
   (setq TMP (eval (read (strcat "LINE" (rtos NN)))))
   (DO_IT TMP)
   (setq NN (1+ NN))
)
(setq N1 (1+ N1))
       )
       (command "_.ERASE" SS1 "")
      )
      ((or (= CHECK "AcDb3dPolyline")
   (= CHECK "AcDb2dPolyline")
   (= CHECK "AcDbPolyline")
   (= CHECK "AcDbModelerGeometry")
       )
       (command "_.COPY" ENT "" "0,0" "@")
       (command "_.EXPLODE" (entlast))
       (setq SS1 (ssget ""))
       (setq N1 0)
       (repeat (sslength SS1)
(setq ENT (ssname SS1 N1))
(DO_IT1 (entget ENT))
(setq N1 (1+ N1))
       )
       (command "_.ERASE" SS1 "")
      )
      (t
       (DO_IT1 (entget ENT))
      )
    )
    (setq N (1+ N))
   
  (princ "\n")
    )
)

wangzhe3972

（setq a 2.1234567)(setq a (rtos a 2 3))(setq a (atof a))

龙龙仔

;;改成小数点后只含3位有效数字那容易,但0.0改为0.000那不行(字符串才可以)
(defun CH_PT_2 (PT_LIST / HOLDZIN)
  (setq HOLDZIN (getvar "dimzin"))
  (setvar "dimzin" 0)
  (setq        PT_LIST        (mapcar
                  '(lambda (X)
                     (list
                       (mapcar
                         '(lambda (Y)
                            (atof (rtos Y 2 3))
                          )
                         (car X)
                       )
                       (mapcar
                         '(lambda (Y)
                            (atof (rtos Y 2 3))
                          )
                         (cadr X)
                       )
                     )
                   )
                  PT_LIST
                )
  )
  (setvar "dimzin" HOLDZIN)
  PT_LIST
)


;;改为字符串
(defun CH_PT_3 (PT_LIST / HOLDZIN)
  (setq HOLDZIN (getvar "dimzin"))
  (setvar "dimzin" 0)
  (setq        PT_LIST        (mapcar
                  '(lambda (X)
                     (list
                       (mapcar
                         '(lambda (Y)
                            (rtos Y 2 3)
                          )
                         (car X)
                       )
                       (mapcar
                         '(lambda (Y)
                            (rtos Y 2 3)
                          )
                         (cadr X)
                       )
                     )
                   )
                  PT_LIST
                )
  )
  (setvar "dimzin" HOLDZIN)
  PT_LIST
)

hlzhong

还有一个问题：你以前有没有碰到过：“在lisp程序计算时由于一个公式中含有不同的数据类型（有的是整型，有的是实型）而导致程序运行不稳（有时可以，有时出错）？”

龙龙仔

shicai

hlzhong

龙大侠，“没查清楚”是什么意思？我就是怕一个公式中数据类型混杂导致程序不稳，所以才想。。[br]龙大侠，“没查清楚”是什么意思？我就是怕一个公式中各种数据类型混杂导致程序不稳，所以才想将其全部转换成 “小数点后含3位有效数字”的实型数，不知这样效果会否好点？

aeo000000

(float int)

龙龙仔

jiang__jin

学习了，经常遇见