一键让我框选到的块颜色全部变成当前颜色(打图需要)

caoyin

这个程序很有意思，在龙版主的提示下，终于可以完成 12 楼的测试：

caoyin

这样就必须改变块定义，改变块定义后，未框选的同名块也会改变，建议楼主定义块的时候将对象的颜色改为ByBlock，这样定义好的块颜色可以随意改变！

caoyin

;;
(defun c:tt (/ ss co i obj bn blks bnlst)
  (if (and (setq ss (ssget '((0 . "insert"))))
           (setq co (acad_colordlg (cond (co) (7))))
      )
    (progn
      ;;取得块名列表
      (repeat (setq i (sslength ss))
        (setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
        (vla-put-color obj co)
        (setq bn (vla-get-name obj))
        (if (not (member bn bnlst))
          (setq bnlst (cons bn bnlst))
        )
      )
      (setq blks (vla-get-Blocks (vla-get-activedocument (vlax-get-acad-object))))
      (foreach x bnlst
        (vlax-for obj (vla-item blks x) (vla-put-color obj 0))
      )
    )
  )
  (princ)
)

龙龙仔

caoyin发表于2008-6-5 17:08:00;;(defun c:tt (/ ss co i obj bn blks bnlst)  (if (and (setq ss (ssget '((0 . \"insert\"))))           (setq co (acad_colordl

對各別顏色的屬性,公差,引線應不行吧!

我u盤中有ch_color程序

caoyin

谢龙版主提示，学习了

我搞了半天没搞出来，能否指教一下，谢谢

龙龙仔

先選顏色,再選物件

caoyin

;;终于明白了(以前从来都不知道)，得到的结论是：
;;块中的引线和公差颜色为 ByBlock ，不随块本身的颜色的变化而变化。
(defun c:ChBlkColor (/ ss co i obj bn bnlst)
  (if (and (setq ss (ssget '((0 . "insert"))))
           (setq co (acad_colordlg 7))
      )
    (progn
      (repeat (setq i (sslength ss))
        (setq obj (vlax-ename->vla-object (ssname ss (setq i (1- i))))
              bn  (vla-get-name obj)
        )
        (vla-put-color obj co)
        (if (and (= (vla-get-ObjectName obj) "AcDbBlockReference")
                 (= (vla-get-HasAttributes obj) :vlax-true)
            )
          (foreach x (vlax-invoke obj 'getattributes)
            (vla-put-color x 0)
          )
        )
        (if (not (member bn bnlst))
          (setq bnlst (cons bn bnlst))
        )
      )
      (setq blks (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))))
      (foreach x bnlst
        (vlax-for obj (vla-item blks x)
          (if (member (vla-get-ObjectName obj) '("AcDbFcf" "AcDbLeader"))
            (vla-put-color obj co)
            (vla-put-color obj 0)
          )
        )
      )
    )
  )
  (princ)
)