[原创][转帖]难倒所有高手的难题

xing979020 · 发表于 2008-1-21 19:24

图形属性是与图形文件相关的信息，如标题、作者、主题以及自定义属性等。使用图形属性命令可显示和设置当前图形文件的属性信息，该命令的调用方式为：
菜单：【File（文件）】→【DrawingProperties…（图形属性）】
命令行：dwgprops
调用该命令后，AutoCAD将显示“Properties（属性）”对话框，该对话框有4个选项卡，现分别介绍如下：
(1)“General（基本）”选项卡：用于显示文件类型、位置、大小、时间和属性等与磁盘文件有关的信息，其显示数据来自操作系统，如图16-3所示。

(2)“Summary（概要）”选项卡：用于设置图形标题、主题、作者、关键字、注释和超级链接基地址（如图16-4所示）。其中超级链接基地址是指插入图形中的所有相关链接的基地址。
(3)“Statistics（统计信息）”选项卡：用于显示文件创建时间、最后修改时间、最后编辑者、修订次数和总编辑时间等信息（如图16-5所示）。这些文件特性是自动维护的，并可利用它们来查找在一个指定的时期内创建或修改的图形。
(4)“Custom（自定义）”选项卡：用于指定最多10个自定义属性，每个属性包括名称和值两部分（如图16-6所示）。使用自定义属性可以在搜索时便于查找图形。
注意只有在保存图形之后，“图形属性”对话框中输入的属性才能与图形相关联。

现在我想问:能不能用visual lisp编程来实现对自定义信息的写入与修改.

如果可以的话.能不能提供个大概.比如可以用什么函数来现实!

谢谢!如我能完成一定会把原码贴上.供大家参习.

caoyin · 发表于 2008-1-22 08:53

本帖最后由 caoyin 于 2012-7-21 02:20 编辑

这样的帖子标题就是要源码吗？

;;; ┏━━━┳━━━━━━━━━━━━━━━━━━━┓
;;; ┃ T: ┃ 图形属性信息操作 ┃
;;; ┗━━━┻━━━━━━━━━━━━━━━━━━━┛
;;; 以下函数参考命令 DWGPROPS 。(vl-load-com)
(setq doc (vla-get-activedocument (vlax-get-acad-object)))
;;_________________________________________________________________________________________
;; ▓ (lt:info-summary-get)
;; [功能] 获取图形属性“概要”信息
;; [返回] 表。表元素内容依次为标题、主题、作者、关键字、注释和超链接地址
(defun lt:info-summary-get (/ sInfo)
(setq sInfo (vla-get-SummaryInfo doc))
(mapcar '(lambda (x) (vlax-get sinfo X))
'(Title Subject author Keywords Comments HyperlinkBase)
)
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-summary-set <值列表>)
;; [功能] 设置图形属性“概要”信息
;; [参数] sumlst---值列表。表中的值依次赋给关键字标题、主题、作者、关键字、注释和超链接地址
;; 若值为 nil 时，则不修改。为 "" 时清除原有值。其中注释的换行符为 "\r\n"。
;; [返回] 修改后的值列表。
;; [测试] (lt:info-summary-set '("朗风工具" "函数测试" "曹饮" nil "函数\r\nlt:info-summary-set" "http://www..."))
(defun lt:info-summary-set (sumlst / sInfo)
(setq sInfo (vla-get-SummaryInfo doc))
(mapcar '(lambda (X Y)
(if (= (type Y) 'STR)
(vlax-put sInfo X Y)
)
(vlax-get sInfo X)
)
'(Title Subject author Keywords Comments HyperlinkBase)
sumlst
)
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-custom-number)
;; [功能] 获取图形属性“自定义”属性的数量
(defun lt:info-custom-number (/ sInfo)
(vla-NumCustomInfo (vla-get-SummaryInfo doc))
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-custom-get)
;; [功能] 获取图形属性“自定义”属性列表
;; [返回] 成功->表，表形式为 ((Key0 . Val0) (Key1 . Val1) ... (KeyN . ValN))；失败-> nil 。
(defun lt:info-custom-get (/ sInfo i lst key val)
(setq sInfo (vla-get-SummaryInfo doc) i -1)
(repeat (vla-NumCustomInfo sInfo)
(vla-GetCustomByIndex sInfo (setq i (1+ i)) 'key 'val)
(setq lst (append lst (list (cons key val))))
)
lst
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-custom-set <关键字> <值>)
;; [功能] 设置或添加图形属性“自定义”属性
;; [参数] key---名称(关键字)。若不存在则在列表尾部添加
;; val---属性值
;; [返回] 该关键字的索引值(INT)，该索引范围从0到自定义属性数量-1
(defun lt:info-custom-set (key val / sInfo i)
(setq sInfo (vla-get-SummaryInfo doc) i -1)
(if (vl-catch-all-apply 'vla-SetCustomByKey (list sInfo key val))
(vla-AddCustomInfo sInfo key val)
)
(while (/= key key2)
(vla-GetCustomByIndex sInfo (setq i (1+ i)) 'key2 'val)
)
i
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-custom-set-byIndex <索引值> <关键字> <值>)
;; [功能] 根据索引值设置图形属性“自定义”属性的关键字和值
;; [参数] index---索引值。该索引范围从0到自定义属性数量-1，如果超出范围
;; key-----新的关键字
;; val-----新的值
;; [返回] 成功-> T，失败-> nil。
(defun lt:info-custom-set-byIndex (index key val)
(not (vl-catch-all-apply
'vla-SetCustomByIndex
(list (vla-get-SummaryInfo doc) index key val)
)
)
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-custom-set-byIndex <关键字或索引值>)
;; [功能] 删除图形属性“自定义”属性的关键字和值
;; [参数] key-----关键字或索引值
;; [返回] 成功-> T，失败-> nil。
(defun lt:info-custom-remove (key / sInfo fun)
(setq sInfo (vla-get-SummaryInfo doc))
(if (numberp key)
(setq fun 'vla-RemoveCustomByIndex)
(setq fun 'vla-RemoveCustomByKey)
)
(not (vl-catch-all-apply fun (list sInfo key)))
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-custom-set-byIndex <关键字或索引值>)
;; [功能] 删除所有图形属性“自定义”属性
;; [返回] 永远返回 nil
(defun lt:info-custom-removeAll (/ sInfo i)
(setq sInfo (vla-get-SummaryInfo doc))
(repeat (setq i (vla-NumCustomInfo sInfo))
(vla-RemoveCustomByIndex sInfo (setq i (1- i)))
)
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-LastSavedBy-get)
;; [功能] 获取图形属性“统计信息”属性的“最后编辑者”
;; [返回] “最后编辑者”属性的字符串
(defun lt:info-LastSavedBy-get ()
(vla-get-lastsavedby (vla-get-SummaryInfo doc))
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-LastSavedBy-set <字符串>)
;; [功能] 设置图形属性“统计信息”属性的“最后编辑者”
;; [参数] name---“最后编辑者”属性的字符串
;; [返回] 成功-> T，失败-> nil。
(defun lt:info-LastSavedBy-set (name)
(not (vl-catch-all-apply 'vla-put-lastsavedby
(list (vla-get-SummaryInfo doc) name)
)
)
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-RevisionNumber-get)
;; [功能] 获取图形属性“统计信息”属性的“修订次数”
;; [返回] “修订次数”属性的字符串
(defun lt:info-RevisionNumber-get ()
(vla-get-RevisionNumber (vla-get-SummaryInfo doc))
)
;;_________________________________________________________________________________________
;; ▓ (lt:info-RevisionNumber-set <字符串或数字>)
;; [功能] 设置图形属性“统计信息”属性的“修订次数”
;; [参数] num---“修订次数”属性的字符串或数字
;; [返回] 成功-> T，失败-> nil。
(defun lt:info-RevisionNumber-set (num)
(not (vl-catch-all-apply 'vla-put-RevisionNumber
(list (vla-get-SummaryInfo doc) num)
)
)
)

;;; ┏━━━┳━━━━━━━━━━━━━━━━━━━┓ 
;;; ┃  T: ┃ 图形属性信息操作               ┃ 
;;; ┗━━━┻━━━━━━━━━━━━━━━━━━━┛ 
;;;  以下函数参考命令 DWGPROPS 。(vl-load-com) 
(setq doc (vla-get-activedocument (vlax-get-acad-object))) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-summary-get) 
;; [功能] 获取图形属性“概要”信息 
;; [返回] 表。表元素内容依次为标题、主题、作者、关键字、注释和超链接地址 
(defun lt:info-summary-get (/ sInfo) 
  (setq sInfo (vla-get-SummaryInfo doc)) 
  (mapcar '(lambda (x) (vlax-get sinfo X)) 
          '(Title Subject author Keywords Comments HyperlinkBase) 
  ) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-summary-set <值列表>) 
;; [功能] 设置图形属性“概要”信息 
;; [参数] sumlst---值列表。表中的值依次赋给关键字标题、主题、作者、关键字、注释和超链接地址 
;;                 若值为 nil 时，则不修改。为 "" 时清除原有值。其中注释的换行符为 "\r\n"。 
;; [返回] 修改后的值列表。 
;; [测试] (lt:info-summary-set '("朗风工具" "函数测试" "曹饮" nil "函数\r\nlt:info-summary-set" "http://www...")) 
(defun lt:info-summary-set (sumlst / sInfo) 
  (setq sInfo (vla-get-SummaryInfo doc)) 
  (mapcar '(lambda (X Y) 
             (if (= (type Y) 'STR) 
               (vlax-put sInfo X Y) 
             ) 
             (vlax-get sInfo X) 
           ) 
          '(Title Subject author Keywords Comments HyperlinkBase) 
          sumlst 
  ) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-custom-number) 
;; [功能] 获取图形属性“自定义”属性的数量 
(defun lt:info-custom-number (/ sInfo) 
  (vla-NumCustomInfo (vla-get-SummaryInfo doc)) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-custom-get) 
;; [功能] 获取图形属性“自定义”属性列表 
;; [返回] 成功->表，表形式为 ((Key0 . Val0) (Key1 . Val1) ... (KeyN . ValN))；失败-> nil 。 
(defun lt:info-custom-get (/ sInfo i lst key val) 
  (setq sInfo (vla-get-SummaryInfo doc) i -1) 
  (repeat (vla-NumCustomInfo sInfo) 
    (vla-GetCustomByIndex sInfo (setq i (1+ i)) 'key 'val) 
    (setq lst (append lst (list (cons key val)))) 
  ) 
  lst 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-custom-set <关键字> <值>) 
;; [功能] 设置或添加图形属性“自定义”属性 
;; [参数] key---名称(关键字)。若不存在则在列表尾部添加 
;;        val---属性值 
;; [返回] 该关键字的索引值(INT)，该索引范围从0到自定义属性数量-1 
(defun lt:info-custom-set (key val / sInfo i) 
  (setq sInfo (vla-get-SummaryInfo doc) i -1) 
  (if (vl-catch-all-apply 'vla-SetCustomByKey (list sInfo key val)) 
    (vla-AddCustomInfo sInfo key val) 
  ) 
  (while (/= key key2) 
    (vla-GetCustomByIndex sInfo (setq i (1+ i)) 'key2 'val) 
  ) 
  i 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-custom-set-byIndex <索引值> <关键字> <值>) 
;; [功能] 根据索引值设置图形属性“自定义”属性的关键字和值 
;; [参数] index---索引值。该索引范围从0到自定义属性数量-1，如果超出范围 
;;        key-----新的关键字 
;;        val-----新的值 
;; [返回] 成功-> T，失败-> nil。 
(defun lt:info-custom-set-byIndex (index key val) 
  (not (vl-catch-all-apply 
         'vla-SetCustomByIndex 
         (list (vla-get-SummaryInfo doc) index key val) 
       ) 
  ) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-custom-set-byIndex <关键字或索引值>) 
;; [功能] 删除图形属性“自定义”属性的关键字和值 
;; [参数] key-----关键字或索引值 
;; [返回] 成功-> T，失败-> nil。 
(defun lt:info-custom-remove (key / sInfo fun) 
  (setq sInfo (vla-get-SummaryInfo doc)) 
  (if (numberp key) 
    (setq fun 'vla-RemoveCustomByIndex) 
    (setq fun 'vla-RemoveCustomByKey) 
  ) 
  (not (vl-catch-all-apply fun (list sInfo key))) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-custom-set-byIndex <关键字或索引值>) 
;; [功能] 删除所有图形属性“自定义”属性 
;; [返回] 永远返回 nil 
(defun lt:info-custom-removeAll (/ sInfo i) 
  (setq sInfo (vla-get-SummaryInfo doc)) 
  (repeat (setq i (vla-NumCustomInfo sInfo)) 
    (vla-RemoveCustomByIndex sInfo (setq i (1- i))) 
  ) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-LastSavedBy-get) 
;; [功能] 获取图形属性“统计信息”属性的“最后编辑者” 
;; [返回] “最后编辑者”属性的字符串 
(defun lt:info-LastSavedBy-get () 
  (vla-get-lastsavedby (vla-get-SummaryInfo doc)) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-LastSavedBy-set <字符串>) 
;; [功能] 设置图形属性“统计信息”属性的“最后编辑者” 
;; [参数] name---“最后编辑者”属性的字符串 
;; [返回] 成功-> T，失败-> nil。 
(defun lt:info-LastSavedBy-set (name) 
  (not (vl-catch-all-apply 'vla-put-lastsavedby 
                           (list (vla-get-SummaryInfo doc) name) 
       ) 
  ) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-RevisionNumber-get) 
;; [功能] 获取图形属性“统计信息”属性的“修订次数” 
;; [返回] “修订次数”属性的字符串 
(defun lt:info-RevisionNumber-get () 
  (vla-get-RevisionNumber (vla-get-SummaryInfo doc)) 
) 
;;_________________________________________________________________________________________ 
;; ▓ (lt:info-RevisionNumber-set <字符串或数字>) 
;; [功能] 设置图形属性“统计信息”属性的“修订次数” 
;; [参数] num---“修订次数”属性的字符串或数字 
;; [返回] 成功-> T，失败-> nil。 
(defun lt:info-RevisionNumber-set (num) 
  (not (vl-catch-all-apply 'vla-put-RevisionNumber 
                           (list (vla-get-SummaryInfo doc) num) 
       ) 
  ) 
)

jaminth · 发表于 2008-1-22 13:08

xing979020,不要小看明经通道!!!像你这样的标题,强烈鄙视你！

谢谢caoyin，给你当头一棒！！

狂刀无痕 · 发表于 2008-1-22 14:04

据我总结，一般半桶水或小半桶水的人才会发这样的标题。

低手和高手一般都比较谦虚

BPE · 发表于 2008-1-22 14:40

见不懂，能说明点吗，我太菜了，

jack093 · 发表于 2012-7-18 18:36

1楼图中基本信息有一个文件修改时间，统计信息中也有一个文件修改时间，
后一个可以通过TDUUPDATE变量得到，
前一个就是存盘时间，不知道如何得到

自贡黄明儒 · 发表于 2012-7-19 15:47

caoyin 发表于 2008-1-22 08:53
这样的帖子标题就是要源码吗？

问一下C版，那个函数l:strp 起什么什么作用？

自贡黄明儒 · 发表于 2012-7-20 20:57

发现一个奇怪的问题,C版程序lt:info-summary-set ,须设置cmdecho为1才行。不知为什么？

sageman · 发表于 2013-5-16 08:12

收藏着，以后肯定有用。

账号		自动登录	找回密码
密码			注册

[原创][转帖]难倒所有高手的难题

点评

浏览过的版块