求助：(autolisp)两条线段相交，已知其中一条线段的两点，如何求出另一条线段的两点

走路

求助：(autolisp)两条线段相交，已知其中一条线段的两点，如何求出另一条线段的两点？[br]

陈伯雄

mccad

(defun I:EntSelF
(Msg                 ; selection prompt
  Filter              ; filter list
  /
  EntN                ; (entsel) list, or "Exit" string
  pbDist              ; pickbox size in drawing units
  PtPick              ; point of selection from (entsel)
  ssPick              ; selection set
) ;_ closes variable declare
(while (not EntN)    ; while no selection (or no exit)
  (setq
   EntN (if Msg                 ; if selection prompt
         (entsel Msg)           ; then (entsel) w/prompt

         (entsel)               ; else plain (entsel)
        ) ;_ closes if
  ) ;_ closes setq
  (if (= (getvar "ErrNo") 52)   ; if null response
   (setq EntN "Exit")           ; then set flag to exit
  ) ;_ closes if
) ;_ closes while
(cond
  ((/= EntN "Exit")             ; if not exit
   (setq
    pbDist (abs                 ; return absolute number
            (/
             (*
              (/                ; get pixel ratio
               (getvar "ickBox")
               (cadr (getvar "ScreenSize"))
              )
              (getvar "ViewSize") ; apply to viewsize
             ) ;_ closes *
            (sin (* 0.25 pi))   ; at 45?
            ) ;_ closes /
           ) ;_ closes abs
    PtPick (cadr EntN)          ; get point of pick
   ) ;_ closes setq
   (if (setq ssPick (ssget "_C" ; if entities in crossing
                     (polar PtPick (* 1.25 pi) pbDist)
                     (polar PtPick (* 0.25 pi) pbDist)
                     Filter     ; match filter, if any
                   ) ;_ closes ssget
       ) ;_ closes setq
    (cons            ; then return first entity as (entsel)
     (ssname ssPick 0) (list PtPick)
    ) ;_ closes cons
   ) ;_ closes if
  ) ;_ closes condition
) ;_ closes cond
) ;_ closes defun I:EntSelF
(defun c:getline(/ filne flineent spntfl epntfl sliness sel_num count slineent spntsl epntsl)
  (setq fline(I:EntSelF "选择直线: " '((0 . "line"))) )
  (setq flineent(entget (car fline)))
  (setq spntfl(cdr (assoc 10 flineent)))
  (setq epntfl(cdr (assoc 11 flineent)))
  (entdel (car fline))
  
  (setq sliness(ssget "f" (list spntfl epntfl) '((0 . "line"))))
  (if (not sliness)
        (progn
            (princ "\n没有直线与选定的直线相交")
        )
        (progn
          (setq sel_num (sslength sliness))
          (princ (strcat "\n有" (itoa sel_num) "条直线与选定的直线相交,以下为交点的列表："))
          (setq count 0)
          (repeat sel_num
            (setq slineent(entget (ssname sliness count)))
            (setq spntsl(cdr(assoc 10 slineent)))
            (setq epntsl(cdr(assoc 11 slineent)))
            (princ (strcat "\n第" (itoa(+ count 1)) "条直线的起点坐标为("))
            (princ spntsl)
            (princ "),终点坐标为(")
            (princ epntsl)
            (princ ")")
            (setq count (+ count 1))
            )
          )
    )
  (entdel (car fline))
  )

lccad

假设P0、P1为已知线段的端点
(setq sa (ssget "C" p0 p1 '((0 . "LINE"))))
(if (and (/= sa nil) (= (sslength sa) 1))
  (setq
     d0 (cdr (assoc '10 (entget (ssname sa 0))))
     d1 (cdr (assoc '11 (entget (ssname sa 0))))
  )
)
d0、d1即为与其相交线段的端点

南子

mccad

lcad

废话，他的前提不就是已知“两条线段相交”了嘛!

mccad

lcad

简单的方法之补充:
假设P0、P1为已知线段的端点
(setq sa (ssget "C" p0 p1 '((0 . "LINE"))))
(if (= sa nil)
  (alert "没有线段与已知线段相交！")
  (progn
    (setq i 0)
    (setq test T)
    (while (< i (sslength sa))
      (setq
        d0 (cdr (assoc '10 (entget (ssname sa i))))
        d1 (cdr (assoc '11 (entget (ssname sa i))))
      )
      (if (inters p0 p1 d0 d1)
        (progn
         (princ "\n与之相交的第")
         (princ (+ i 1))
         (princ "条线段端点为:")
         (princ d0)
         (princ d1)
         (setq test nil)
        )
      )
      (setq i (+ i 1))
    )
    (if test (alert "没有线段与已知线段相交！"))
  )
)

陈伯雄