[讨论]批量处理一批图形是否要用脚本？

碎玉す全瓦

如题，如果想要批量处理图形的话，普通的lsp能做到吗？

还有一事不明，如果用脚本的话，脚本是一个什么样的概念呢？是不是也像lsp一样编代码，最后保存成scr就可以执行呢？请主手明示，谢谢。

ZZXXQQ

LISP可以做到。编程序思路：

1、程序在新图中运行；

2、程序开始设UNDO开始点；

3、插入要处理的图形；

4、对图形处理；

5、将处理后的图样另存成你想要的文件（可以与插入文件同名）；

6、设UNDO结束点；

7、UNDO；

8、从第2步开始新循环。

脚本文件就是ACAD的命令序列，也可以包含LISP代码。

碎玉す全瓦

谢谢，我明白了。只是对于脚本还是一直迷茫中。

byghbcx

用lisp打开图形，处理图形，关闭图形可以做到的．只是在ＭＤＩ下全部要用Activex方法运行。

cindy_fisher

byghbcx 发表于 2007-3-19 09:46
用lisp打开图形，处理图形，关闭图形可以做到的．只是在ＭＤＩ下全部要用Activex方法运行。

您好，

能不能给个手上有个lisp，能打开图形，处理图形，关闭图形。
最近我自己写好了一个别的lisp，100张图纸都要运行这个lisp，我要一张张打开，然后运行，在command.如果不用手动打开，运行，程序自己一次处理就好了，谢谢。

yutuo404

;给你个示例代码，不开图批量设置文件夹下dwg字体并清理
(defun c:puall( / cadobj file ob path vercad i styob styname docobj styles styhz txtob)
    (vl-load-com)
    ;出错处理
    (defun *error* (msg)
        (if (= nil cadobj)
            (princ "\n您已取消操作！")
            (progn
                (Vlax-Invoke-Method cadobj 'Quit)
                (princ "\n您已取消操作！")
            )
        )
        (princ)
    )
    (setq file nil)
    (setq path (strcat (qf_getFolder "请选取要清理的文件所在目录") "\\"))
    (setq cadobj (vlax-create-object "AUTOCAD.Application"))
    (setq n 0)
    (foreach file (vl-directory-files path "*.dwg" 1)
        (setq docobj (vla-open (vla-get-documents cadobj) (strcat path file)))
        (setq styles (Vlax-Get-property docobj 'textstyles))
        (setq styhz (vlax-invoke-method styles 'add "HZ"))
        (vlax-put-property styhz 'bigfontfile "hztxt.shx")
        (vlax-put-property styhz 'fontfile "simplexs.shx")
        (vlax-put-property styhz 'width 0.7)
        (Vlax-Put-Property docobj 'ActiveTextStyle styhz)
        (vlax-for txtob (Vlax-Get docobj 'ModelSpace)
            (cond
                ((= "AcDbText" (Vlax-Get txtob 'ObjectName ))(vlax-put-property txtob 'stylename "HZ"))
                ((= "AcDbMText" (Vlax-Get txtob 'ObjectName ))(vlax-put-property txtob 'stylename "HZ"))
            )
        )
        (vla-purgeall docobj)
        (prompt (strcat "\n" file " 已设置字体HZ，并清理完成"))
        (Vlax-Invoke-Method docobj 'SaveAs (strcat path file))
        (setq n (+ 1 n))
    )
    (Vlax-Invoke-Method cadobj 'Quit)
    (alert (strcat "共清理" (itoa n) "张图纸\n请逐一检查"))
    (princ)
)
;-----------------------------------------START-----------------------------
    ;取得目录
    (defun qf_getFolder (msg / WinShell shFolder path catchit)
      (vl-load-com)
      (setq winshell (vlax-create-object "Shell.Application"))
      (setq shFolder (vlax-invoke-method WinShell 'BrowseForFolder 0 msg 1))
      (setq
        catchit (vl-catch-all-apply
          '(lambda () (setq shFolder (vlax-get-property shFolder 'self)) (setq path (vlax-get-property shFolder 'path))
        )
        )
      )
      (if (vl-catch-all-error-p catchit)
        nil
        path
      )
    )
;------------------------------------------OVER-----------------------------

(princ "\n调用命令：puall  用前请备份，用后请核对")
(princ)

fanpaulm

这都能做到啊!

zhangcan0515

学习了一下最近在研究批量问题

my0314cn

请问可以不开图打印吗