我要在lisp程序中很方便地删除一个文件夹中所有文件及此文件夹该如何编程？

congcong

meflying

龙龙仔

王咣生

命令: (command "shell" "del c:\\11\\*.* /Q")
命令: (command "shell" "rd c:\\11")

龙龙仔

[此贴子已经被龙龙仔于2003-6-16 16:30:17编辑过]

王咣生

就AutoCAD本身而言,(command "shell" "rd c:\11 /s/q")也可以删除目录树,包括其中的隐藏文件和只读文件.

龙龙仔

;; SORRY!命令名称都一样<FOR TEST ONLY>
;; DelFile
;; BY 龙龙仔
;; Deletes existing files
;; Arguments [Typ]:
;;   Fil = FileName, "C:\\test\\Autoexec.bat" [STR]
;; Notes:
;;   - Requires ScrRun.dll.
;; USAGE: (DelFile "C:\\test\\Autoexec.bat")
(defun DELFILE (FIL /)
  (vlax-invoke
    (vlax-create-object "Scripting.FileSystemObject")
    "deletefile"
    FIL
    :vlax-false
  )
  (princ)
)

;; DelFolder
;; BY 龙龙仔
;; Deletes a directory and all of its subdirectories.
;; Arguments [Typ]:
;;   Fil = FolderName, "C:\\test" [STR]
;; Notes:
;;   - Requires ScrRun.dll.
;; USAGE: (DelFolder "C:\\test")
(defun DELFOLDER (FIL /)
  (vlax-invoke
    (vlax-create-object "Scripting.FileSystemObject")
    "deletefolder"
    FIL
    :vlax-false
  )
  (princ)
)

;; DelFile
;; BY 龙龙仔
;; 能删除所有档案
;; Deletes existing files
;; Arguments [Typ]:
;;   Fil = FileName, "C:\\test\\Autoexec.bat" [STR]
;; Notes:
;;   - Requires ScrRun.dll.
;; USAGE: (DelFile "C:\\test\\*.*")
;; USAGE: (DelFile "C:\\test\\Autoexec.bat")
(defun DELFILE (FIL / FILSYS FILDIR SS ENT)
  (setq FILSYS (vlax-create-object "Scripting.FileSystemObject"))
  (setq FILDIR (vl-filename-directory FIL))
  (setq
    SS (vl-directory-files
         FILDIR
         (strcat (vl-filename-base FIL) (vl-filename-extension FIL))
         1
       )
  )
  (foreach ENT SS
    (vlax-invoke
      FILSYS
      "deletefile"
      (strcat FILDIR "\\" ENT)
      :vlax-false
    )
  )
  (vlax-release-object FILSYS)
  (princ)
)

;; DelFile
;; BY 龙龙仔
;; 对属性为只读的档案不能删除
;; Deletes existing files
;; Arguments [Typ]:
;;   Fil = FileName, "C:\\test\\Autoexec.bat" [STR]
;; Notes:
;;   - Requires ScrRun.dll.
;; USAGE: (DelFile "C:\\test\\*.*")
;; USAGE: (DelFile "C:\\test\\Autoexec.bat")
(defun DELFILE (FIL / FILDIR SS ENT)
  (setq FILDIR (vl-filename-directory FIL))
  (setq
    SS (vl-directory-files
         FILDIR
         (strcat (vl-filename-base FIL) (vl-filename-extension FIL))
         1
       )
  )
  (foreach ENT SS
    (vl-file-delete (strcat FILDIR "\\" ENT))
  )
  (princ)
)

王咣生

我认为你也同样出色.希望以后能见到各位斑竹写的比Doslib功能更强的开发工具.

wujin

有个问题，　我如果想自动删除文件呢。比如我运行了一个程序，生成了一个文件如
c:\test\11.txt
这个11.txt是我在程序启动后提示用户输入的，如果我的程序出错了，我想在出错函数里面自动删除这个文件11.txt该如何做呢。请指教！

meflying

那你就在*error*函数里调用以上各位提供的函数啊