计算图形惯性矩，面积等

hb_xiaofen · 发表于 2008-2-19 15:51:00

本帖最后由作者于 2008-2-19 16:02:25 编辑

工具计算任意图形（region）对象的面积，周长，惯性矩，主惯性矩，主矩方向，并表示在Cad图上。非常方便，单首先要把封闭图形利用region命令做成面域对象。

zml84 · 发表于 2008-2-19 16:24:00

凑个热闹，下面这个是纯算法的。
http://zml84.blog.sohu.com/77169816.html

;;;=======================================
;;;功能：根据点位表，计算截面特性值
;;;参数：LST_PT ----截面内外轮廓线二维点表
(defun ZML-JM (LST_PT / X面积 X静矩对X轴惯性矩
Y面积 Y静矩对Y轴惯性矩 PT0
X0 Y0 X1 Y1 XX
YY Y面积 Y静矩面积A 面积B
YA YB 惯性矩A 惯性矩B X形心
Y形心对形心X轴惯性矩对形心Y轴惯性矩
对X轴惯性矩 LST_X LST_Y MAX_X
MAX_Y MIN_X MIN_Y 形心至上形心至下
形心至左形心至右
)
;;==========
;;第一部分计算与面积有关的特性
(setq X面积 0
Y面积 0
X静矩 0
Y静矩 0
对X轴惯性矩 0
对Y轴惯性矩 0
)
(setq PT0 (last LST_PT))
(foreach PT LST_PT
(progn
;;
(setq X0 (car PT0)
Y0 (cadr PT0)
X1 (car PT)
Y1 (cadr PT)
)
(setq XX (- X1 X0)
YY (- Y1 Y0)
)
;;对于X轴
;;备忘：a为矩形，b为三角形
(setq 面积A (* XX Y0)
YA (* 0.5 Y0)
惯性矩A (* (/ 1.0 12) XX Y0 Y0 Y0)
惯性矩A (+ 惯性矩A (* 面积A YA YA))
)
(setq 面积B (* 0.5 XX YY)
YB (+ Y0 (/ YY 3.0))
惯性矩B (* (/ 1.0 36) XX YY YY YY)
惯性矩B (+ 惯性矩B (* 面积B YB YB))
)
(setq X面积 (+ X面积面积A 面积B)
X静矩 (+ X静矩 (* 面积A YA) (* 面积B YB))
对X轴惯性矩 (+ 对X轴惯性矩惯性矩A 惯性矩B)
)
;;对于y轴
;;备忘：a为矩形，b为三角形
(setq 面积A (* YY X0)
YA (* 0.5 X0)
惯性矩A (* (/ 1.0 12) YY X0 X0 X0)
惯性矩A (+ 惯性矩A (* 面积A YA YA))
)
(setq 面积B (* 0.5 YY XX)
YB (+ X0 (/ XX 3.0))
惯性矩B (* (/ 1.0 36) YY XX XX XX)
惯性矩B (+ 惯性矩B (* 面积B YB YB))
)
(setq Y面积 (+ Y面积面积A 面积B)
Y静矩 (+ Y静矩 (* 面积A YA) (* 面积B YB))
对Y轴惯性矩 (+ 对Y轴惯性矩惯性矩A 惯性矩B)
)
(setq PT0 PT)
)
)
;;计算形心位置
(setq X形心 (/ Y静矩 Y面积)
Y形心 (/ X静矩 X面积)
)
;;计算对自身形心的惯性矩
(setq 对形心X轴惯性矩 (- 对X轴惯性矩 (* X面积 Y形心 Y形心))
对形心Y轴惯性矩 (- 对Y轴惯性矩 (* Y面积 X形心 X形心))
)
;;==========
;;第二部分计算截面的边缘位置
(setq LST_X '()
LST_Y '()
)
(foreach PT LST_PT
(setq LST_X (cons (car PT) LST_X)
LST_Y (cons (cadr PT) LST_Y)
)
)
(setq MAX_Y (apply 'max LST_Y)
MIN_Y (apply 'min LST_Y)
MAX_X (apply 'max LST_X)
MIN_X (apply 'min LST_X)
)
(setq 形心至上 (- MAX_Y Y形心)
形心至下 (- Y形心 MIN_Y)
形心至右 (- MAX_X X形心)
形心至左 (- X形心 MIN_X)
)
;;==========
;;第三部分返回结果
(list (cons "面积" Y面积)
(cons "形心" (list X形心 Y形心))
(cons "形心至上" 形心至上)
(cons "形心至下" 形心至下)
(cons "形心至左" 形心至左)
(cons "形心至右" 形心至右)
(cons "对X轴静矩" (- X静矩))
(cons "对Y轴静矩" Y静矩)
(cons "对X轴惯性矩" (- 对X轴惯性矩))
(cons "对Y轴惯性矩" 对Y轴惯性矩)
(cons "对形心X轴惯性矩" (- 对形心X轴惯性矩))
(cons "对形心Y轴惯性矩" 对形心Y轴惯性矩)
)
)

;;;=======================================
;;;功能：根据点位表，计算截面特性值
;;;参数：LST_PT  ----截面内外轮廓线二维点表
(defun ZML-JM (LST_PT    /       X面积  X静矩     对X轴惯性矩
         Y面积    Y静矩       对Y轴惯性矩     PT0
         X0    Y0       X1    Y1     XX
         YY    Y面积       Y静矩  面积A     面积B
         YA    YB       惯性矩A  惯性矩B     X形心
         Y形心    对形心X轴惯性矩  对形心Y轴惯性矩
         对X轴惯性矩       LST_X  LST_Y     MAX_X
         MAX_Y    MIN_X       MIN_Y  形心至上   形心至下
         形心至左    形心至右
        )
    ;;==========
    ;;第一部分  计算与面积有关的特性
    (setq X面积  0
    Y面积  0
    X静矩  0
    Y静矩  0
    对X轴惯性矩 0
    对Y轴惯性矩 0
    )
    (setq PT0 (last LST_PT))
    (foreach PT  LST_PT
  (progn
      ;;
      (setq X0 (car PT0)
      Y0 (cadr PT0)
      X1 (car PT)
      Y1 (cadr PT)
      )
      (setq XX (- X1 X0)
      YY (- Y1 Y0)
      )
      ;;对于X轴
      ;;备忘：a为矩形，b为三角形
      (setq 面积A    (* XX Y0)
      YA    (* 0.5 Y0)
      惯性矩A (* (/ 1.0 12) XX Y0 Y0 Y0)
      惯性矩A (+ 惯性矩A (* 面积A YA YA))
      )
      (setq 面积B    (* 0.5 XX YY)
      YB    (+ Y0 (/ YY 3.0))
      惯性矩B (* (/ 1.0 36) XX YY YY YY)
      惯性矩B (+ 惯性矩B (* 面积B YB YB))
      )
      (setq X面积        (+ X面积 面积A 面积B)
      X静矩        (+ X静矩 (* 面积A YA) (* 面积B YB))
      对X轴惯性矩 (+ 对X轴惯性矩 惯性矩A 惯性矩B)
      )
      ;;对于y轴
      ;;备忘：a为矩形，b为三角形
      (setq 面积A    (* YY X0)
      YA    (* 0.5 X0)
      惯性矩A (* (/ 1.0 12) YY X0 X0 X0)
      惯性矩A (+ 惯性矩A (* 面积A YA YA))
      )
      (setq 面积B    (* 0.5 YY XX)
      YB    (+ X0 (/ XX 3.0))
      惯性矩B (* (/ 1.0 36) YY XX XX XX)
      惯性矩B (+ 惯性矩B (* 面积B YB YB))
      )
      (setq Y面积        (+ Y面积 面积A 面积B)
      Y静矩        (+ Y静矩 (* 面积A YA) (* 面积B YB))
      对Y轴惯性矩 (+ 对Y轴惯性矩 惯性矩A 惯性矩B)
      )
      (setq PT0 PT)
  )
    )
    ;;计算形心位置
    (setq X形心  (/ Y静矩 Y面积)
    Y形心  (/ X静矩 X面积)
    )
    ;;计算对自身形心的惯性矩
    (setq 对形心X轴惯性矩 (- 对X轴惯性矩 (* X面积 Y形心 Y形心))
    对形心Y轴惯性矩 (- 对Y轴惯性矩 (* Y面积 X形心 X形心))
    )
    ;;==========
    ;;第二部分  计算截面的边缘位置
    (setq LST_X  '()
    LST_Y  '()
    )
    (foreach PT  LST_PT
  (setq LST_X (cons (car PT) LST_X)
        LST_Y (cons (cadr PT) LST_Y)
  )
    )
    (setq MAX_Y  (apply 'max LST_Y)
    MIN_Y  (apply 'min LST_Y)
    MAX_X  (apply 'max LST_X)
    MIN_X  (apply 'min LST_X)
    )
    (setq 形心至上 (- MAX_Y Y形心)
    形心至下 (- Y形心 MIN_Y)
    形心至右 (- MAX_X X形心)
    形心至左 (- X形心 MIN_X)
    )
    ;;==========
    ;;第三部分  返回结果
    (list (cons "面积" Y面积)
    (cons "形心" (list X形心 Y形心))
    (cons "形心至上" 形心至上)
    (cons "形心至下" 形心至下)
    (cons "形心至左" 形心至左)
    (cons "形心至右" 形心至右)
    (cons "对X轴静矩" (- X静矩))
    (cons "对Y轴静矩" Y静矩)
    (cons "对X轴惯性矩" (- 对X轴惯性矩))
    (cons "对Y轴惯性矩" 对Y轴惯性矩)
    (cons "对形心X轴惯性矩" (- 对形心X轴惯性矩))
    (cons "对形心Y轴惯性矩" 对形心Y轴惯性矩)
    )
)

苍龙在天 · 发表于 2012-5-19 19:28:03

这个太有用了，谢谢两位楼上的

fdb2007 · 发表于 2012-5-20 09:14:48

谢谢分享，下载学习了，顶一下

zs2002zs · 发表于 2012-10-9 13:10:44

谢谢。。。。。。。。。。。。

crazylsp · 发表于 2012-10-11 09:48:49

能不能计算部分受压区的惯性距呢？

yjtdkj · 发表于 2018-9-26 16:43:36

本帖最后由 yjtdkj 于 2018-9-26 17:00 编辑

楼主看一下我这个图纸，为什么惯性矩和CAD自带的查出来不一样呀？
形心、面积都一样，是不是中间挖空的原因？

=====================
不好意思，是我搞错了，系统自带的惯性矩是针对0,0,0点来求的

账号		自动登录	找回密码
密码			注册

计算图形惯性矩，面积等

本帖子中包含更多资源

本帖子中包含更多资源