怎么entmake出来一条轻便多义线(lwpolyline),

Taoyimaier

我用如下list来entmake一个lwpolyline,可是不能成功,为什么...

2. (setq the_lst (list (cons 0   "LWPOLYLINE")(cons 70 0)(cons 67 0)(cons 90  4)   (cons 43  0.0) (cons 38  0.0) (cons 39  0.0)(cons 10 (list 0 0))(cons 40 0)(cons 41 0)(cons 42 0)(cons 10 (list -1 -1))(cons 40 0)(cons 41 0)(cons 42 0)(list 210 0.0 0.0 1.0))
3. )
4. (entmake the_lst)

(setq the_lst (list (cons 0   "LWPOLYLINE")(cons 70 0)(cons 67 0)(cons 90  4)   (cons 43  0.0) (cons 38  0.0) (cons 39  0.0)(cons 10 (list 0 0))(cons 40 0)(cons 41 0)(cons 42 0)(cons 10 (list -1 -1))(cons 40 0)(cons 41 0)(cons 42 0)(list 210 0.0 0.0 1.0)) ) (entmake the_lst)

就将组码都写得那么细致了,还不能在cad中生成一条lwpolyline,是什么回事啊,请高手解答
或者请您用entmake这个函数生成一个很简单的lwpolyline也行,只要您将代码贴出来
谢谢

hnfsf

(defun #m_lpl# (d70 plw pla pl_list lay lty color / pb)
  (setq d90 (length pl_list)
 pb '()
  )
  (foreach x pl_list
    (progn
      (setq pb (append
   pb
   (list (cons 10 x)
   (cons 40 plw)
   (cons 41 plw)
   (cons 42 pla)
   )
        )
      )
    )
  )
  (setq en000 (append
  (list (cons 0 "LWPOLYLINE") (cons 100 "AcDbEntity")
        (cons 8 lay) (cons 100 "AcDbPolyline")
        (cons 90 d90) (cons 70 d70)
  )
  pb
       )
  )
  (if (/= -1 color) (setq en000 (append en000 (list (cons 62 color)))))
  (if (/= -1 lty)(setq en000 (append en000 (list (cons 6 lty)))))
  (if (= nil (entmake en000))
      (princ "\n LWPL 制造失败.")
  )
)

Taoyimaier

谢谢,我做出来了,有这几个组码是必须要的,

((0 . "lwpolyline")(100 . "acdbentity")(100 . "acdbpolyline")(90 . 定点数)(10 1 1)(10 2 2))

为什么lwpolyline需要这两个100的组码,而entmake circle却不要100这个组码呢,有没有什么原因的

谢谢hnfsf的解答!