如何判定一个单行文本是实数或整数？

高级用户

实数或整数 返回 t

其他           返回 nil

有这样的函数吗?

xgr

 用TYPE函数。

    (setq a 123 r 3.45 s "Hello! " x '(a b c))

    (setq f (open "name" "r"))

    (type 'a)           返回          SYM

    (type a)            返回          INT

    (type f)            返回          FILE    

    (type r)            返回          REAL

    (type s)            返回          STR

    (type x)            返回          LIST

    (type +)            返回         SUBR

    (type nil)          返回          nil

　

  (defun isint (a)

(if (= (type a) 'INT)   (是整型数形态吗? )

    T                   (是, 返回 T)

    Nil                 (否, 返回 nil)

    )

    )     

(if (= (type a) 'INT)   (是整型数形态吗? )

    T                   (是, 返回 T)

    Nil                 (否, 返回 nil)

    )

    )     

caoyin

(defun Text_NumberP (txt)
  (numberp (read (cdr (assoc 1 (entget txt)))))
)

;;test

(Text_NumberP (car(entsel "\n选择单行文字: ")))

高级用户

caoyin发表于2007-11-22 15:21:00(defun Text_NumberP (txt)  (numberp (read (cdr (assoc 1 (entget txt))))));;test(Text_NumberP (car(entsel \"\n选择单行文字: \")))

有两个问题：

1.  如果是一行文本就一个小数点，怎么出错了

     选择单行文字: ; 错误: 输入中的点位置不正确

2.  如果有空格，像"123   456"、"123    abc" 也会返回t，但像这样的应该返回nil才对

caoyin

(defun Text_NumberP (txt / lst)
  (setq lst (vl-string->list (cdr (assoc 1 (entget txt)))))
  (and (apply 'and (mapcar '(lambda (x)
                                             (member x '(46 48 49 50 51 52 53 54 55 56 57))
                                           )
                                          lst
                             )
          )
          (/= (car lst) 46)
  )
)

;;test
(Text_NumberP (car(entsel "\n选择单行文字: ")))

高级用户

vl-string->list 转乘字符代码逐一判断，学习了

第三行很深奥，没看明白

xbkxbk

;;;简单判断字符型x值是整数,还是实数;

(setq x "333.73aa")
;(setq x ".3355")
;(setq x "564")
;x中不能以0-9或.以外的字符开头,否则判断都是整数!
;;;;程式开始;;;;;
(setq y (atof x))  ;转成实数型 ==> y=333.73
(setq z (atoi x))  ;转成整数值 ==> z=333
(if (> (- y z) 0)
    (princ "\n实数")
    (princ "\n整数")
)

caoyin

楼上的方法好像有点问题
(setq x "333.0") 判断也是整数吗

;;根据AutoCAD的某些逻辑，重新写了一个

;; ▓ (l:str-numberP str)
;; [功能] 判断字符串 str 是否是数字
;; [返回] 整数则返回整数，实数则返回实数。其他->nil
;; [测试] (l:str-NumberP ".1")->0.1
;;        (l:str-NumberP " .1")->0.1
;;        (l:str-NumberP "0 .1")->nil
;;        (l:str-NumberP "0.1")->0.1
;;        (l:str-NumberP "1")->1
;;        (l:str-NumberP "1.")->1.0
(defun l:str-NumberP (str / num)
  (if (numberp (vl-catch-all-apply 'angtof (list str)))
    (progn
      (setq num (vl-catch-all-apply 'read (list str)))
      (if (vl-catch-all-error-p num)
        (atof str)
        num
      )
    )
  )
)

xbkxbk

  强..考虑周到...学习.....