[求助]请教高手,如何知道文件中哪些文字样式缺少字体?

userzhl

请教高手,如何知道文件中哪些文字样式缺少字体?

userzhl

这种情况我们经常会遇到,怎么会没人关注呢?

userzhl

我是想实现这样的功能

userzhl

自动判断文字样式是否缺少字体并进行替换.

liu_kunlun

;;;得到所有TextStyle Name

;;;从网上得到
(defun GetAllTextStyleNames (/ names)
   (or Gb:AcO (setq Gb:AcO (vlax-get-acad-object)))
   (or Gb:AcD (setq Gb:AcD (vla-get-ActiveDocument Gb:AcO)))
   (vlax-for Sty (vla-get-TextStyles Gb:AcD)
      (setq names (cons (vla-get-Name Sty) names))
   )
   names
)

;;判断一个style的font是否找得到

;;对windos字体不完善
(defun IsTextStyleFontOk (sty / f3 f4 )
   (and (setq f4 (tblsearch "style"  sty))       
        (or (findfile (setq f3 (cdrassoc 3 f4)))
            (findfile (strcat f3 ".shx"))
     (findfile (strcat "C:\\WINDOWS\\Fonts\\" f3))
     (and (= f3 "SimSun.ttf")
   (findfile "c:/windows/fonts/simsun.ttc")
     )  
        )
        (or (null (setq f4 (cdrassoc 4 f4)))
     (= "" f4)
            (findfile f4)
     (findfile (strcat f4 ".shx"))
        )
   )
)

userzhl

;将不认识的字体自动替换成,自己定义的字体。
(defun ukword (bit kwd msg def / inp)
  (if (and
 def
 (/= def "")
      )
    (setq msg (strcat "\n" msg "<" def ">:")
   bit (* 2 (fix (/ bit 2)))
    )
    (setq msg (strcat "\n" msg ":"))
  )
  (initget bit kwd)
  (setq inp (getkword msg))
  (if inp
    inp
    def
  )
)
(defun c:gps_txt_rep ( / cn elist en enl nm gps_hzstyle);!!!<-字体样式自动替换 
  (setq ukw (ukword 2 "Y N" "\n缺少字体自动替换成._txt.shx,hztxt.确认修改?[是(Y)/否(N)]" "Y"))
  (if (= "Y" ukw)
    (progn 
      (if (not $gps_hztxt_e) (setq $gps_hztxt_e "_txt.shx"))
  (if (not $gps_hztxt)   (setq $gps_hztxt "hztxt.shx"))
  (setq gps_hzstyle (strcat $gps_hztxt_e "," $gps_hztxt ))
    (setq elist (tblnext "STYLE" T))
    (while (/= elist nil)
      (setq nm (cdr (assoc 2 elist))
            en (cdr (assoc 3 elist))
            cn (cdr (assoc 4 elist))
           enl (strlen en)
      )
      (if (and
             (/= en nil)
             (= cn nil)
             (= (findfile en) nil)
             (= (strcase (substr en (- enl 2))) "SHX")
           )
         (command "_style" nm $gps_hztxt_e "0.0" "0.7" "" "" "" "")
      )
      (if (and
             (/= cn nil)
             (= (findfile cn) nil)
           )
         (command "_style" nm  gps_hzstyle "0.0" "0.7" "" "" "" "")
      )
     (setq elist (tblnext "STYLE"))
   )
    )
  )
 )