[求助]如何取真彩色的数值？

jaminth · 发表于 2009-4-21 07:27:00

如下图所示，如何取真彩色的数值？又如何进行反操作？！

highflybir · 发表于 2009-4-21 16:24:00

[Post=10]一个图元的dxf表中的420是truecolor 数值，

;;;===============
;;;把truecolordlg
;;;420构成的数值返
;;;回RGB列表.
;;;===============
(defun Number->RGB (C)
(list (lsh C -16)
(lsh (lsh C 16) -24)
(lsh (lsh C 24) -24)
)
)
;;;逆转换
(defun RGB->Number (lst)
(+ (lsh (car lst) 16) (lsh (cadr lst) 8) (caddr lst))
)
;;;===============
;;;RGB转化成索引号
;;;===============
(defun RGB->Index (colRGB / acadver colorObj)
(vl-load-com)
(setq acadver (getvar "acadver"))
(setq acadver (strcat "AutoCAD.AcCmColor." (substr acadver 1 2)))
(setq colorObj (vla-getinterfaceobject (vlax-get-acad-object) acadver))
(vla-setRGB colorobj (car colRGB) (cadr colRGB) (caddr colRGB))
(vla-get-ColorIndex colorobj)
)
;;;===============
;;;索引号转化成RGB
;;;===============
(defun Index->RGB (ci / acadver colorObj)
(vl-load-com)
(setq acadver (getvar "acadver"))
(setq acadver (strcat "AutoCAD.AcCmColor." (substr acadver 1 2)))
(setq colorObj (vla-getinterfaceobject (vlax-get-acad-object) acadver))
(vla-put-ColorIndex colorobj ci)
(list (vla-get-red colorobj)
(vla-get-green colorobj)
(vla-get-blue colorobj)
)
)

;;;===============
;;;把truecolordlg 
;;;420构成的数值返
;;;回RGB列表.     
;;;===============
(defun Number->RGB (C)
  (list (lsh C -16)
        (lsh (lsh C 16) -24)
        (lsh (lsh C 24) -24)
  )
)
;;;逆转换
(defun RGB->Number (lst)
  (+ (lsh (car lst) 16) (lsh (cadr lst) 8) (caddr lst))
)
;;;===============
;;;RGB转化成索引号
;;;===============
(defun RGB->Index (colRGB / acadver colorObj)
  (vl-load-com)
  (setq acadver (getvar "acadver"))
  (setq acadver (strcat "AutoCAD.AcCmColor." (substr acadver 1 2)))
  (setq colorObj (vla-getinterfaceobject (vlax-get-acad-object) acadver))
  (vla-setRGB colorobj (car colRGB) (cadr colRGB) (caddr colRGB)) 
  (vla-get-ColorIndex colorobj)
)
;;;===============
;;;索引号转化成RGB
;;;===============
(defun Index->RGB (ci / acadver colorObj)
  (vl-load-com)
  (setq acadver (getvar "acadver"))
  (setq acadver (strcat "AutoCAD.AcCmColor." (substr acadver 1 2)))
  (setq colorObj (vla-getinterfaceobject (vlax-get-acad-object) acadver))
  (vla-put-ColorIndex  colorobj ci)
  (list (vla-get-red   colorobj)
        (vla-get-green colorobj)
        (vla-get-blue  colorobj)
  )
)

另外autodesk公司提供了样例函数，你不妨参考它。
X:\Program Files\AutoCAD 2006\Sample\VisualLISP\color-util.lsp
[/Post]

jaminth · 发表于 2009-4-21 21:39:00

谢谢! highflybir

highflybir,以下返回值有偏差，有没有办法返回真正的值？！

;--------------------------------------

(Index->RGB (cdr (assoc 62 (tblsearch "layer" "COL-T3"))))

返回：(47 76 38) 实际值：(49 75 38)

(Index->RGB (cdr (assoc 62 (tblsearch "layer" "COL-T1"))))

返回：(255 127 0) 实际值：(255 121 0)

highflybir · 发表于 2009-4-22 09:45:00

回复：我的方法实际上也是autodesk的方法，我以前也发现了这样的偏差问题，在某些数值上有偏差，但很接近，在颜色上很难分别出来。
如果楼主有空，不妨把这个bug在autodesk论坛上贴出来。
下面是color-util.lsp的方法,可以看出我的方法就是它的方法。

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; TrueColor-split - takes a TrueColor number and returns a list of integers the form '(red green blue)
;;
(defun TrueColor-split ( c / )
(list (lsh (fix c) -16)
(lsh (lsh (fix c) 16) -24)
(lsh (lsh (fix c) 24) -24)
)
);defun TrueColor-split
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; TrueColor-make - takes TrueColor components (red green blue) and creates a single TrueColor integer
;;
(defun TrueColor-make ( r g b / )
(+ (lsh (fix r) 16)
(lsh (fix g) 8)
(fix b)
)
);defun TrueColor-make

jaminth · 发表于 2009-4-22 19:02:00

存在这样的BUG, 有点遗憾！有空我在贴贴吧！

谢谢！

账号		自动登录	找回密码
密码			注册

[求助]如何取真彩色的数值？

本帖子中包含更多资源