[求助]怎么得到多义线各顶点相对应的水平线的各点

cq_qg

<h2>有一条多义线，在其上方或下方有一水平线，怎么能得到多义线各顶点相对应的水平线上的点，即沿各顶点垂直向上或向下与水平线的交点？lisp里面怎么实现？</h2>

i-Stone

用SSGET加点选如何?

无痕

取多义线顶点，分别求顶点到水平线的最近点

用ｖｌａｘ－ｃｕｒｖｅ－ｇｅｔｃｌｏｓｅｓｔｐｏｉｎｔｔｏ　

highflybir

如果不用vl函数也可以这样。

(defun c:test(/ pline pllst hline hllst p1 p2 a1 a2 p3 pt lst)
  (if (and (setq pline (car (entsel "\n请选取多段线：")))
    (setq pllst (entget pline))
    (= (cdr (assoc 0 pllst)) "LWPOLYLINE")
    (setq Hline (car (entsel "\n请选取水平线：")))
    (setq hllst (entget hline))
    (= (cdr (assoc 0 hllst)) "LINE")
      )
    (progn
      (setq p1 (cdr (assoc 10 hllst)))
      (setq p2 (cdr (assoc 11 hllst)))
      (setq A1 (angle p1 p2))
      (setq a2 (+ (/ pi 2) a1))
      (foreach pp pllst
 (if (= (car pp) 10)
   (progn
     (setq p3 (polar (cdr pp) a2 1))
     (setq pt (inters p1 p2 (cdr pp) p3 nil))
     (setq lst (cons pt lst))
     (entmake
       (list
         (cons 0 "POINT")
         (cons 10 pt)
       )
            )
   )
 )
      )
      (reverse lst)
    )
  )
)  
    

或者用trans函数-〉坐标变换的形式，我不知道哪一种更快，只有你自己去试验了。

cq_qg

谢谢，这是我原来程序的代码，我想要标注多义线各顶点到水平线的距离。

程序功能是可以完成，但是各标注的尺寸线的一个起点都是到水平线的一个端点。另一个是在顶点处。这样不太好，我想标注的尺寸界线原点与尺寸线位置重合，这样不会都以水平线为端点为起点。

可能说得不是很清楚，执行一下我得程序代码就知道了。

(defun c:tt (/ D I LEAME P10 PLEAME PLST)
  (defun get_pt    (ename / elist ptlist)
    (setq elist (entget ename))
    (foreach n elist
      (if (= 10 (car n))
    (setq ptlist (cons (cdr n) ptlist))
      )
    )
    (reverse ptlist)
  )
  (if (and (setq pleame (car (entsel "\n>>>选择多段线<退出>:")))
       (setq leame (car (entsel "\n>>>选择水平线<退出>:")))
       ;(setq d (getdist "\n>>>输入标注间隔<退出>:"))
       (setq plst (get_pt pleame))
       (setq p10 (cdr (assoc 10 (entget leame))))
       (setq i 0)
      )
    (repeat (length plst)
      (command ".DIMLINEAR"
           (nth i plst)
           p10
           "v"
           (nth i plst) 
           ;(polar p10 pi (* (+ i 1) d))
      )
      (setq i (1+ i))
    )
    (princ "\n>>>安全退出!<<<")
  )
  (princ "\n>>>程序执行完毕!<<<")
  (princ)
)

无痕

ｒｅｐｅａｔ处改为:

(repeat (length plst)
      (command ".DIMLINEAR"
           (nth i plst)
        "per"
           p10
           "v"
           (nth i plst) 
      )
      (setq i (1+ i))
    )

是这个意思？

highflybir

我运行了你的程序，发现你说的问题完全可以不用编程就能实现。

cq_qg

就是无痕斑竹的意思。这么简单怎么没想到呢。

呵呵，不编程是可以实现，但是好多各一个个标注好累的。

现在可以了。谢谢两位斑竹的帮助。