求一个批量删除同名块的程序

hull

图里面的块重复插入很多次，名字知道了，有几百副这样的图。要删除这里面指定名字的所有块。

英雄无敌

是都要删除吗？

(defun c:sb (/ en lst typ blkn ss n ret)

  (setq en (entsel "\n请选择一个块:"))
  (if en
    (progn
      (setq lst (entget (car en)))
      (setq typ (cdr (assoc 0 lst)))
      (if (= "INSERT" typ)
 (progn
   (setq blkn (cdr (assoc 2 lst)))
   (setq ss (ssget "x" (list (cons 2 blkn))))
   (setq n -1)
   (repeat (sslength ss)
     (setq en (ssname ss (setq n (1+ n))))
     (redraw en 3)
   )
   (initget "Move Erase eXplode")
   (setq ret
   (getpoint
     "\n选择基点或选择一种操作方式\"移动<Move>，删除<Erase>，打碎<eXplode>,<右键取消>\"]:"
   )
   )
   (cond
     ((= "Move" ret)
      (command "move" ss "")
     )
     ((= "Erase" ret)
      (command "erase" ss "")
     )
     ((= "eXplode" ret)
      (setq n -1)
      (command "undo" "be")
      (repeat (sslength ss)
        (setq en (ssname ss (setq n (1+ n))))
        (command "explode" en)
      )
      (command "undo" "e")
     )
     ((listp ret)
      (if ret
        (progn
   (command "move" ss "" ret)
        )
        (progn
   (setq n -1)
   (repeat (sslength ss)
     (setq en (ssname ss (setq n (1+ n))))
     (redraw en 4)
   )
        )
      )
     )
   )

 )
 (alert "\n请选择块！")
      )
    )
  )

  (princ)
)

里面供了3种选择方式，如果你只要删除，你修改一下程序即可

钾肥

用过滤选择后删除就好啦~

没必要特地写一个程序吧~

liushengri

能用框选的方式来删除吗？

钾肥

当然~不然就没啥意义了~

liushengri

用框选的方式如何来删除?

英雄无敌

如果要框选，只要将(setq ss (ssget "x" (list (cons 2 blkn))))
改成(setq ss (ssget  (list (cons 2 blkn))))就行了，不过有一点，不支持无名块，如果要支持，得修改程序。

jiangkaimin

请英雄无敌大侠改下程序吧。其实实际应用中，很多情况就是要删除无名块。

感谢英雄无敌大侠了！

weidesign669

怎样过滤选择无名块